recipes/pam/libpam_1.0.2.bb

   1 DESCRIPTION = "\
   2 PAM authentication library for Linux.  \
   3 Linux-PAM (Pluggable Authentication Modules for Linux) is a \
   4 library that enables the local system administrator to choose \
   5 how individual applications authenticate users. For an \
   6 overview of the Linux-PAM library see the Linux-PAM System \
   7 Administrators' Guide."
   8 HOMEPAGE = "http://kernel.org/pub/linux/libs/pam"
   9 SECTION = "libs"
  10 PRIORITY = "optional"
  11 LICENSE = "GPLv2"
  12
  13 DEPENDS = "flex flex-native"
  14
  15 PR = "r2"
  16
  17 # The project is actually called Linux-PAM but that gives
  18 # a bad OE package name because of the upper case characters
  19 pn = "Linux-PAM"
  20 p = "${pn}-${PV}"
  21 S = "${WORKDIR}/${p}"
  22
  23 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/libs/pam/library/${p}.tar.bz2 \
  24            file://pam-nodocs.patch;patch=1 "
  25
  26 inherit autotools
  27
  28 LEAD_SONAME = "libpam.so.*"
  29
  30 # maintain the pam default layout
  31 EXTRA_OECONF += " --includedir=${includedir}/security"
  32
  33 PACKAGES_DYNAMIC += " pam-plugin-*"
  34 python populate_packages_prepend () {
  35         import os.path
  36
  37         pam_libdir    = bb.data.expand('${libdir}/security', d)
  38         pam_libdirdebug = bb.data.expand('${libdir}/security/.debug', d)
  39         pam_filterdir = bb.data.expand('${libdir}/security/pam_filter', d)
  40         do_split_packages(d, pam_libdir, '^pam(.*)\.so$', 'pam-plugin%s', 'PAM plugin for %s', extra_depends='')
  41         do_split_packages(d, pam_libdir, '^pam(.*)\.la$', 'pam-plugin%s-dev', 'PAM plugin for %s dev', extra_depends='')
  42         if os.path.exists(pam_libdirdebug):
  43                 do_split_packages(d, pam_libdirdebug, '^pam(.*)\.so$', 'pam-plugin%s-dbg', 'PAM plugin for %s debugging symbols', extra_depends='')
  44         do_split_packages(d, pam_filterdir, '^(.*)$', 'pam-filter-%s', 'PAM filter for %s', extra_depends='')
  45 }
  46
  47
  48 do_stage() {
  49         autotools_stage_all
  50 }