conf/bitbake.conf

   1 ##################################################################
   2 # Recipe Parsing
   3 ##################################################################
   4 BBMASK = "/(nonworking|obsolete)/"
   5
   6 ##################################################################
   7 # Standard target filesystem layout.
   8 ##################################################################
   9
  10 # Path prefixes
  11 layout_prefix = "${prefix}"
  12 layout_exec_prefix = "${exec_prefix}"
  13 layout_base_prefix = "${base_prefix}"
  14
  15 # Base paths
  16 layout_base_bindir = "${base_bindir}"
  17 layout_base_sbindir = "${base_sbindir}"
  18 layout_base_libdir = "${base_libdir}"
  19
  20 # Architecture independent paths
  21 layout_sysconfdir = "${sysconfdir}"
  22 layout_localstatedir = "${localstatedir}"
  23 layout_servicedir = "${servicedir}"
  24 layout_sharedstatedir = "${sharedstatedir}"
  25 layout_datadir = "${datadir}"
  26 layout_infodir = "${infodir}"
  27 layout_mandir = "${mandir}"
  28 layout_docdir = "${docdir}"
  29
  30 # Architecture dependent paths
  31 layout_bindir = "${bindir}"
  32 layout_sbindir = "${sbindir}"
  33 layout_libdir = "${libdir}"
  34 layout_includedir = "${includedir}"
  35 layout_libexecdir = "${libexecdir}"
  36
  37 ##################################################################
  38 # Standard target filesystem paths.
  39 ##################################################################
  40
  41 # Path prefixes
  42 export base_prefix = ""
  43 export prefix = "/usr"
  44 export exec_prefix = "/usr"
  45
  46 # Base paths
  47 export base_bindir = "${base_prefix}/bin"
  48 export base_sbindir = "${base_prefix}/sbin"
  49 export base_libdir = "${base_prefix}/lib"
  50
  51 # Architecture independent paths
  52 export datadir = "${prefix}/share"
  53 export sysconfdir = "${base_prefix}/etc"
  54 export servicedir = "${base_prefix}/srv"
  55 export sharedstatedir = "${base_prefix}/com"
  56 export localstatedir = "${base_prefix}/var"
  57 export infodir = "${datadir}/info"
  58 export mandir = "${datadir}/man"
  59 export docdir = "${datadir}/doc"
  60
  61 # Architecture dependent paths
  62 export bindir = "${exec_prefix}/bin"
  63 export sbindir = "${exec_prefix}/sbin"
  64 export libexecdir = "${exec_prefix}/libexec"
  65 export libdir = "${exec_prefix}/lib"
  66 export includedir = "${exec_prefix}/include"
  67 export oldincludedir = "${exec_prefix}/include"
  68
  69 #
  70 # These must match the various bbclass layout definitions
  71 #
  72 base_bindir_native = "/bin"
  73 base_sbindir_native = "/sbin"
  74 sysconfdir_native = "/etc"
  75 base_libdir_native = "/lib"
  76 prefix_native = "/usr"
  77 bindir_native = "${prefix_native}/bin"
  78 sbindir_native = "${prefix_native}/sbin"
  79 includedir_native = "${prefix_native}/include"
  80 libdir_native = "${prefix_native}/lib"
  81 datadir_native = "${prefix_native}/share"
  82 bindir_cross = "/bin"
  83
  84 #
  85 # Cross recipes need to know about the target layout
  86 # := is used carefully here
  87 #
  88 target_datadir := "${datadir}"
  89
  90 ##################################################################
  91 # Architecture-dependent build variables.
  92 ##################################################################
  93
  94 BUILD_ARCH := "${@os.uname()[4]}"
  95 BUILD_OS := "${@os.uname()[0].lower()}"
  96 BUILD_VENDOR = ""
  97 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  98 BUILD_PREFIX = ""
  99 BUILD_CC_ARCH = ""
 100 BUILD_EXEEXT = ""
 101
 102 HOST_ARCH = "${TARGET_ARCH}"
 103 HOST_OS = "${TARGET_OS}"
 104 HOST_VENDOR = "${TARGET_VENDOR}"
 105 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
 106 HOST_PREFIX = "${TARGET_PREFIX}"
 107 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
 108 HOST_EXEEXT = ""
 109
 110 TARGET_ARCH ?= "INVALID"
 111 TARGET_OS = "INVALID"
 112 TARGET_VENDOR = "${BUILD_VENDOR}"
 113 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
 114 TARGET_PREFIX = "${TARGET_SYS}-"
 115 TARGET_CC_ARCH = ""
 116 TARGET_EXEEXT = ""
 117
 118 SDK_ARCH ?= "${BUILD_ARCH}"
 119 SDK_OS ?= "${BUILD_OS}"
 120 SDK_VENDOR ?= "${BUILD_VENDOR}"
 121 SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + bb.data.getVar('SDK_OS', d, 1), ''][bb.data.getVar('SDK_OS', d, 1) == ('' or 'custom')]}"
 122 SDK_PREFIX = "${SDK_SYS}-"
 123 SDK_CC_ARCH ?= "${BUILD_CC_ARCH}"
 124 SDK_EXEEXT = ""
 125
 126 # A shortcut for the commonly used value
 127 EXEEXT = "${HOST_EXEEXT}"
 128
 129 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
 130 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
 131 PACKAGE_EXTRA_ARCHS ?= ""
 132 MACHINE_ARCH = "${@oe.utils.ifelse(bool(d.getVar('MACHINE', True)), '${MACHINE}', \
 133                                    'BASE_PACKAGE_ARCH')}"
 134 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
 135
 136 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
 137 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 138 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
 139 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
 140 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 141
 142 # select proper CPU to get binary locales generated
 143 QEMU_OPTIONS = ""
 144 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 145 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 146 QEMU_OPTIONS_armv6-novfp = "-cpu arm1136"
 147 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 148
 149 ##################################################################
 150 # Date/time variables.
 151 ##################################################################
 152
 153 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 154 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 155 DATETIME = "${DATE}${TIME}"
 156
 157 ##################################################################
 158 # Openembedded Software Prerequisites.
 159 ##################################################################
 160
 161 # python-native should be here but python relies on building
 162 # its own in staging
 163 ASSUME_PROVIDED = "\
 164     bc-native \
 165     bzip2-native \
 166     cvs-native \
 167     diffstat-native \
 168     patch-native \
 169     perl-native-runtime \
 170     python-native-runtime \
 171     svn-native \
 172     texinfo-native \
 173     util-linux-native \
 174     "
 175
 176 ##################################################################
 177 # Package default variables.
 178 ##################################################################
 179 PN = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[0] or 'defaultpkgname'}"
 180 PV = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[1] or '1.0'}"
 181 PR = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[2] or 'r0'}"
 182 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 183 PE ?= "0"
 184 EXTENDPE = "${@int('${PE}') and '${PE}_' or ''}"
 185 EXTENDPEVER = "${@int('${PE}') and '${PE}:' or ''}"
 186 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 187 P = "${PN}-${PV}"
 188
 189 # Define a PR for kernels that machines can override so things like
 190 # modules get rebuilt
 191 MACHINE_KERNEL_PR = ""
 192
 193 # Base package name
 194 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 195 # otherwise it is the same as PN and P
 196 SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -nativesdk -crosssdk -cross-canadian -sdk"
 197 BPN = "${@base_prune_suffix('${PN}', '${SPECIAL_PKGSUFFIX}'.split(), d)}"
 198 BP = "${BPN}-${PV}"
 199
 200 # Package info.
 201
 202 SECTION = "base"
 203 PRIORITY = "optional"
 204 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 205 LICENSE = "unknown"
 206 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 207 HOMEPAGE = "unknown"
 208
 209 # Package dependencies and provides.
 210
 211 # Ensure that -dev packages recommend the corresponding -dev packages of their
 212 # deps, and the same for -dbg.
 213 DEPCHAIN_PRE  = ""
 214 DEPCHAIN_POST = "-dev -dbg"
 215
 216 DEPENDS = ""
 217 RDEPENDS = ""
 218 PROVIDES = ""
 219 PROVIDES_prepend = "${P} ${PF} ${PN} "
 220 RPROVIDES = ""
 221
 222 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 223
 224 SOLIBS = ".so.*"
 225 SOLIBS_darwin = ".*.dylib"
 226 SOLIBS_darwin8 = ".*.dylib"
 227 SOLIBS_darwin9 = ".*.dylib"
 228
 229 SOLIBSDEV = ".so"
 230 SOLIBSDEV_darwin = ".dylib"
 231 SOLIBSDEV_darwin8 = ".dylib"
 232 SOLIBSDEV_darwin9 = ".dylib"
 233
 234 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-static ${PN}-locale"
 235 #enable this when bitbake is upgraded to cope with ++ values in the field
 236 PACKAGES_DYNAMIC = "${PN}-locale-*"
 237 FILES = ""
 238
 239 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
 240             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 241             ${base_bindir}/* ${base_sbindir}/* \
 242             ${base_libdir}/*${SOLIBS} \
 243             ${datadir}/${PN} ${libdir}/${PN}/* \
 244             ${datadir}/pixmaps ${datadir}/applications \
 245             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 246             ${libdir}/bonobo/servers"
 247
 248 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 249             ${datadir}/gnome/help"
 250 SECTION_${PN}-doc = "doc"
 251
 252 FILES_${PN}-static = "${libdir}/*.a ${base_libdir}/*.a"
 253
 254 FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
 255                 ${libdir}/*.o ${libdir}/pkgconfig \
 256                 ${base_libdir}/*.o ${datadir}/aclocal ${datadir}/pkgconfig"
 257 SECTION_${PN}-dev = "devel"
 258 ALLOW_EMPTY_${PN}-dev = "1"
 259 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 260
 261 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 262             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 263             ${libdir}/matchbox-panel/.debug ${datadir}/gdb/autoload"
 264 SECTION_${PN}-dbg = "devel"
 265 ALLOW_EMPTY_${PN}-dbg = "1"
 266 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 267
 268 FILES_${PN}-locale = "${datadir}/locale"
 269
 270 # file:// search paths
 271 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 272 FILESPATHBASE = "${FILE_DIRNAME}"
 273 FILESPATHPKG = "${PF}:${P}:${PN}:${BP}:${BPN}:files:."
 274 FILESPATH = "${@':'.join([os.path.normpath(os.path.join(fp, p, o)) for fp in d.getVar('FILESPATHBASE', 1).split(':') for p in d.getVar('FILESPATHPKG', 1).split(':') for o in (d.getVar('OVERRIDES', 1) + ':').split(':')])}"
 275 FILESDIR = "${@bb.which(d.getVar('FILESPATH', 1), '.')}"
 276
 277 ##################################################################
 278 # General work and output directories for the build system.
 279 ##################################################################
 280
 281 TMPDIR = "${TOPDIR}/tmp"
 282 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 283 CO_DIR = "${DL_DIR}"
 284 CVSDIR = "${CO_DIR}/cvs"
 285 SVNDIR = "${CO_DIR}/svn"
 286 GITDIR = "${CO_DIR}/git"
 287 BZRDIR = "${CO_DIR}/bzr"
 288 HGDIR = "${CO_DIR}/hg"
 289
 290 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 291 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 292 T = "${WORKDIR}/temp"
 293 D = "${WORKDIR}/image"
 294 S = "${WORKDIR}/${BP}"
 295 B = "${S}"
 296
 297 STAGING_DIR = "${TMPDIR}/sysroots"
 298
 299 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 300 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
 301 STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
 302 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH}${base_bindir_native}"
 303 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
 304 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
 305 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
 306 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
 307
 308 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 309 # specific packages - hack around it for now.
 310 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 311 STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
 312 STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
 313 STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
 314 STAGING_ETCDIR = "${STAGING_DIR_HOST}${sysconfdir}"
 315 STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
 316 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
 317 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 318 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 319 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 320
 321 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 322 # specific packages - hack around it for now.
 323 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 324 STAGING_DIR_JAVA = "${STAGING_DATADIR}/java"
 325
 326 STAGING_DIR_SDK = "${STAGING_DIR}/${SDK_SYS}"
 327
 328 # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
 329 # packaged staging and/or multimachine.
 330 DEPLOY_DIR ?= "${TMPDIR}/deploy"
 331 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 332 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 333 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 334 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 335 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 336 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 337
 338 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 339
 340 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 341 SDK_PATH = "/usr/local/${SDK_NAME}"
 342 SDKPATH = "${SDK_PATH}"
 343
 344 ##################################################################
 345 # Kernel info.
 346 ##################################################################
 347
 348 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 349
 350 ##################################################################
 351 # Specific image creation and rootfs population info.
 352 ##################################################################
 353
 354 IMAGE_ROOTFS = "${TMPDIR}/rootfs/${PN}"
 355 IMAGE_BASENAME = "${PN}"
 356 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 357 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 358 IMAGE_EXTRA_SPACE = 10240
 359
 360 UBI_VOLNAME ?= "${MACHINE}-rootfs"
 361
 362 IMAGE_CMD = ""
 363 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 364 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 365 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 366 IMAGE_CMD_ext2 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 367 IMAGE_CMD_ext2.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz"
 368 IMAGE_CMD_ext2.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.bz2"
 369 IMAGE_CMD_ext3 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 370 IMAGE_CMD_ext3.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz"
 371 IMAGE_CMD_ext3.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.bz2"
 372 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 373 IMAGE_CMD_squashfs-lzma = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend -comp lzma"
 374 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 375 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 376 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 377 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio) ${EXTRA_IMAGECMD}"
 378 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}"
 379 IMAGE_CMD_cpio.gz.u-boot = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}; mkimage -A ${UBOOT_ARCH} -O linux -T ramdisk -C gzip -n ${IMAGE_NAME} -d ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz.u-boot"
 380 IMAGE_CMD_cpio.lzma = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | lzma -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.lzma) ${EXTRA_IMAGECMD}"
 381 IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
 382 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 383
 384 EXTRA_IMAGECMD = ""
 385 EXTRA_IMAGECMD_jffs2 = ""
 386 EXTRA_IMAGECMD_yaffs2 = "1"
 387 EXTRA_IMAGECMD_squashfs = ""
 388 EXTRA_IMAGECMD_squashfs-lzma = ""
 389 EXTRA_IMAGECMD_cpio = ""
 390 EXTRA_IMAGECMD_cpio.gz = ""
 391 EXTRA_IMAGECMD_cpio.lzma = ""
 392 EXTRA_IMAGECMD_ubi = ""
 393 EXTRA_IMAGECMD_ubifs = ""
 394
 395 IMAGE_DEPENDS = ""
 396 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 397 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 398 IMAGE_DEPENDS_cramfs = "cramfs-native"
 399 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 400 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 401 IMAGE_DEPENDS_ext2.bz2 = "genext2fs-native"
 402 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 403 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 404 IMAGE_DEPENDS_ext3.bz2 = "genext2fs-native e2fsprogs-native"
 405 IMAGE_DEPENDS_cpio.gz.u-boot = "u-boot-mkimage-native"
 406 IMAGE_DEPENDS_cpio.lzma = "lzma-native"
 407 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 408 IMAGE_DEPENDS_squashfs-lzma = "squashfs-tools-native"
 409 IMAGE_DEPENDS_ubi = "mtd-utils-native"
 410 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 411
 412 EXTRA_IMAGEDEPENDS = ""
 413
 414 ##################################################################
 415 # Toolchain info.
 416 ##################################################################
 417 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}/${base_bindir_native}:"
 418 export PATH
 419
 420 ##################################################################
 421 # Build utility info.
 422 ##################################################################
 423
 424 CCACHE ?= ""
 425 TOOLCHAIN_OPTIONS = ""
 426 TOOLCHAIN_PATH ?= "${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH}"
 427 TOOLCHAIN_SYSPATH ?= "${TOOLCHAIN_PATH}/${TARGET_SYS}"
 428
 429 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 430 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 431 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 432 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 433 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 434 export CCLD = "${CC}"
 435 export AR = "${HOST_PREFIX}ar"
 436 export AS = "${HOST_PREFIX}as"
 437 export RANLIB = "${HOST_PREFIX}ranlib"
 438 export STRIP = "${HOST_PREFIX}strip"
 439 export OBJCOPY = "${HOST_PREFIX}objcopy"
 440 export OBJDUMP = "${HOST_PREFIX}objdump"
 441 export NM = "${HOST_PREFIX}nm"
 442 PYTHON = "${@sys.executable}"
 443
 444 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 445 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 446 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 447 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 448 export BUILD_LD = "${BUILD_PREFIX}ld"
 449 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 450 export BUILD_AR = "${BUILD_PREFIX}ar"
 451 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 452 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 453
 454 export MAKE = "make"
 455 EXTRA_OEMAKE = "-e MAKEFLAGS="
 456
 457 ##################################################################
 458 # Patch handling.
 459 ##################################################################
 460 PATCHTOOL = 'quilt'
 461 PATCHRESOLVE = 'noop'
 462
 463 ##################################################################
 464 # Build flags and options.
 465 ##################################################################
 466
 467 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 468 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 469 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${includedir}"
 470 export SDK_CPPFLAGS = "-isystem${STAGING_DIR_SDK}${includedir} -isystem${STAGING_DIR_HOST}${includedir}"
 471
 472 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 473 export CFLAGS = "${TARGET_CFLAGS}"
 474 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 475 export SDK_CFLAGS = "${SDK_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 476
 477 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 478 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 479 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 480 export SDK_CXXFLAGS = "${SDK_CFLAGS} -fpermissive"
 481
 482 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 483                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 484                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 485
 486 export LDFLAGS = "${TARGET_LDFLAGS}"
 487 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${libdir} \
 488                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${libdir} \
 489                          -Wl,-O1 \
 490                          ${TARGET_LINK_HASH_STYLE}"
 491 export SDK_LDFLAGS = "-L${STAGING_DIR_SDK}${libdir} \
 492                          -Wl,-rpath-link,${STAGING_DIR_SDK}${libdir} \
 493                          -Wl,-O1"
 494
 495 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 496 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 497
 498 # Pass parallel make options to the compile task only
 499 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 500 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 501
 502 ##################################################################
 503 # Optimization flags.
 504 ##################################################################
 505
 506 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 507 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 508 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 509 BUILD_OPTIMIZATION = "-O2 -g"
 510
 511 ##################################################################
 512 # Bootstrap stuff.
 513 ##################################################################
 514
 515 BOOTSTRAP_EXTRA_RDEPENDS = ""
 516 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 517
 518 ##################################################################
 519 # Palmtop stuff.
 520 ##################################################################
 521
 522 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 523 export QPEDIR = "${STAGING_DIR_HOST}"
 524 export OPIEDIR = "${STAGING_DIR_HOST}"
 525 export palmtopdir = "${libdir}/opie"
 526 export palmqtdir = "${palmtopdir}"
 527
 528 ##################################################################
 529 # Download locations and utilities.
 530 ##################################################################
 531
 532 OE_STRICT_CHECKSUMS ?= "1"
 533
 534 ADOBE_MIRROR = "http://fpdownload.macromedia.com/get/flashplayer/current/"
 535 APACHE_MIRROR = "http://archive.apache.org/dist"
 536 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 537 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 538 E_URI = "http://enlightenment.freedesktop.org/files"
 539 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 540 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 541 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 542 GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
 543 GNOME_GIT = "git://git.gnome.org"
 544 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 545 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 546 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 547 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 548 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 549 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 550 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 551 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 552 KERNELORG_MIRROR = "http://kernel.org"
 553 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 554 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 555 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 556
 557 # You can use the mirror of your country to get faster downloads by putting
 558 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 559 #     into your local.conf
 560
 561 FETCHCMD_svn = "/usr/bin/env svn --non-interactive"
 562 FETCHCMD_cvs = "/usr/bin/env cvs"
 563 FETCHCMD_wget = "/usr/bin/env wget -t 5 --no-check-certificate"
 564 FETCHCMD_bzr = "/usr/bin/env bzr"
 565 FETCHCMD_hg = "/usr/bin/env hg"
 566
 567 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 568 FETCHCOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 569 FETCHCOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 570 FETCHCOMMAND_svn = "/usr/bin/env svn co --non-interactive ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 571 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 572 RESUMECOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -c -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 573 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 574 UPDATECOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 575 UPDATECOMMAND_svn = "/usr/bin/env svn update --non-interactive --force --accept theirs-full ${SVNCOOPTS}"
 576 SRCDATE = "${DATE}"
 577 SRCREV = "1"
 578 SRCPV = "${@bb.fetch.get_srcrev(d)}"
 579 AUTOREV = "${SRCPV}"
 580
 581 # For now disable autoincrement of revision counter in SRCPV, whoever wants it, should enable it in local.conf or distro config
 582 # Revision counter is incremented only locally (bad for multiple builders filling shared feeds), LOCALCOUNT can be used to maintain
 583 # counter globally in OE metadata (LOCALCOUNT value set in recipe).
 584 # Make sure you disable it, if you want always upgradable paths for git recipes without bumping LOCALCOUNT with every SRCREV change
 585 # or if you're using AUTOREV feature.
 586 BB_LOCALCOUNT_OVERRIDE = "1"
 587
 588 # Value for revision counter in GIT recipes (NNNN in PV="1.0+gitrNNNN+a7401084a72285c8d3485bacf4eed593f303b1b7-r4.4")
 589 LOCALCOUNT = "0"
 590
 591 SRC_URI = "file://${FILE}"
 592
 593 ##################################################################
 594 # UI/Interaction Configuration
 595 ##################################################################
 596
 597 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 598 export SHELLCMDS = "${SHELLRCCMD}"
 599 # Some common terminal programs to choose from
 600 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 601 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 602 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 603 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 604 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 605 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 606 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 607 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 608
 609 # Set a default
 610 TERMCMD ?= "${GNOME_TERMCMD}"
 611 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 612
 613 ##################################################################
 614 # Miscellaneous utilities.
 615 ##################################################################
 616
 617 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 618 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 619
 620 # GNU patch tries to be intellgent about checking out read-only files from
 621 # a RCS, which freaks out those special folks with active Perforce clients
 622 # the following makes patch ignore RCS:
 623
 624 export PATCH_GET="0"
 625
 626 # Program to be used to build ipkg packages
 627
 628 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 629
 630 ##################################################################
 631 # Not sure about the rest of this yet.
 632 ##################################################################
 633
 634 # slot - currently unused by OE. portage remnants
 635 SLOT = "0"
 636
 637 # Other
 638
 639 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${libdir}/pkgconfig"
 640 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 641 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 642 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 643
 644 export XDG_DATA_DIRS = "${STAGING_DATADIR}"
 645
 646 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 647 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 648 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 649
 650 # library package naming
 651 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 652
 653 # Globally toggle certain dependencies
 654 ENTERPRISE_DISTRO ?= "0"
 655
 656 # Pre-build configuration output
 657
 658 BUILDCFG_HEADER = "Build Configuration:"
 659 BUILDCFG_VARS ?= "BB_VERSION METADATA_BRANCH METADATA_REVISION TARGET_ARCH TARGET_OS MACHINE DISTRO DISTRO_VERSION"
 660 BUILDCFG_VARS_append_arm = " TARGET_FPU"
 661 BUILDCFG_VARS_append_armeb = " TARGET_FPU"
 662 BUILDCFG_NEEDEDVARS ?= "TARGET_ARCH TARGET_OS"
 663
 664 ###
 665 ### Config file processing
 666 ###
 667
 668 # Overrides are processed left to right, so the ones that are named later take precedence.
 669 # You generally want them to go from least to most specific.
 670 #
 671 # This means that an envionment variable named '<foo>_arm' overrides an
 672 # environment variable '<foo>' (when ${TARGET_ARCH} is arm).
 673 # an environment variable '<foo>_ramses' overrides '<foo>' but doesn't override
 674 # '<foo>_arm' when ${MACHINE} is 'ramses'.
 675 # If you use combination ie '<foo>_arm_ramses', then '<foo>_arm_ramses' will override
 676 # '<foo>_arm' and then '<foo>' will be overriden with that value from '<foo>_arm'.
 677 # And finally '<foo>_local' overrides anything, but with lowest priority.
 678 #
 679 # This works for  functions as well, they are really just environment variables.
 680 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 681 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 682 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 683 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 684
 685 ##################################################################
 686 # Include the rest of the config files.
 687 ##################################################################
 688
 689 include conf/site.conf
 690 include conf/auto.conf
 691 include conf/local.conf
 692 # USERDISTRO should always contain original DISTRO value as set by user
 693 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 694 # overrides like it wants), USERDISTRO must be reassigned with := first
 695 USERDISTRO = "${DISTRO}"
 696 include conf/build/${BUILD_SYS}.conf
 697 include conf/target/${TARGET_SYS}.conf
 698 include conf/machine/${MACHINE}.conf
 699 include conf/distro/${DISTRO}.conf
 700 include conf/documentation.conf
 701 require conf/sanity.conf
 702 require conf/abi_version.conf
 703 require conf/enterprise.conf
 704 require conf/compatibility-providers.conf
 705
 706 ##################################################################
 707 # Weak variables (usually to retain backwards compatibility)
 708 ##################################################################
 709
 710 DL_DIR ?= "${TMPDIR}/downloads"
 711 PSTAGE_DIR ?= "${TMPDIR}/pstage"
 712 IMAGE_FSTYPES ?= "tar.gz"
 713 PCMCIA_MANAGER ?= "pcmcia-cs"
 714 DEFAULT_TASK_PROVIDER ?= "task-base"
 715 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 716 IMAGE_ROOTFS_SIZE ?= "65536"
 717 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 718 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 719 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 720 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 721 DISTRO_PR ?= ""
 722
 723 # Forcefully set CACHE now so future changes to things like
 724 # MACHINE don't change the path to the cache
 725 CACHE := "${CACHE}"
 726
 727 # Default to disabling packaged staging code
 728 export PSTAGING_ACTIVE = "0"
 729
 730 ##################################################################
 731 # Magic Cookie for SANITY CHECK
 732 ##################################################################
 733 OES_BITBAKE_CONF = "1"
 734
 735 ##################################################################
 736 # Machine properties and task-base stuff
 737 ##################################################################
 738
 739 MACHINE_FEATURES ?= "kernel26"
 740 DISTRO_FEATURES ?= ""
 741 # Add thumb-interwork to feature list if selected machine supports it.
 742 DISTRO_FEATURES += ' ${@["", "thumb-interwork"][bb.data.getVar('THUMB_INTERWORK', d, 1) == "yes"]}'
 743
 744 # This is used to limit what packages goes into images built, so set big by default
 745 ROOT_FLASH_SIZE ?= "256"
 746
 747 MACHINE_GUI_CLASS ?= "smallscreen"
 748 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 749 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 750 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 751 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 752 MACHINE_DISPLAY_ORIENTATION ?= "0"
 753 MACHINE_DISPLAY_BPP ?= "16"
 754
 755 DISTRO_EXTRA_RDEPENDS ?= ""
 756 DISTRO_EXTRA_RRECOMMENDS ?= ""
 757 MACHINE_EXTRA_RDEPENDS ?= ""
 758 MACHINE_EXTRA_RRECOMMENDS ?= ""
 759 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 760 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 761
 762 COMBINED_FEATURES = "\
 763     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 764     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 765     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 766     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 767     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 768     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 769     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 770     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 771     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 772     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 773
 774 # We want madwifi if all of the following are true:
 775 # - distro has pci, wifi, and madwifi in its features
 776 # - machine has pci in its features
 777 COMBINED_FEATURES += "${@base_ifelse( \
 778     base_contains('DISTRO_FEATURES', ('pci', 'wifi', 'madwifi'), True, False, d) and \
 779     base_contains('MACHINE_FEATURES', 'pci', True, False, d), \
 780     'madwifi', '')}"
 781
 782 # We want hostap if all of the following are true:
 783 # - 'wifi' and 'hostap' are in distro features
 784 # - either 'pci' or 'pcmcia' are in both distro and machine features
 785 COMBINED_FEATURES += "${@base_ifelse( \
 786     base_contains('DISTRO_FEATURES', ('wifi', 'hostap'), True, False, d) and \
 787     ((base_contains('MACHINE_FEATURES', 'pci', True, False, d) and \
 788       base_contains('DISTRO_FEATURES', 'pci', True, False, d)) or \
 789      (base_contains('MACHINE_FEATURES', 'pcmcia', True, False, d) and \
 790       base_contains('DISTRO_FEATURES', 'pcmcia', True, False, d))), \
 791     'hostap', '')}"
 792
 793 # Make sure MACHINE isn't exported
 794 # (breaks binutils at least)
 795 MACHINE[unexport] = "1"
 796
 797 # Make sure TARGET_ARCH isn't exported
 798 # (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
 799 # in them, undocumented)
 800 TARGET_ARCH[unexport] = "1"
 801
 802 # Make sure DISTRO isn't exported
 803 # (breaks sysvinit at least)
 804 DISTRO[unexport] = "1"
 805
 806 # Make sure that LIBC isn't exported
 807 # (breaks perl at least)
 808 LIBC[unexport] = "1"