recipes/lirc/lirc_0.8.7.bb

   1 DESCRIPTION = "LIRC is a package that allows you to decode and send infra-red signals of many commonly used remote controls."
   2 DESCRIPTION_append_lirc = " This package contains the lirc daemon, libraries and tools."
   3 DESCRIPTION_append_lirc-x = " This package contains lirc tools for X11."
   4 DESCRIPTION_append_lirc-exec = " This package contains a daemon that runs programs on IR signals."
   5 DESCRIPTION_append_lirc-remotes = " This package contains some config files for remotes."
   6 DESCRIPTION_append_lirc-nslu2example = " This package contains a working config for RC5 remotes and a modified NSLU2."
   7 SECTION = "console/network"
   8 PRIORITY = "optional"
   9 HOMEPAGE = "http://www.lirc.org"
  10 LICENSE = "GPL"
  11 DEPENDS = "virtual/kernel virtual/libx11 libxau libsm libice"
  12 DEPENDS_nslu2 = "virtual/kernel lirc-modules"
  13 RDEPENDS_${PN} = "lirc-modules"
  14 RDEPENDS_lirc-x = "lirc"
  15 RDEPENDS_lirc-exec = "lirc"
  16 RDEPENDS_lirc-nslu2example = "lirc lirc-exec"
  17 RRECOMMENDS_lirc = "lirc-exec"
  18 PR = "r0"
  19
  20 inherit autotools module-base update-rc.d
  21 SRC_URI_append = " file://lircd.init \
  22                    file://lircmd.init \
  23                    file://lircexec.init \
  24                  "
  25 SRC_URI_append_nslu2 = " file://lircd.conf_nslu2 \
  26                          file://lircrc_nslu2 \
  27                        "
  28
  29 INITSCRIPT_PACKAGES = "lirc lirc-exec"
  30 INITSCRIPT_NAME = "lircd"
  31 INITSCRIPT_PARAMS = "defaults 20"
  32 INITSCRIPT_NAME_lirc-exec = "lircexec"
  33 INITSCRIPT_PARAMS_lirc-exec = "defaults 21"
  34
  35 require lirc-config.inc
  36
  37 EXTRA_OEMAKE = 'SUBDIRS="daemons tools"'
  38
  39 do_install_append() {
  40         install -d ${D}${sysconfdir}/init.d
  41         install ${WORKDIR}/lircd.init ${D}${sysconfdir}/init.d/lircd
  42         install ${WORKDIR}/lircexec.init ${D}${sysconfdir}/init.d/lircexec
  43         install -d ${D}${datadir}/lirc/
  44         cp -pPR ${S}/remotes ${D}${datadir}/lirc/
  45         rm -rf ${D}/dev
  46 }
  47
  48 do_install_append_nslu2() {
  49         install -d ${D}${sysconfdir}
  50         install ${WORKDIR}/lircd.conf_nslu2 ${D}${sysconfdir}/lircd.conf
  51         install ${WORKDIR}/lircrc_nslu2 ${D}${sysconfdir}/lircrc
  52 }
  53
  54 PACKAGES =+ "lirc-x lirc-exec lirc-remotes"
  55 PACKAGES_prepend_nslu2 = "lirc-nslu2example "
  56
  57 FILES_${PN}-dbg += "${bindir}/.debug ${sbindir}/.debug"
  58 FILES_${PN}-dev += "${libdir}/liblirc_client.so"
  59 FILES_${PN} = "${bindir} ${sbindir} ${libdir} ${sysconfdir} ${exec_prefix}/var"
  60 FILES_lirc-x = "${bindir}/irxevent ${bindir}/xmode2"
  61 FILES_lirc-exec = "${bindir}/irexec ${sysconfdir}/init.d/lircexec"
  62 FILES_lirc-remotes = "${datadir}/lirc/remotes"
  63 FILES_lirc-nslu2example = "${sysconfdir}/lircd.conf ${sysconfdir}/lircrc"
  64 CONFFILES_lirc-nslu2example = "${FILES_lirc-nslu2example}"