recipes/ti/ti-dmai_svn.bb

   1 require ti-dmai.inc
   2 require ti-paths.inc
   3
   4 inherit module-base
   5
   6 #This is a kernel module, don't set PR directly
   7 MACHINE_KERNEL_PR_append = "b"
   8
   9 # compile time dependencies
  10 DEPENDS_omap3evm  += "alsa-lib ti-codec-engine ti-xdctools-native ti-dspbios-native ti-cgt6x-native ti-cs1-omap3530 virtual/kernel ti-dsplink-module"
  11 DEPENDS_armv7a  += "alsa-lib  ti-codec-engine ti-xdctools-native ti-dspbios-native ti-cgt6x-native ti-cs1-omap3530 virtual/kernel ti-dsplink-module "
  12 DEPENDS_dm6446-evm      += "alsa-lib  ti-codec-engine ti-xdctools-native ti-dspbios-native ti-cgt6x-native ti-codec-combo-dm6446 virtual/kernel ti-dsplink-module "
  13 DEPENDS_dm355-evm       += "alsa-lib ti-codec-engine ti-xdctools-native ti-codec-combo-dm355 virtual/kernel"
  14 DEPENDS_da830-omapl137-evm      += "alsa-lib  ti-codec-engine ti-xdctools-native ti-dspbios-native ti-cgt6x-native ti-codec-combo-omapl137 virtual/kernel ti-dsplink-module "
  15
  16 # Define DMAI build time variables
  17 TARGET                  ?= "all"
  18 TARGET_armv7a   ?= "o3530_al"
  19 TARGET_dm355-evm        ?= "dm355_al"
  20 TARGET_dm6446-evm       ?= "dm6446_al"
  21 TARGET_da830-omapl137-evm       ?= "ol137_al"
  22
  23 DSPBIOS_DIR = "${STAGING_DIR_NATIVE}/ti-dspbios-native"
  24 CGT6x_DIR = "${STAGING_DIR_NATIVE}/ti-cgt6x-native"
  25 XDCTOOLS_DIR = "${STAGING_DIR_NATIVE}/ti-xdctools-native"
  26 USER_XDC_PATH = "${CE_INSTALL_DIR}/examples"
  27
  28 PARALLEL_MAKE = ""
  29
  30 do_configure () {
  31
  32         # PSP kernel is based on older DSS. we need to replace linux/omapfb.h with
  33         # mach/omapfb.h
  34
  35     if [ ${MACHINE} == "omap3evm" ] ; then
  36         sed -i -e s:linux/omapfb:mach/omapfb:g ${S}/dmai/packages/ti/sdo/dmai/linux/Display_fbdev.c
  37         sed -i -e s:linux/omapfb:mach/omapfb:g ${S}/dmai/packages/ti/sdo/dmai/linux/priv/_Display.h
  38     fi
  39 }
  40
  41
  42 do_compile () {
  43
  44         unset DMAI_INSTALL_DIR
  45         cd ${S}
  46         make XDC_INSTALL_DIR="${XDCTOOLS_DIR}" clean
  47
  48         #  TODO: Figure out how to pass the alsa include location, currently
  49     #  LINUXLIBS_INSTALL_DIR is hard-coded for armv5te
  50         make CE_INSTALL_DIR="${CE_INSTALL_DIR}" \
  51                 CODEC_INSTALL_DIR="${CODEC}" \
  52                 FC_INSTALL_DIR="${FC_INSTALL_DIR}" \
  53                 LINUXKERNEL_INSTALL_DIR="${STAGING_KERNEL_DIR}" \
  54                 XDC_INSTALL_DIR="${XDCTOOLS_DIR}" \
  55                 CODEGEN_INSTALL_DIR="${CGT6x_DIR}" \
  56                 BIOS_INSTALL_DIR="${DSPBIOS_DIR}"\
  57                 LINUXLIBS_INSTALL_DIR="${STAGING_DIR_HOST}/usr" \
  58                 USER_XDC_PATH="${USER_XDC_PATH}" \
  59                 CROSS_COMPILE="${CROSS_DIR}/bin/${TARGET_PREFIX}" \
  60                 VERBOSE="true" \
  61                 XDAIS_INSTALL_DIR="${CE_INSTALL_DIR}/cetools" \
  62                 LINK_INSTALL_DIR="${LINK_INSTALL_DIR}" \
  63                 CMEM_INSTALL_DIR="${CE_INSTALL_DIR}/cetools" \
  64                 LPM_INSTALL_DIR="${CE_INSTALL_DIR}/cetools" \
  65                 PLATFORM="${TARGET}"
  66 }
  67
  68 do_install () {
  69         unset DMAI_INSTALL_DIR
  70         # install dmai apps on target
  71     cd ${S}/dmai
  72     make PLATFORM="${TARGET}" EXEC_DIR=${D}/${installdir}/dmai-apps install
  73         install -m 0755 ${WORKDIR}/loadmodules-ti-dmai-${TARGET}.sh ${D}/${installdir}/dmai-apps/loadmodule.sh
  74
  75     cd ${S}/tests
  76     make PLATFORM="${TARGET}" EXEC_DIR=${D}/${installdir}/dmai-tests install
  77         install -m 0755 ${WORKDIR}/loadmodules-ti-dmai-${TARGET}.sh ${D}/${installdir}/dmai-tests/loadmodule.sh
  78 }
  79
  80 pkg_postinst_ti-dmai-apps () {
  81         ln -sf ${installdir}/codec-combo/* ${installdir}/dmai-apps/
  82 }
  83
  84 do_stage () {
  85         install -d ${DMAI_INSTALL_DIR}
  86         cp -pPrf ${S}/dmai/* ${DMAI_INSTALL_DIR}
  87 }
  88
  89 # Disable QA check untils we figure out how to pass LDFLAGS in build
  90 INSANE_SKIP_${PN} = True
  91 INSANE_SKIP_ti-dmai-apps = True
  92 INSANE_SKIP_ti-dmai-tests = True
  93
  94 PACKAGE_ARCH = "${MACHINE_ARCH}"
  95 INHIBIT_PACKAGE_STRIP = "1"
  96 PACKAGES += "ti-dmai-apps ti-dmai-tests"
  97 FILES_ti-dmai-apps = "${installdir}/dmai-apps/*"
  98 FILES_ti-dmai-tests = "${installdir}/dmai-tests/*"
  99
 100 # run time dependencies
 101 RDEPENDS_ti-dmai-apps_dm355-evm += "ti-dm355mm-module ti-cmem-module ti-codec-combo-dm355"
 102 RDEPENDS_ti-dmai-apps_dm6446-evm += "ti-cmem-module ti-dsplink-module ti-codec-combo-dm6446"
 103 RDEPENDS_ti-dmai-apps_omap3evm += "ti-cmem-module ti-dsplink-module ti-cs1-omap3530 ti-lpm-module ti-sdma-module"
 104 RDEPENDS_ti-dmai-apps_armv7a += "ti-cmem-module ti-dsplink-module ti-cs1-omap3530 ti-lpm-module ti-sdma-module"
 105 RDEPENDS_ti-dmai-apps_da830-omapl137-evm += "ti-cmem-module ti-dsplink-module ti-codec-combo-ol137"
 106