recipes/glib-2.0/glib-2.0_2.24.1.bb

   1 DESCRIPTION = "GLib is a general-purpose utility library, \
   2 which provides many useful data types, macros, \
   3 type conversions, string utilities, file utilities, a main \
   4 loop abstraction, and so on. It works on many \
   5 UNIX-like platforms, Windows, OS/2 and BeOS."
   6 LICENSE = "LGPL"
   7 SECTION = "libs"
   8 PRIORITY = "optional"
   9 DEPENDS = "glib-2.0-native gtk-doc zlib"
  10 DEPENDS_virtclass-native = "gettext-native gtk-doc-native \
  11                             pkgconfig-native"
  12
  13 PR = "r1"
  14
  15 SRC_URI = "\
  16   http://ftp.gnome.org/pub/GNOME/sources/glib/2.24/glib-${PV}.tar.bz2;name=archive \
  17   file://glibconfig-sysdefs.h \
  18   file://configure-libtool.patch \
  19   file://g_once_init_enter.patch \
  20   file://gatomic-proper-pointer-get-cast.patch \
  21   file://gio.patch \
  22   file://60_wait-longer-for-threads-to-die.patch \
  23 "
  24
  25 SRC_URI[archive.md5sum] = "6a7db81c9a2cffe6a34dadb57d7ba2d2"
  26 SRC_URI[archive.sha256sum] = "014c3da960bf17117371075c16495f05f36501db990851ceea658f15d2ea6d04"
  27
  28 SRC_URI_append_arm = " file://atomic-thumb.patch"
  29 SRC_URI_append_armv6 = " file://gatomic_armv6.patch"
  30 SRC_URI_append_armv7a = " file://gatomic_armv6.patch"
  31
  32 inherit autotools gettext
  33
  34 S = "${WORKDIR}/glib-${PV}"
  35
  36 EXTRA_OECONF = "--disable-debug "
  37
  38 # Add and entry for your favourite arch if your (g)libc has a sane printf
  39 EXTRA_OECONF_append_glibc_arm = "  --enable-included-printf=no "
  40
  41 do_configure_prepend () {
  42         install -m 0644 ${WORKDIR}/glibconfig-sysdefs.h .
  43 }
  44
  45 do_install_append() {
  46         sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g ${D}${bindir}/glib-mkenums || true
  47 }
  48
  49 EXTRA_OECONF_virtclass-native = ""
  50
  51 do_configure_prepend_virtclass-native() {
  52     if [ -e ${S}/${TARGET_SYS}-libtool ] ; then
  53                 echo "${TARGET_SYS}-libtool already present"
  54     else
  55         cp ${STAGING_BINDIR}/${TARGET_SYS}-libtool ${S}
  56     fi
  57
  58 }
  59
  60 BBCLASSEXTEND = "native"
  61
  62 PACKAGES =+ "gobject-2.0 gmodule-2.0 gthread-2.0 gio-2.0 glib-2.0-utils "
  63 LEAD_SONAME = "libglib-2.0.*"
  64 FILES_glib-2.0-utils = "${bindir}/*"
  65 FILES_${PN} = "${libdir}/lib*so.* ${libdir}/gio/modules/*.so"
  66 FILES_${PN}-dev += "${libdir}/glib-2.0 ${datadir}/glib-2.0 ${libdir}/gio/modules/*.la"
  67 FILES_${PN}-dbg += "${libdir}/gio/modules/.debug"
  68 FILES_gmodule-2.0 = "${libdir}/libgmodule-2.0.so.*"
  69 FILES_gobject-2.0 = "${libdir}/libgobject-2.0.so.*"
  70 FILES_gio-2.0 = "${libdir}/libgio-2.0.so.*"
  71 FILES_gthread-2.0 = "${libdir}/libgthread-2.0.so.*"
  72
  73 # Let various glib components end up in glib package
  74 # for compatibility (with binary packages from Maemo).
  75 FILES_gthread-2.0_chinook-compat = ""
  76 FILES_gmodule-2.0_chinook-compat = ""
  77 FILES_gobject-2.0_chinook-compat = ""
  78 FILES_gio-2.0_chinook-compat = ""