recipes/netperf/netperf_2.4.4.bb

   1 DESCRIPTION="Network performance benchmark including tests for TCP, UDP, sockets, ATM and more."
   2 SECTION = "console/network"
   3 HOMEPAGE = "http://www.netperf.org/"
   4 LICENSE = "netperf"
   5 PR = "r1"
   6
   7 SRC_URI="ftp://ftp.netperf.org/netperf/archive/netperf-${PV}.tar.bz2 \
   8          file://cpu_set.patch;patch=1 \
   9          file://init"
  10
  11 inherit update-rc.d autotools
  12
  13 S = "${WORKDIR}/netperf-${PV}"
  14
  15 # cpu_set.patch plus _GNU_SOURCE makes src/netlib.c compile with CPU_ macros
  16 CFLAGS_append = " -DDO_UNIX -DDO_IPV6 -D_GNU_SOURCE"
  17
  18 do_install() {
  19         install -d ${D}${sbindir} ${D}${bindir} ${D}${sysconfdir}/init.d
  20         install -m 4755 src/netperf ${D}${bindir}
  21         install -m 4755 src/netserver ${D}${sbindir}
  22         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/netperf
  23
  24         # man
  25         install -d ${D}${mandir}/man1/
  26         install -m 0644 doc/netserver.man ${D}${mandir}/man1/netserver.1
  27         install -m 0644 doc/netperf.man ${D}${mandir}/man1/netperf.1
  28
  29         # move scripts to examples directory
  30         install -d ${D}${docdir}/netperf/examples
  31         install -m 0644 doc/examples/*_script ${D}${docdir}/netperf/examples/
  32
  33         # docs ..
  34         install -m 0644 COPYING ${D}${docdir}/netperf
  35         install -m 0644 Release_Notes ${D}${docdir}/netperf
  36         install -m 0644 README ${D}${docdir}/netperf
  37         install -m 0644 doc/netperf_old.ps ${D}${docdir}/netperf
  38 }
  39
  40 INITSCRIPT_NAME="netperf"
  41 INITSCRIPT_PARAMS="defaults"
  42
  43 SRC_URI[md5sum] = "0e942f22864e601406a994420231075b"
  44 SRC_URI[sha256sum] = "28e76af491ea3696885e4558ae2f5628a4b9ebdbefc2f1d9cf1b35db2813e497"