recipes/perl/perl_5.10.1.bb

   1 DESCRIPTION = "Perl is a popular scripting language."
   2 HOMEPAGE = "http://www.perl.org/"
   3 SECTION = "devel/perl"
   4 LICENSE = "Artistic|GPLv1+"
   5 PRIORITY = "optional"
   6 DEPENDS = "virtual/db perl-native"
   7 PR = "r22"
   8
   9 # 5.10.1 has Module::Build built-in
  10 PROVIDES += "libmodule-build-perl"
  11
  12 # Major part of version
  13 PVM = "5.10"
  14
  15 SRC_URI = "ftp://ftp.funet.fi/pub/CPAN/src/perl-${PV}.tar.gz;name=perl-${PV} \
  16         file://arm_thread_stress_timeout.diff \
  17         file://cpan_config_path.diff \
  18         file://cpan_definstalldirs.diff \
  19         file://db_file_ver.diff \
  20         file://doc_info.diff \
  21         file://enc2xs_inc.diff \
  22         file://errno_ver.diff \
  23         file://extutils_hacks.diff \
  24         file://fakeroot.diff \
  25         file://instmodsh_doc.diff \
  26         file://ld_run_path.diff \
  27         file://libnet_config_path.diff \
  28         file://m68k_thread_stress.diff \
  29         file://mod_paths.diff \
  30         file://module_build_man_extensions.diff \
  31         file://perl_synopsis.diff \
  32         file://prune_libs.diff \
  33         file://use_gdbm.diff \
  34         file://assorted_docs.diff \
  35         file://net_smtp_docs.diff \
  36         file://processPL.diff \
  37         file://perlivp.diff \
  38         file://pod2man-index-backslash.diff \
  39         file://disable-zlib-bundling.diff \
  40         file://kfreebsd_cppsymbols.diff \
  41         file://cpanplus_definstalldirs.diff \
  42         file://cpanplus_config_path.diff \
  43         file://kfreebsd-filecopy-pipes.diff \
  44         file://anon-tmpfile-dir.diff \
  45         file://abstract-sockets.diff \
  46         file://hurd_cppsymbols.diff \
  47         file://autodie-flock.diff \
  48         file://archive-tar-instance-error.diff \
  49         file://positive-gpos.diff \
  50         file://devel-ppport-ia64-optim.diff \
  51         file://trie-logic-match.diff \
  52         file://hppa-thread-eagain.diff \
  53         file://crash-on-undefined-destroy.diff \
  54         file://tainted-errno.diff \
  55         file://safe-upgrade.diff \
  56         file://tell-crash.diff \
  57         file://format-write-crash.diff \
  58         file://arm-alignment.diff \
  59         file://fcgi-test.diff \
  60         file://hurd-ccflags.diff \
  61         file://perl-time-hires-fix-cross-compilation.patch \
  62         \
  63         file://Makefile.patch \
  64         file://Makefile.SH.patch \
  65         file://installperl.patch \
  66         file://perl-dynloader.patch \
  67         file://perl-moreconfig.patch \
  68         file://letgcc-find-errno.patch \
  69         file://generate-sh.patch \
  70         file://shared-ldflags.patch \
  71         file://cross-generate_uudmap.patch \
  72         file://config.sh \
  73         file://config.sh-32 \
  74         file://config.sh-32-le \
  75         file://config.sh-32-be \
  76         file://config.sh-64 \
  77         file://config.sh-64-le \
  78         file://config.sh-64-be"
  79
  80 SRC_URI[perl-5.10.1.md5sum] = "b9b2fdb957f50ada62d73f43ee75d044"
  81 SRC_URI[perl-5.10.1.sha256sum] = "cb7f26ea4b2b28d6644354d87a269d01cac1b635287dae64e88eeafa24b44f35"
  82
  83 inherit siteinfo
  84
  85 # Where to find the native perl
  86 HOSTPERL = "${STAGING_BINDIR_NATIVE}/perl${PV}"
  87
  88 # Where to find .so files - use the -native versions not those from the target build
  89 export PERLHOSTLIB = "${STAGING_LIBDIR_NATIVE}/perl/${PV}/"
  90
  91 # LDFLAGS for shared libraries
  92 export LDDLFLAGS = "${LDFLAGS} -shared"
  93
  94 # We're almost Debian, aren't we?
  95 CFLAGS += "-DDEBIAN"
  96
  97 do_nolargefile() {
  98         sed -i -e "s,\(uselargefiles=\)'define',\1'undef',g" \
  99                 -e "s,\(d_readdir64_r=\)'define',\1'undef',g" \
 100                 -e "s,\(readdir64_r_proto=\)'\w+',\1'0',g" \
 101                 -e "/ccflags_uselargefiles/d" \
 102                 -e "s/-Duselargefiles//" \
 103                 -e "s/-D_FILE_OFFSET_BITS=64//" \
 104                 -e "s/-D_LARGEFILE_SOURCE//" \
 105                 ${S}/Cross/config.sh-${TARGET_ARCH}-${TARGET_OS}
 106 }
 107
 108 do_configure() {
 109         # Make hostperl in build directory be the native perl
 110         ln -sf ${HOSTPERL} hostperl
 111
 112         # Do out work in the cross subdir
 113         cd Cross
 114
 115         # Generate configuration
 116         rm -f config.sh-${TARGET_ARCH}-${TARGET_OS}
 117         for i in ${WORKDIR}/config.sh \
 118                  ${WORKDIR}/config.sh-${SITEINFO_BITS} \
 119                  ${WORKDIR}/config.sh-${SITEINFO_BITS}-${SITEINFO_ENDIANNESS}; do
 120             cat $i >> config.sh-${TARGET_ARCH}-${TARGET_OS}
 121         done
 122
 123         # Fixups for uclibc
 124         if [ "${TARGET_OS}" = "linux-uclibc" -o "${TARGET_OS}" = "linux-uclibceabi" -o "${TARGET_OS}" = "linux-uclibcspe" ]; then
 125                 sed -i -e "s,\(d_crypt_r=\)'define',\1'undef',g" \
 126                        -e "s,\(d_futimes=\)'define',\1'undef',g" \
 127                        -e "s,\(crypt_r_proto=\)'\w+',\1'0',g" \
 128                        -e "s,\(d_getnetbyname_r=\)'define',\1'undef',g" \
 129                        -e "s,\(getnetbyname_r_proto=\)'\w+',\1'0',g" \
 130                        -e "s,\(d_getnetbyaddr_r=\)'define',\1'undef',g" \
 131                        -e "s,\(getnetbyaddr_r_proto=\)'\w+',\1'0',g" \
 132                        -e "s,\(d_getnetent_r=\)'define',\1'undef',g" \
 133                        -e "s,\(getnetent_r_proto=\)'\w+',\1'0',g" \
 134                        -e "s,\(d_sockatmark=\)'define',\1'undef',g" \
 135                        -e "s,\(d_sockatmarkproto=\)'\w+',\1'0',g" \
 136                     config.sh-${TARGET_ARCH}-${TARGET_OS}
 137         fi
 138
 139         ${@base_contains('DISTRO_FEATURES', 'largefile', '', 'do_nolargefile', d)}
 140
 141         # Update some paths in the configuration
 142         sed -i -e 's,@DESTDIR@,${D},g' \
 143                -e 's,@ARCH@,${TARGET_ARCH}-${TARGET_OS},g' \
 144                -e "s%/usr/include/%${STAGING_INCDIR}/%g" \
 145                -e 's,/usr/,${exec_prefix}/,g' \
 146             config.sh-${TARGET_ARCH}-${TARGET_OS}
 147
 148         case "${TARGET_ARCH}" in
 149                 x86_64 | powerpc | s390)
 150                         sed -i -e "s,\(need_va_copy=\)'undef',\1'define',g" \
 151                                 config.sh-${TARGET_ARCH}-${TARGET_OS}
 152                         ;;
 153                 arm)
 154                         sed -i -e "s,\(d_u32align=\)'undef',\1'define',g" \
 155                                 config.sh-${TARGET_ARCH}-${TARGET_OS}
 156                         ;;
 157         esac
 158
 159         # These are strewn all over the source tree
 160         for foo in `grep -lrI -m1 \/usr\/include\/.*\\.h ${WORKDIR}/*` ; do
 161             echo Fixing: $foo
 162             sed -e "s%/usr/include/%${STAGING_INCDIR}/%g" -i $foo
 163         done
 164
 165         rm -f config
 166         echo "ARCH = ${TARGET_ARCH}" > config
 167         echo "OS = ${TARGET_OS}" >> config
 168 }
 169 do_compile() {
 170         sed -i -e 's|/usr/include|${STAGING_INCDIR}|g' ext/Errno/Errno_pm.PL
 171         cd Cross
 172         oe_runmake perl LD="${CCLD}"
 173 }
 174 do_install() {
 175         oe_runmake install
 176         # Add perl pointing at current version
 177         ln -sf perl${PV} ${D}${bindir}/perl
 178
 179         # Fix up versioned directories
 180         mv ${D}/${libdir}/perl/${PVM} ${D}/${libdir}/perl/${PV}
 181         mv ${D}/${datadir}/perl/${PVM} ${D}/${datadir}/perl/${PV}
 182         ln -sf ${PV} ${D}/${libdir}/perl/${PVM}
 183         ln -sf ${PV} ${D}/${datadir}/perl/${PVM}
 184
 185         # Remove unwanted file
 186         rm -f ${D}/${libdir}/perl/${PV}/.packlist
 187
 188         # Fix up shared library
 189         mv -f ${D}/${libdir}/perl/${PV}/CORE/libperl.so ${D}/${libdir}/libperl.so.${PV}
 190         ln -sf libperl.so.${PV} ${D}/${libdir}/libperl.so.5
 191
 192         # Fix up installed configuration
 193         sed -i -e "s,${D},,g" \
 194                -e "s,-isystem${STAGING_INCDIR} ,,g" \
 195                -e "s,${STAGING_LIBDIR},${libdir},g" \
 196                -e "s,${STAGING_BINDIR},${bindir},g" \
 197                -e "s,${STAGING_INCDIR},${includedir},g" \
 198                -e "s,${TOOLCHAIN_PATH}${base_bindir}/,,g" \
 199             ${D}${bindir}/h2xs \
 200             ${D}${bindir}/h2ph \
 201             ${D}${datadir}/perl/${PV}/pod/*.pod \
 202             ${D}${datadir}/perl/${PV}/cacheout.pl \
 203             ${D}${datadir}/perl/${PV}/FileCache.pm \
 204             ${D}${libdir}/perl/${PV}/Config.pm \
 205             ${D}${libdir}/perl/${PV}/Config_heavy.pl \
 206             ${D}${libdir}/perl/${PV}/CORE/perl.h \
 207             ${D}${libdir}/perl/${PV}/CORE/pp.h
 208 }
 209
 210 do_stage() {
 211         install -d ${STAGING_LIBDIR_NATIVE}/perl/${PV} \
 212                    ${STAGING_LIBDIR}/perl/${PV}/CORE \
 213                    ${STAGING_DATADIR}/perl/${PV}/ExtUtils
 214         # target config, used by cpan.bbclass to extract version information
 215         install config.sh ${STAGING_LIBDIR}/perl/
 216         # target configuration, used by native perl when cross-compiling
 217         install lib/Config_heavy.pl ${STAGING_LIBDIR_NATIVE}/perl/${PV}/Config_heavy-${TARGET_SYS}.pl
 218         sed -r -i \
 219                 -e "s,^(archlib=).*$,\1'${STAGING_LIBDIR}/perl/${PV}'," \
 220                 -e "s,^(archlibexp=).*$,\1'${STAGING_LIBDIR}/perl/${PV}'," \
 221                 -e "s,^(privlib=).*$,\1'${STAGING_DATADIR}/perl/${PV}'," \
 222                 -e "s,^(privlibexp=).*$,\1'${STAGING_DATADIR}/perl/${PV}'," \
 223                 ${STAGING_LIBDIR_NATIVE}/perl/${PV}/Config_heavy-${TARGET_SYS}.pl \
 224                 ${STAGING_LIBDIR}/perl/config.sh
 225         # target configuration
 226         install lib/Config.pm       ${STAGING_LIBDIR}/perl/${PV}/
 227         install lib/ExtUtils/typemap ${STAGING_DATADIR}/perl/${PV}/ExtUtils/
 228         # perl shared library headers
 229         for i in av.h embed.h gv.h keywords.h op.h perlio.h pp.h regexp.h \
 230                  uconfig.h XSUB.h cc_runtime.h embedvar.h handy.h opnames.h \
 231                  perliol.h pp_proto.h regnodes.h unixish.h config.h EXTERN.h \
 232                  hv.h malloc_ctl.h pad.h perlsdio.h proto.h scope.h utf8.h \
 233                  cop.h fakesdio.h INTERN.h mg.h patchlevel.h perlsfio.h \
 234                  reentr.h sv.h utfebcdic.h cv.h fakethr.h intrpvar.h \
 235                  nostdio.h overload.h parser.h perlapi.h perlvars.h util.h \
 236                  dosish.h form.h iperlsys.h opcode.h perl.h perly.h regcomp.h \
 237                  thread.h warnings.h mydtrace.h git_version.h; do
 238             install $i ${STAGING_LIBDIR}/perl/${PV}/CORE
 239         done
 240 }
 241
 242 PACKAGES = "perl-dbg perl perl-misc perl-lib perl-dev perl-pod perl-doc"
 243 FILES_${PN} = "${bindir}/perl ${bindir}/perl${PV}"
 244 FILES_${PN}-lib = "${libdir}/libperl.so* ${libdir}/perl/${PVM} ${datadir}/perl/${PVM} ${datadir}/perl/${PV}/unicore/lib"
 245 FILES_${PN}-dev = "${libdir}/perl/${PV}/CORE"
 246 FILES_${PN}-pod = "${datadir}/perl/${PV}/pod \
 247                    ${datadir}/perl/${PV}/*.pod \
 248                    ${datadir}/perl/${PV}/*/*.pod \
 249                    ${datadir}/perl/${PV}/*/*/*.pod \
 250                    ${libdir}/perl/${PV}/*.pod"
 251 FILES_perl-misc = "${bindir}/*"
 252 FILES_${PN}-dbg += "${libdir}/perl/${PV}/auto/*/.debug \
 253                     ${libdir}/perl/${PV}/auto/*/*/.debug \
 254                     ${libdir}/perl/${PV}/auto/*/*/*/.debug \
 255                     ${datadir}/perl/${PV}/auto/*/.debug \
 256                     ${datadir}/perl/${PV}/auto/*/*/.debug \
 257                     ${datadir}/perl/${PV}/auto/*/*/*/.debug \
 258                     ${libdir}/perl/${PV}/CORE/.debug"
 259 FILES_${PN}-doc = "${datadir}/perl/${PV}/*/*.txt \
 260                    ${datadir}/perl/${PV}/*/*/*.txt \
 261                    ${datadir}/perl/${PV}/B/assemble \
 262                    ${datadir}/perl/${PV}/B/cc_harness \
 263                    ${datadir}/perl/${PV}/B/disassemble \
 264                    ${datadir}/perl/${PV}/B/makeliblinks \
 265                    ${datadir}/perl/${PV}/CGI/eg \
 266                    ${datadir}/perl/${PV}/CPAN/PAUSE2003.pub \
 267                    ${datadir}/perl/${PV}/CPAN/SIGNATURE \
 268                    ${datadir}/perl/${PV}/CPANPLUS/Shell/Default/Plugins/HOWTO.pod \
 269                    ${datadir}/perl/${PV}/Encode/encode.h \
 270                    ${datadir}/perl/${PV}/ExtUtils/MANIFEST.SKIP \
 271                    ${datadir}/perl/${PV}/ExtUtils/NOTES \
 272                    ${datadir}/perl/${PV}/ExtUtils/PATCHING \
 273                    ${datadir}/perl/${PV}/ExtUtils/typemap \
 274                    ${datadir}/perl/${PV}/ExtUtils/xsubpp \
 275                    ${datadir}/perl/${PV}/Net/*.eg \
 276                    ${datadir}/perl/${PV}/unicore/mktables \
 277                    ${datadir}/perl/${PV}/unicore/mktables.lst \
 278                    ${datadir}/perl/${PV}/unicore/version \
 279                    ${datadir}/perl/${PV}/ExtUtils/Changes_EU-Install \
 280 "
 281
 282 RPROVIDES_perl-lib = "perl-lib"
 283
 284 require perl.inc
 285
 286 # Create a perl-modules package recommending all the other perl
 287 # packages (actually the non modules packages and not created too)
 288 ALLOW_EMPTY_perl-modules = "1"
 289 PACKAGES_append = " perl-modules "
 290 RRECOMMENDS_perl-modules = "${@' '.join(all_perl_packages(d))}"
 291
 292 python populate_packages_prepend () {
 293         libdir = bb.data.expand('${libdir}/perl/${PV}', d)
 294         do_split_packages(d, libdir, 'auto/(.*)(?!\.debug)/', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
 295         do_split_packages(d, libdir, '(.*)\.(pm|pl|e2x)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
 296         datadir = bb.data.expand('${datadir}/perl/${PV}', d)
 297         do_split_packages(d, datadir, 'auto/(.*)(?!\.debug)/', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
 298         do_split_packages(d, datadir, '(.*)\.(pm|pl|e2x)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
 299 }
 300
 301 PACKAGES_DYNAMIC = "perl-module-*"
 302 FILES_perl-module-cpan += "${datadir}/perl/${PV}/CPAN"
 303 FILES_perl-module-cpanplus += "${datadir}/perl/${PV}/CPANPLUS"
 304 FILES_perl-module-unicore-name += "${datadir}/perl/${PV}/unicore"
 305
 306 require perl-rdepends_${PV}.inc
 307 require perl-rprovides.inc
 308 require perl-rprovides_${PV}.inc
 309
 310 PARALLEL_MAKE = ""