recipes/netpbm/netpbm_10.28.bb

   1 DESCRIPTION = "Netpbm is a toolkit for manipulation of graphic images, including\
   2 conversion of images between a variety of different formats.  There\
   3 are over 220 separate tools in the package including converters for\
   4 about 100 graphics formats."
   5 HOMEPAGE = "http://netpbm.sourceforge.net"
   6 SECTION = "console/utils"
   7 LICENSE = "GPL MIT Artistic"
   8 # NOTE: individual command line utilities are covered by different
   9 # licenses.  The compiled and linked command line utilties are
  10 # subject to the licenses of the libraries they use too - including
  11 # libpng libz, IJG, and libtiff licenses
  12 DEPENDS = "jpeg zlib libpng tiff flex-native"
  13 RDEPENDS_${PN} = "perl\
  14         perl-module-cwd\
  15         perl-module-english\
  16         perl-module-fcntl\
  17         perl-module-file-basename\
  18         perl-module-file-spec\
  19         perl-module-getopt-long\
  20         perl-module-strict\
  21         "
  22
  23 # these should not be required, they are here because the perl
  24 # module dependencies are currently incorrect:
  25 RDEPENDS_${PN} += "perl-module-exporter-heavy"
  26 RDEPENDS_${PN} += "perl-module-file-spec-unix"
  27
  28 PR = "r8"
  29
  30 SRC_URI = "${SOURCEFORGE_MIRROR}/netpbm/netpbm-${PV}.tgz \
  31            file://ppmtojpeg.patch;striplevel=42 \
  32            file://libgnuhash.patch \
  33            file://Makefile.config \
  34            file://oeendiangen"
  35
  36 PARALLEL_MAKE = ""
  37
  38 EXTRA_OEMAKE = "ENDIANGEN=${S}/buildtools/oeendiangen TARGET_LD=${LD} 'STRIPFLAG='"
  39
  40 do_configure() {
  41         install -c -m 644 ../Makefile.config .
  42         # The following stops the host endiangen program being run and uses
  43         # the target endian.h header instead.
  44         install -c -m 755 ../oeendiangen buildtools
  45 }
  46
  47 do_compile() {
  48         # need all to get the static library too
  49         oe_runmake all default
  50 }
  51
  52 do_install() {
  53         # netpbm makes its own installation package, which must then be
  54         # installed to form the dummy installation for ipkg
  55         rm -rf ${WORKDIR}/netpbm-package
  56         oe_runmake package pkgdir=${WORKDIR}/netpbm-package
  57         # now install the stuff from the package into ${D}
  58         for d in ${WORKDIR}/netpbm-package/*
  59         do
  60                 # following will cause an error if used
  61                 case "$d" in
  62                 */README)       ;;
  63                 */VERSION)      ;;
  64                 */pkginfo)      ;;
  65                 */bin)          install -d ${D}${bindir}
  66                                 cp -pPR "$d"/* ${D}${bindir}
  67                                 rm ${D}${bindir}/doc.url;;
  68                 */include)      install -d ${D}${includedir}
  69                                 cp -pPR "$d"/* ${D}${includedir};;
  70                 */link|*/lib)   install -d ${D}${libdir}
  71                                 cp -pPR "$d"/* ${D}${libdir};;
  72                 */man)          install -d ${D}${mandir}
  73                                 cp -pPR "$d"/* ${D}${mandir};;
  74                 */misc)         install -d ${D}${datadir}/netpbm
  75                                 cp -pPR "$d"/* ${D}${datadir}/netpbm;;
  76                 */config_template)
  77                                 install -d ${D}${bindir}
  78                                 sed "/^@/d
  79                                         s!@VERSION@!$(<'${WORKDIR}/netpbm-package/VERSION')!
  80                                         s!@DATADIR@!${datadir}/netpbm!
  81                                         s!@LIBDIR@!${libdir}!
  82                                         s!@LINKDIR@!${libdir}!
  83                                         s!@INCLUDEDIR@!${includedir}!
  84                                         s!@BINDIR@!${bindir}!
  85                                         " "$d" >${D}${bindir}/netpbm-config
  86                                 chmod 755 ${D}${bindir}/netpbm-config;;
  87                 *)              echo "netpbm-package/$d: unknown item" >&2
  88                                 exit 1;;
  89                 esac
  90         done
  91 }
  92
  93 SRC_URI[md5sum] = "18ed6d0f1adf75a748df55d5e924fabb"
  94 SRC_URI[sha256sum] = "e42d3b3f30de0c1ad0a86aa039b35cf2bf64c7f64c29ee333cbf934784639973"