recipes/p910nd/p910nd_0.95.bb

   1 DESCRIPTION = "A small network printer daemon for embedded situations that passes the job directly to the printer."
   2 SECTION = "console/utils"
   3 HOMEPAGE = "http://p910nd.sourceforge.net/"
   4 LICENSE = "GPLv2"
   5 SECTION = "console/utils"
   6 PR = "r1"
   7 RDEPENDS_${PN}-avahi = "avahi"
   8
   9 inherit update-rc.d
  10
  11 INITSCRIPT_NAME = "p910nd"
  12 INITSCRIPT_PARAMS = "defaults 60 "
  13
  14 SRC_URI = "${SOURCEFORGE_MIRROR}/p910nd/p910nd-${PV}.tar.bz2 \
  15            file://p910nd.init \
  16            file://avahi"
  17
  18 SRC_URI[md5sum] = "c7ac6afdf7730ac8387a8e87198d4491"
  19 SRC_URI[sha256sum] = "7d78642c86dc247fbdef1ff85c56629dcdc6b2a457c786420299e284fffcb029"
  20
  21 PACKAGES_prepend = "${PN}-avahi "
  22
  23 FILES_${PN}-avahi += "${sysconfdir}/avahi/services/p910nd.service"
  24
  25 do_compile () {
  26         ${CC} ${LDFLAGS} -o p910nd p910nd.c
  27 }
  28
  29 # The avahi stuff makes it work with bonjour printing
  30 do_install () {
  31         install -D -m 0755 ${S}/p910nd ${D}${sbindir}/p910nd
  32         install -D -m 0644 ${S}/p910nd.conf ${D}${sysconfdir}/p910nd.conf
  33         install -D -m 0755 ${WORKDIR}/p910nd.init ${D}${sysconfdir}/init.d/p910nd
  34         install -D -m 0755 ${WORKDIR}/avahi ${D}${sysconfdir}/avahi/services/p910nd.service
  35 }
  36
  37 pkg_postinst_${PN}-avahi_append() {
  38 #!/bin/sh
  39
  40 if [ "x$D" != "x" ] ; then
  41         exit 1
  42 fi
  43
  44 # If avahi is already running reload it to pickup the p910nd config
  45 PAV=`pidof avahi-daemon`
  46 if [ "x$PAV" != "x" ] ; then
  47         /etc/init.d/avahi-daemon reload
  48 fi
  49 }