recipes/cmake/cmake_2.8.3.bb

   1 require cmake.inc
   2
   3 PR = "${INC_PR}.1"
   4
   5 inherit cmake
   6
   7 DEPENDS += "curl expat zlib libarchive ncurses"
   8
   9 SRC_URI[md5sum] = "a76a44b93acf5e3badda9de111385921"
  10 SRC_URI[sha256sum] = "689ed02786b5cefa5515c7716784ee82a82e8ece6be5a3d629ac3cc0c05fc288"
  11
  12 SRC_URI += "file://dont-run-cross-binaries.patch"
  13
  14 # Strip ${prefix} from ${docdir}, set result into docdir_stripped
  15 python () {
  16     prefix=bb.data.getVar("prefix", d, 1)
  17     docdir=bb.data.getVar("docdir", d, 1)
  18
  19     if not docdir.startswith(prefix):
  20         raise bb.build.FuncFailed('docdir must contain prefix as its prefix')
  21
  22     docdir_stripped = docdir[len(prefix):]
  23     if len(docdir_stripped) > 0 and docdir_stripped[0] == '/':
  24         docdir_stripped = docdir_stripped[1:]
  25
  26     bb.data.setVar("docdir_stripped", docdir_stripped, d)
  27 }
  28
  29 EXTRA_OECMAKE=" \
  30 # Override default "doc" (this is relative to ${prefix})
  31     -DCMAKE_DOC_DIR=${docdir_stripped}/cmake-2.8 \
  32 # Using system libs spares us some cmake cross trouble.
  33     -DCMAKE_USE_SYSTEM_LIBRARIES=1 \
  34 # This is compiler & target dependant, but it seems cmake does not in fact use this value.
  35     -DKWSYS_CHAR_IS_SIGNED=1 \
  36 # This disables large file support. Hopefully nobody processes >2G files on the target.
  37 # If you want to enable this, add -DWKSYS_LFS_WORKS=1
  38     -DKWSYS_LFS_DISABLE=1 \
  39 "
  40
  41 FILES_${PN} += "${datadir}/cmake-2.8"
  42
  43 # The doc is quite... absent. Just the licensing information is there.
  44 # Real doc was nuked by dont-run-cross-binaries.patch. Fixing the doc
  45 # generation would be quite complicated, as cmake build process innovatively
  46 # runs the generated binaries to extract help contained in them.
  47 # -> Fixing this is probably not worth it.
  48 FILES_${PN}-doc += "${docdir}/cmake-2.8"