recipes/cups/cups_1.4.6.bb

   1 #package the html for the webgui inside the main packages (~1MB uncompressed)
   2 DESCRIPTION = "An Internet printing system for Unix."
   3 SECTION = "console/utils"
   4 LICENSE = "GPL LGPL"
   5 DEPENDS = "gnutls libpng jpeg dbus dbus-glib zlib fakeroot-native"
   6 DEPENDS += "virtual/libusb0"
   7 PROVIDES = "cups14"
   8
   9 SRC_URI = "ftp://ftp.easysw.com/pub/cups/${PV}/cups-${PV}-source.tar.bz2 \
  10            file://use_echo_only_in_init.patch \
  11            file://skip_tools.patch \
  12            file://configure.patch \
  13            file://textonly.ppd \
  14            file://textonly \
  15            file://text.convs \
  16            "
  17 SRC_URI[md5sum] = "de8fb5a29c36554925c0c6a6e2c0dae1"
  18 SRC_URI[sha256sum] = "f08711702a77b52c7150f96fe1f45482f6151cb95ef601268c528607fe6ad514"
  19
  20 inherit autotools binconfig
  21
  22 EXTRA_OECONF = "--enable-gnutls \
  23                 --enable-dbus \
  24                 --enable-browsing \
  25                 --disable-openssl \
  26                 --disable-tiff \
  27                 --without-php \
  28                 --without-perl \
  29                 --without-python \
  30                 --without-java \
  31                 --disable-gssapi \
  32                 --disable-largefile \
  33                 --enable-debug \
  34                 --disable-relro \
  35                 --enable-libusb \
  36                 "
  37
  38 do_configure() {
  39     gnu-configize
  40     libtoolize --force
  41     DSOFLAGS="${LDFLAGS}" oe_runconf
  42 }
  43 do_compile () {
  44     sed -i s:STRIP:NOSTRIP: Makedefs
  45     sed -i s:serial:: backend/Makefile
  46     echo "all:"    >  man/Makefile
  47     echo "libs:" >> man/Makefile
  48     echo "install:" >> man/Makefile
  49     echo "install-data:" >> man/Makefile
  50     echo "install-exec:" >> man/Makefile
  51     echo "install-headers:" >> man/Makefile
  52     echo "install-libs:" >> man/Makefile
  53     oe_runmake "SSLLIBS=-lgnutls -L${STAGING_LIBDIR}" \
  54                "LIBPNG=-lpng -lm -L${STAGING_LIBDIR}" \
  55                "LIBJPEG=-ljpeg -L${STAGING_LIBDIR}" \
  56                "LIBZ=-lz -L${STAGING_LIBDIR}" \
  57                "-I."
  58 }
  59
  60 PACKAGES =+ "${PN}-lib ${PN}-libimage ${PN}-filter-textonly ${PN}-filters ${PN}-models"
  61
  62 PACKAGES_DYNAMIC += "${PN}-backend-*"
  63
  64 python populate_packages_prepend() {
  65         backend_dir = bb.data.expand('${libdir}/cups/backend/', d)
  66         do_split_packages(d, backend_dir, '^(.*)$', 'cups-backend-%s',
  67                           '${PN} backend for %s', prepend=True, allow_links=True)
  68 }
  69
  70 FILES_${PN}-lib = "${libdir}/libcups.so.*"
  71 FILES_${PN}-libimage = "${libdir}/libcupsimage.so.*"
  72 FILES_${PN}-filter-textonly += "${datadir}/ppd/cups-included/textonly.ppd \
  73                                 ${datadir}/cups/mime/text.convs \
  74                                 ${libdir}/cups/filter/textonly \
  75                                 "
  76 FILES_${PN}-filters += "${libdir}/cups/filter/*"
  77 FILES_${PN}-models += "${datadir}/cups/model/*"
  78 FILES_${PN}-dbg += "${libdir}/cups/backend/.debug \
  79                     ${libdir}/cups/cgi-bin/.debug \
  80                     ${libdir}/cups/filter/.debug \
  81                     ${libdir}/cups/monitor/.debug \
  82                     ${libdir}/cups/notifier/.debug \
  83                     ${libdir}/cups/daemon/.debug \
  84                     "
  85 FILES_${PN} += "${datadir}/doc/cups/images \
  86                 ${datadir}/doc/cups/*html \
  87                 ${datadir}/doc/cups/*.css \
  88                 ${datadir}/icons/ \
  89                 "
  90
  91 CONFFILES_${PN} += "${sysconfdir}/cups/cupsd.conf"
  92
  93 LEAD_SONAME = "libcupsdriver.so"
  94
  95 fakeroot do_install () {
  96     oe_runmake "DSTROOT=${D}" install
  97     # This directory gets installed with perms 511, which makes packaging fail
  98     chmod 0711 "${D}/${localstatedir}/run/cups/certs"
  99
 100     install -d ${D}/${libdir}/cups/filter
 101     install -m 755 ${WORKDIR}/textonly ${D}/${libdir}/cups/filter
 102
 103     install -d ${D}/${datadir}/cups/mime
 104     install -m 644 ${WORKDIR}/text.convs ${D}/${datadir}/cups/mime
 105
 106     install -d ${D}/${datadir}/ppd/cups-included
 107     install -m 644 ${WORKDIR}/textonly.ppd ${D}/${datadir}/ppd/cups-included
 108 }
 109
 110 python do_package_append() {
 111         # Change permissions back the way they were, they probably had a reason...
 112         workdir = bb.data.getVar('WORKDIR', d, 1)
 113         os.system('chmod 0511 %s/install/cups/var/run/cups/certs' % workdir)
 114 }