recipes/vnc/fbvncserver_0.9.4.bb

   1 DESCRIPTION = "Framebuffer VNC server"
   2 SECTION = "console/utils"
   3 PRIORITY = "optional"
   4 LICENSE = "GPL"
   5 DEPENDS = "libvncserver jpeg zlib"
   6 RDEPENDS_${PN} = "fbvncserver-kmodule libvncserver-storepasswd libvncserver-javaapplet"
   7 PR = "r4"
   8
   9 SRC_URI = "http://sdgsystems.com/download/fbvncserver-${PV}.tar.gz \
  10            file://libvncs0.6.patch \
  11            file://paths.patch \
  12            file://kernelinclude.patch \
  13            file://buildfix.patch \
  14            file://ipaq.patch \
  15            file://init"
  16
  17 S = "${WORKDIR}/fbvncserver-${PV}"
  18
  19 export INCLUDES = "-I${STAGING_INCDIR}"
  20 export LIBS = "-L${STAGING_LIBDIR} -lpthread"
  21 export VNCSERVER_DIR = "${STAGING_LIBDIR}"
  22 export ZAURUS_ZLIB_LIBS = "${STAGING_LIBDIR}"
  23 export ZAURUS_JPEG_LIBS = "${STAGING_LIBDIR}"
  24
  25 inherit update-rc.d
  26
  27 INITSCRIPT_NAME = "fbvncinput"
  28 INITSCRIPT_PARAMS = "defaults 97"
  29
  30 FBVNCSERVER_SYSTEM = "zaurus"
  31 FBVNCSERVER_SYSTEM_h3600 = "ipaq"
  32 FBVNCSERVER_SYSTEM_h3900 = "ipaq"
  33
  34 do_compile () {
  35         oe_runmake ${FBVNCSERVER_SYSTEM}_fbvncserver ${FBVNCSERVER_SYSTEM}_tssimd
  36 }
  37
  38 do_install () {
  39         install -d ${D}${bindir}
  40         install -m 0755 ${FBVNCSERVER_SYSTEM}_fbvncserver ${D}${bindir}/fbvncserver
  41         install -m 0755 ${FBVNCSERVER_SYSTEM}_tssimd ${D}${bindir}/tssimd
  42
  43         install -d ${D}${datadir}/fbvncserver
  44         install -m 0644 ${FBVNCSERVER_SYSTEM}_panel.jpg ${D}${datadir}/fbvncserver/
  45
  46         install -d ${D}${sysconfdir}/init.d
  47         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/fbvncinput
  48 }
  49
  50 FILES_${PN} += " /usr/share/fbvncserver/*.jpg"
  51
  52
  53 SRC_URI[md5sum] = "01a37f17857641253541307f59dd8cc5"
  54 SRC_URI[sha256sum] = "e22ed10ecba059904649f344be260512fdb3cbecbd95ca965f8b5cc3ea1785b5"