recipes/siproxd/siproxd.inc

   1 DESCRIPTION = "SIP proxy/masquerading daemon"
   2 SECTION = "net"
   3 DEPENDS = "libosip2"
   4 LICENSE = "GPL"
   5
   6 SRC_URI = " \
   7         ${SOURCEFORGE_MIRROR}/siproxd/siproxd-${PV}.tar.gz \
   8         file://siproxd.init \
   9         "
  10
  11 inherit autotools update-rc.d
  12
  13 INITSCRIPT_NAME = "siproxd"
  14
  15 EXTRA_OECONF = "--disable-doc"
  16
  17 do_configure() {
  18         gnu-configize
  19         aclocal
  20         libtoolize --copy --force
  21         automake --add-missing
  22         autoreconf
  23         oe_runconf
  24 }
  25
  26 do_install_append() {
  27         cp ${D}/${sysconfdir}/siproxd.conf.example ${D}/${sysconfdir}/siproxd.conf
  28         sed -ri "s,^#?(pid_file)\ *=\ *.*$,\1 = /var/run/siproxd.pid," ${D}/${sysconfdir}/siproxd.conf
  29         sed -ri "s,^#?(plugindir)\ *=\ *.*$,\1 = ${libdir}/siproxd/," ${D}/${sysconfdir}/siproxd.conf
  30         install -d ${D}/${sysconfdir}/init.d
  31         install -m 755 ${WORKDIR}/siproxd.init ${D}/${sysconfdir}/init.d/siproxd
  32 }
  33
  34 CONFFILES_${PN} = " \
  35         ${sysconfdir}/siproxd.conf \
  36         ${sysconfdir}/siproxd_passwd.cfg \
  37         "
  38
  39 FILES_${PN} = "${sysconfdir} ${sbindir} ${libdir}/siproxd/*.so.*"
  40 FILES_${PN}-dev += "${libdir}/siproxd/*.so ${libdir}/siproxd/*.a ${libdir}/siproxd/*.la"