recipes/linux/opensimpad_2.4.25-vrs2-pxa1-jpm1.bb

   1 DESCRIPTION = "Linux kernel for the SIEMENS SIMpad family of devices."
   2 SECTION = "kernel"
   3 LICENSE = "GPLv2"
   4 KV = "${@bb.data.getVar('PV',d,True).split('-')[0]}"
   5 VRSV = "${@bb.data.getVar('PV',d,True).split('-')[1]}"
   6 PXAV = "${@bb.data.getVar('PV',d,True).split('-')[2]}"
   7 JPMV = "${@bb.data.getVar('PV',d,True).split('-')[3]}"
   8 PR = "r22"
   9
  10 COMPATIBLE_MACHINE = 'simpad'
  11
  12 FILESPATHPKG =. "opensimpad-${PV}:opensimpad:"
  13
  14 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.4/linux-${KV}.tar.bz2;name=kernel \
  15            file://${KV}-${VRSV}.patch \
  16            file://${KV}-${VRSV}-${PXAV}.patch \
  17            file://${KV}-${VRSV}-${PXAV}-${JPMV}.patch \
  18            file://sound-volume-reversed.patch \
  19            file://disable-pcmcia-probe.patch \
  20            file://mkdep.patch \
  21            file://defconfig-${MACHINE} \
  22            http://www.openswan.org/download/old/openswan-2.2.0-kernel-2.4-klips.patch.gz;name=patch \
  23            file://mipv6-1.1-v2.4.25.patch \
  24            file://simpad-backlight-if.patch \
  25            file://simpad-switches-input.patch \
  26            file://simpad-switches-input2.patch \
  27            file://simpad-apm.diff;striplevel=0 \
  28            file://simpad-ts-noninput.patch \
  29            file://simpad-pm-updates.patch;striplevel=0 \
  30            file://support-128mb-ram.patch \
  31            file://mmc-spi.patch \
  32            file://iw249_we17-13.diff \
  33            file://iw240_we18-5.diff \
  34 "
  35
  36 S = "${WORKDIR}/linux-${KV}"
  37
  38 inherit kernel
  39
  40 KERNEL_CCSUFFIX = "-3.3.4"
  41 COMPATIBLE_HOST = "arm.*-linux"
  42
  43 SIMPAD_MEM     = '${@bb.data.getVar("SIMPAD_MEMORY_SIZE",d,1)  or "32"}'
  44 SIMPAD_RD      = '${@bb.data.getVar("SIMPAD_RAMDISK_SIZE",d,1) or "32"}'
  45 export CMDLINE = '${@bb.data.getVar("SIMPAD_CMDLINE",d,1) or  "mtdparts=sa1100:512k(boot),1m(kernel),14848k(root),-(home) console=ttySA root=1f02 noinitrd jffs2_orphaned_inodes=delete rootfstype=jffs2 "}'
  46 EXTRA_OEMAKE = ""
  47
  48 module_conf_sa1100_ir = "alias irda0 sa1100_ir"
  49
  50 do_configure() {
  51         install -m 0644 ${WORKDIR}/defconfig-${MACHINE} ${S}/.config || die "No default configuration for ${MACHINE} available."
  52
  53         mem=${SIMPAD_MEM}
  54         rd=${SIMPAD_RD}
  55         mempos=`echo "obase=16; $mem * 1024 * 1024" | bc`
  56         rdsize=`echo "$rd * 1024" | bc`
  57         total=`expr $mem + $rd`
  58         addr=`echo "obase=16; ibase=16; C0000000 + $mempos" | bc`
  59
  60         if [ "$rd" == "0" ]
  61         then
  62                 echo "# CONFIG_MTD_MTDRAM is not set" >> ${S}/.config
  63         else
  64                 echo "CONFIG_MTD_MTDRAM=y"           >> ${S}/.config
  65                 echo "CONFIG_MTDRAM_TOTAL_SIZE=$rdsize"     >> ${S}/.config
  66                 echo "CONFIG_MTDRAM_ERASE_SIZE=1"           >> ${S}/.config
  67                 echo "CONFIG_MTDRAM_ABS_POS=$addr"          >> ${S}/.config
  68         fi
  69         if [ "$total" == "128" ]
  70         then
  71                 echo "CCONFIG_SA1100_SIMPAD_128M=y"           >> ${S}/.config
  72         else
  73                 echo "# CONFIG_SA1100_SIMPAD_128M is not set" >> ${S}/.config
  74         fi
  75         if [ "$total" == "32" ]
  76         then
  77                 echo "CONFIG_SA1100_SIMPAD_SINUSPAD=y"            >> ${S}/.config
  78         else
  79                 echo "# CONFIG_SA1100_SIMPAD_SINUSPAD is not set" >> ${S}/.config
  80         fi
  81         echo "CONFIG_CMDLINE=\"${CMDLINE} mem=${mem}M\"" >> ${S}/.config
  82         oe_runmake oldconfig
  83 }
  84 SRC_URI[kernel.md5sum] = "5fc8e9f43fa44ac29ddf9a9980af57d8"
  85 SRC_URI[kernel.sha256sum] = "877af8ed89e56af004bb0662c1a9cfc785b40c602f71a8bf81521991026cf2f0"
  86 SRC_URI[patch.md5sum] = "5c54040bba6fea2bfb47df01056e953f"
  87 SRC_URI[patch.sha256sum] = "d35213dc854f1e1a08512154c7a92fb94d9f0506cc5107f8b2f248412679fb53"