recipes/linux/linux_2.6.23+2.6.24-rc5.bb

   1 require linux.inc
   2
   3 # Mark archs/machines that this kernel supports
   4 DEFAULT_PREFERENCE = "-1"
   5
   6 PR = "r3"
   7
   8 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-2.6.23.tar.bz2;name=kernel \
   9            ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/testing/v2.6.24/patch-2.6.24-rc5.bz2;apply=yes;name=patch \
  10            file://defconfig \
  11            "
  12
  13 S = "${WORKDIR}/linux-2.6.23"
  14
  15 SRC_URI_append_cm-x270 = "\
  16         file://0001-cm-x270-match-type.patch \
  17         file://0002-ramdisk_load.patch \
  18         file://0003-mmcsd_large_cards-r0.patch \
  19         file://0004-cm-x270-nand-simplify-name.patch \
  20         file://0005-cmx270-pci.patch"
  21
  22 SRC_URI_append_gesbc-9302 = "file://0001-gesbc-nand.patch"
  23
  24 CMDLINE_cm-x270 = "console=${CMX270_CONSOLE_SERIAL_PORT},38400 monitor=8 bpp=16 mem=64M mtdparts=physmap-flash.0:256k(boot)ro,0x180000(kernel),-(root);cm-x270-nand:64m(app),-(data) rdinit=/sbin/init root=mtd3 rootfstype=jffs2"
  25
  26 CMDLINE_gesbc-9302 = "console=ttyAM0 root=/dev/ram"
  27
  28 FILES_kernel-image_cm-x270 = ""
  29 FILES_kernel-image_gesbc-9302 = ""
  30
  31 python do_compulab_image() {
  32         import os
  33         import os.path
  34         import struct
  35
  36         machine = bb.data.getVar('MACHINE', d, 1)
  37         if machine == "cm-x270":
  38             deploy_dir = bb.data.getVar('DEPLOY_DIR_IMAGE', d, 1)
  39             kernel_file = os.path.join(deploy_dir, bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.bin')
  40             img_file = os.path.join(deploy_dir, bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.cmx270')
  41
  42             fo = open(img_file, 'wb')
  43
  44             image_data = open(kernel_file, 'rb').read()
  45
  46             # first write size into first 4 bytes
  47             size_s = struct.pack('i', len(image_data))
  48
  49             # truncate size if we are running on a 64-bit host
  50             size_s = size_s[:4]
  51
  52             fo.write(size_s)
  53             fo.write(image_data)
  54             fo.close()
  55
  56             os.chdir(deploy_dir)
  57             link_file = bb.data.expand('${KERNEL_IMAGE_SYMLINK_NAME}', d) + '.cmx270'
  58             img_file = bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.cmx270'
  59             try:
  60                 os.unlink(link_file)
  61             except:
  62                 pass
  63             os.symlink(img_file, link_file)
  64 }
  65
  66 addtask compulab_image after do_deploy before do_build
  67
  68 SRC_URI[kernel.md5sum] = "2cc2fd4d521dc5d7cfce0d8a9d1b3472"
  69 SRC_URI[kernel.sha256sum] = "d4e67c0935ffb2a4158234bff92cc791b83177866009fc9b2214104e0038dbdb"
  70 SRC_URI[patch.md5sum] = "ae984c2ba6bf54e3f7d139c197563792"
  71 SRC_URI[patch.sha256sum] = "fc8edda5992a3d45bb0b2cfbad9c9a683f74be110f8d767745182c49a86072fd"