recipes/udev/udev_118.bb

   1 DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
   2 /dev/, handles hotplug events and loads drivers at boot time. It replaces \
   3 the hotplug package and requires a kernel not older than 2.6.12."
   4 RPROVIDES_${PN} = "hotplug"
   5
   6 require udev.inc
   7
   8 RDEPENDS_${PN}_slugos = "udev-utils"
   9
  10 PR = "${INC_PR}.0"
  11
  12 LD = "${CC}"
  13
  14 DEFAULT_PREFERENCE = "-118"
  15
  16 SRC_URI += "\
  17  file://flags.patch \
  18  file://vol_id_ld.patch \
  19  file://udevtrigger_add_devname_filtering.patch \
  20  file://mtd-exclude-persistent.patch \
  21  file://mount.blacklist \
  22 "
  23 TARGET_CC_ARCH += "${LDFLAGS}"
  24
  25 FILES_${PN} += "${base_libdir}/udev/*"
  26 FILES_${PN}-dbg += "${base_libdir}/udev/.debug"
  27 UDEV_EXTRAS = "extras/firmware/ extras/scsi_id/ extras/volume_id/"
  28 EXTRA_OEMAKE += "libudevdir=/lib/udev libdir=${base_libdir} prefix="
  29
  30 do_compile_prepend() {
  31         sed -i s,asmlinkage,, *.c
  32 }
  33
  34 do_install () {
  35         install -d ${D}${usrsbindir} \
  36                    ${D}${sysconfdir} \
  37                    ${D}${sbindir}
  38         oe_runmake 'DESTDIR=${D}' INSTALL=install install
  39         install -d ${D}${sysconfdir}/init.d
  40         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
  41
  42         install -d ${D}${sysconfdir}/udev/rules.d/
  43
  44         install -m 0644 ${WORKDIR}/mount.blacklist     ${D}${sysconfdir}/udev/
  45         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
  46         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
  47         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
  48         install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
  49         if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
  50                 install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
  51         fi
  52
  53         install -d ${D}${sysconfdir}/udev/scripts/
  54
  55         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
  56         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
  57
  58         install -d ${D}${base_libdir}/udev/
  59 }
  60
  61 pkg_postinst_append() {
  62
  63        # Add the root partition to mount.blacklist to avoid a bug in the auto-mounter,
  64        # causing confusion with fsck on boot
  65
  66         while read dev mp fs junk
  67         do
  68                 if test "$mp" = "/"
  69                 then
  70                         root_partition="$dev"
  71                         echo "$root_partition" >> $D${sysconfdir}/udev/mount.blacklist
  72                 fi
  73         done < $D${sysconfdir}/fstab
  74 }
  75
  76
  77 SRC_URI[md5sum] = "a8233f2afc62a8a8971f79df8878d57e"
  78 SRC_URI[sha256sum] = "4467f57484124b735450e05617c2aa0f75e0e56306e92c74f9dfe59bd028fcd9"