recipes/shr/libphone-ui_git.bb

   1 DESCRIPTION = "A generic framework for phone ui"
   2 HOMEPAGE = "http://shr-project.org/"
   3 LICENSE = "LGPLv2.1"
   4 LIC_FILES_CHKSUM = "file://LICENSE;md5=4fbd65380cdd255951079008b364516c"
   5 SECTION = "libs"
   6 SRCREV = "c17c9af4f681536d40451138ac256713acf0a18c"
   7 PV = "0.0.1+gitr${SRCPV}"
   8 PR = "r3"
   9
  10 DEPENDS="glib-2.0 libshr-glib libfso-glib libfsoframework libphone-utils alsa-lib"
  11
  12 SRC_URI = " \
  13  git://git.shr-project.org/repo/libphone-ui.git;protocol=http;branch=master \
  14 "
  15
  16 S = "${WORKDIR}/git"
  17
  18 inherit autotools pkgconfig
  19
  20 do_install_append() {
  21         libphone_ui_install_machine_specific_configs
  22 }
  23
  24 libphone_ui_install_machine_specific_configs() {
  25         # Check for machine specific conf.
  26         CONF_PATH="${S}/conf"
  27         CONF_PATH_MACHINE="${CONF_PATH}"
  28         if [ -d "${CONF_PATH}/${MACHINE}" ] ; then
  29                 CONF_PATH_MACHINE="${CONF_PATH}/${MACHINE}"
  30         fi
  31         install -d ${D}${sysconfdir}
  32         install -m 0644 ${CONF_PATH_MACHINE}/libphoneui.conf ${D}${sysconfdir}/libphoneui.conf
  33 }
  34
  35 PACKAGES =+ "${PN}-config"
  36 PACKAGE_ARCH_${PN}-config = "${MACHINE_ARCH}"
  37
  38 RDEPENDS_${PN} = "${PN}-config"
  39
  40 FILES_${PN}-config = " \
  41   ${sysconfdir}/libphoneui.conf \
  42 "
  43
  44 CONFFILES_${PN}-config = "\
  45   ${sysconfdir}/libphoneui.conf \
  46 "