recipes/poptop/poptop_1.3.4.bb

   1 DESCRIPTION = "Poptop is the PPTP server solution for Linux Using Poptop, \
   2 Linux servers can now function seamlessly in a PPTP VPN environment. This \
   3 enables administrators to leverage the considerable benefits of both \
   4 Microsoft and Linux operating systems The current release version supports \
   5 Windows 95/98/Me/NT/2000/XP PPTP clients and Linux PPTP clients"
   6 HOMEPAGE = "http://www.poptop.org/"
   7 SECTION = "network"
   8 LICENSE = "GPL"
   9 RDEPENDS_${PN} = "ppp"
  10 RDEPENDS_${PN}-logwtmp-plugin = "${PN}"
  11 PR = "r5"
  12
  13 SRC_URI = "${SOURCEFORGE_MIRROR}/poptop/pptpd-${PV}.tar.gz \
  14            file://fix-plugins-install.patch \
  15            file://pptpd.init"
  16
  17 S = "${WORKDIR}/pptpd-${PV}"
  18
  19 inherit autotools update-rc.d
  20
  21 do_install_append() {
  22         # Install init script
  23         install -m 0755 -d ${D}${sysconfdir}/init.d
  24         install -m 0755 ${WORKDIR}/pptpd.init ${D}${sysconfdir}/init.d/pptpd
  25         # Install
  26         install -d ${D}${sbindir} ${D}/${sysconfdir} ${D}/${sysconfdir}/ppp
  27         install -m 0644 samples/options.pptpd ${D}/${sysconfdir}/ppp/
  28         install -m 0644 samples/pptpd.conf ${D}/${sysconfdir}/
  29
  30         # broken
  31         sed -ri "s,^[:space:]*logwtmp[:space:]*,# logwtmp," ${D}/${sysconfdir}/pptpd.conf
  32         rm -f ${D}${libdir}/pptpd/pptpd-logwtmp.so
  33         # Use mppe option in OE style
  34         sed -ri "s|^[[:space:]]*require-mppe-128[[:space:]]*$|mppe required,no40,no56|" ${D}/${sysconfdir}/ppp/options.pptpd
  35         echo "# don't expose open port by default" >> ${D}/${sysconfdir}/pptpd.conf
  36         echo "listen  127.0.0.1" >> ${D}/${sysconfdir}/pptpd.conf
  37 }
  38
  39 PACKAGES = "${PN}-dbg ${PN}-bcrelay ${PN} ${PN}-doc"
  40
  41 FILES_${PN}-bcrelay = "${sbindir}/bcrelay"
  42
  43 CONFFILES_${PN} = "${sysconfdir}/pptpd.conf \
  44                    ${sysconfdir}/ppp/options.pptpd"
  45
  46 INITSCRIPT_NAME = "pptpd"
  47 INITSCRIPT_PARAMS = "defaults 92 8"
  48
  49 SRC_URI[md5sum] = "b38df9c431041922c997c1148bedf591"
  50 SRC_URI[sha256sum] = "c23a9bdd219a0a36ae7ca20e7c9749f2efdcdbf108aabeeeb5066ba442ec88b6"