recipes/pango/pango_1.8.2.bb

   1 LICENSE = "LGPL"
   2 SECTION = "x11/libs"
   3 DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libx11 libxft gtk-doc"
   4 RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc"
   5 DESCRIPTION = "The goal of the Pango project is to provide an \
   6 Open Source framework for the layout and rendering of \
   7 internationalized text."
   8 PR = "r0"
   9
  10 # seems to go wrong with default cflags
  11 FULL_OPTIMIZATION_arm = "-O2"
  12
  13 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.6/pango-${PV}.tar.bz2 \
  14            file://no-tests.patch \
  15            file://pkgconfig_fixes.patch"
  16
  17 inherit autotools pkgconfig
  18
  19 EXTRA_OECONF = "--disable-glibtest \
  20                 --enable-explicit-deps=no \
  21                 --disable-debug"
  22
  23 FILES_${PN} = "/etc ${bindir} ${libdir}/libpango*.so.*"
  24
  25 LIBV = "1.4.0"
  26
  27 do_stage () {
  28         for lib in pango pangox pangoft2 pangoxft; do
  29                 oe_libinstall -so -C pango lib$lib-1.0 ${STAGING_LIBDIR}/
  30         done
  31         install -d ${STAGING_INCDIR}/pango
  32         install -m 0644 ${S}/pango/pango*.h ${STAGING_INCDIR}/pango/
  33 }
  34
  35 postinst_prologue() {
  36 if [ "x$D" != "x" ]; then
  37   exit 1
  38 fi
  39
  40 }
  41
  42 PACKAGES_DYNAMIC = "pango-module-*"
  43
  44 python populate_packages_prepend () {
  45         prologue = bb.data.getVar("postinst_prologue", d, 1)
  46
  47         modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
  48
  49         do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
  50 }
  51
  52 SRC_URI[md5sum] = "f5b5da7a173f0566d8217ec112fde993"
  53 SRC_URI[sha256sum] = "4cf04489ff291f3f1835783b8cfa8347d99f6a05d7d9da21c8d737f441bea3ac"