recipes/gstreamer/gst-plugins-package.inc

   1 LIBV = "0.10"
   2
   3 python populate_packages_prepend () {
   4         gst_libdir = bb.data.expand('${libdir}/gstreamer-${LIBV}', d)
   5         postinst = bb.data.getVar('plugin_postinst', d, 1)
   6         glibdir = bb.data.expand('${libdir}', d)
   7
   8         do_split_packages(d, glibdir, '^lib(.*)\.so\.*', 'lib%s', 'gstreamer %s library', extra_depends='', allow_links=True)
   9         do_split_packages(d, gst_libdir, '^libgst(.*)\.so$', 'gst-plugin-%s', 'GStreamer plugin for %s', postinst=postinst, extra_depends='')
  10         do_split_packages(d, gst_libdir, '^libgst(.*)\.l?a$', 'gst-plugin-%s-dev', 'GStreamer plugin for %s (development files)', extra_depends='')
  11
  12         pn = bb.data.getVar('PN', d, 1)
  13         metapkg =  pn + '-meta'
  14         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
  15         bb.data.setVar('FILES_' + metapkg, "", d)
  16         blacklist = [ pn + '-locale', pn + '-dev', pn + '-dbg', pn + '-doc' ]
  17         metapkg_rdepends = []
  18         packages = bb.data.getVar('PACKAGES', d, 1).split()
  19         for pkg in packages[1:]:
  20                 if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.count('locale') and not pkg.count('-static'):
  21                         metapkg_rdepends.append(pkg)
  22         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
  23         bb.data.setVar('DESCRIPTION_' + metapkg, pn + ' meta package', d)
  24         packages.append(metapkg)
  25         bb.data.setVar('PACKAGES', ' '.join(packages), d)
  26
  27 }
  28
  29 ALLOW_EMPTY = "1"
  30
  31 PACKAGES += "${PN}-apps"
  32 FILES_${PN}-apps = "${bindir}"
  33
  34 FILES_${PN} = "${datadir}/gstreamer-0.10"
  35 FILES_${PN}-dbg += "${libdir}/gstreamer-${LIBV}/.debug"
  36
  37