recipes/rxvt-unicode/rxvt-unicode_5.4.bb

   1 SECTION = "x11/utils"
   2 DEPENDS = "virtual/libx11 libxt libxft"
   3 DESCRIPTION = "rxvt-unicode is a clone of the well known \
   4 terminal emulator rxvt, modified to store text in Unicode \
   5 (either UCS-2 or UCS-4) and to use locale-correct input and \
   6 output. It also supports mixing multiple fonts at the \
   7 same time, including Xft fonts."
   8 LICENSE = "GPL"
   9 SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
  10            file://xwc.patch \
  11            file://signedchar.patch"
  12 PR = "r2"
  13
  14 inherit autotools update-alternatives
  15
  16 PROVIDES = "virtual/x-terminal-emulator"
  17 ALTERNATIVE_NAME = "x-terminal-emulator"
  18 ALTERNATIVE_PATH = "${bindir}/rxvt"
  19
  20 CFLAGS_append = " -fpermissive"
  21
  22 EXTRA_OECONF = "--enable-menubar --enable-xim \
  23                 --enable-utmp --enable-wtmp --enable-lastlog \
  24                 --disable-strings --with-term=rxvt --enable-keepscrolling \
  25                 --enable-xft --with-name=rxvt --enable-frills \
  26                 --enable-swapscreen --enable-transparency \
  27                 --with-codesets=eu \
  28                 --enable-cursor-blink --enable-pointer-blank \
  29                 --enable-text-blink --enable-rxvt-scroll \
  30                 --enable-combining --enable-shared \
  31                 --enable-xgetdefault \
  32                 --with-x=${STAGING_LIBDIR}/.."
  33 EXTRA_OEMAKE = "'XINC=-I${STAGING_INCDIR}' \
  34                 'XLIB=-L${STAGING_LIBDIR} -lX11'"
  35
  36 do_configure () {
  37         mv autoconf/configure.in . || true
  38         rm autoconf/libtool.m4
  39         libtoolize --force
  40         autotools_do_configure
  41         echo '#define RXVT_UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
  42         echo '#define RXVT_WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
  43         echo '#define RXVT_LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
  44         echo '#define HAVE_XLOCALE 1' >> config.h
  45 }
  46
  47 do_compile () {
  48         if test -e ${S}/${HOST_SYS}-libtool; then
  49                 LIBTOOL=${S}/${HOST_SYS}-libtool
  50         else
  51                 LIBTOOL=${S}/libtool
  52         fi
  53         # docs need "yodl" and I have no idea what that is
  54         oe_runmake -C src "LIBTOOL=$LIBTOOL"
  55 }
  56
  57 SRC_URI[md5sum] = "7efde6ec77c0ee47a32bd2f447d2937a"
  58 SRC_URI[sha256sum] = "0b9018e30281290cfdacf89f1680b6b0e961e47aab66fbb65c15a31d85ca473a"