classes/package_dbg.bbclass

   1 # package_dbg.bbclass: populate -dbg versions for each package in PACKAGES
   2 #
   3 # Copyright (c) 2009 MontaVista Software, Inc.  All rights reserved.
   4 #
   5 # Released under the MIT license (see LICENSE.MIT for the terms)
   6
   7
   8 inherit package
   9
  10
  11 PACKAGE_DBG_DESC = "Debugging files for %s"
  12 PACKAGE_DBG_EXCLUDE = "${PN}-locale* ${PN}-doc ${PN}-dev *-dbg"
  13
  14
  15 def add_dbg_packages(d):
  16     from fnmatch import fnmatch
  17
  18     packages = d.getVar("PACKAGES", True).split()
  19     excludes = d.getVar("PACKAGE_DBG_EXCLUDE", True).split()
  20
  21     for pkg in tuple(packages):
  22         if any(fnmatch(pkg, excluded) for excluded in excludes):
  23             continue
  24
  25         dbgpkg = "%s-dbg" % pkg
  26         if not dbgpkg in packages:
  27             packages.insert(0, dbgpkg)
  28
  29     d.setVar("PACKAGES", " ".join(packages))
  30
  31
  32 # Add the -dbg packages to PACKAGES
  33 python () {
  34     from bb.data import inherits_class as inherits
  35
  36     # Task handles its own -dbg versions of its packages at the moment
  37     if not inherits("task", d):
  38         dynpkgs = d.getVar("PACKAGES_DYNAMIC", True).split()
  39         dynpkgs += ["%s-dbg" % dyn for dyn in dynpkgs]
  40         d.setVar("PACKAGES_DYNAMIC", " ".join(dynpkgs))
  41
  42         add_dbg_packages(d)
  43 }
  44
  45 python populate_packages_prepend () {
  46         from bb.data import inherits_class as inherits
  47
  48         if not inherits("task", d):
  49                 bb.build.exec_func("package_do_dbg", d)
  50 }
  51
  52 # Populate the -dbg subpackage metadata
  53 python package_do_dbg() {
  54     """ Populate the -dbg subpackage metadata. """
  55
  56     import oe.package
  57     from os.path import join, basename, dirname
  58
  59     def setVar(key, val):
  60         if d.getVar(key, val) is None:
  61             d.setVar(key, val)
  62
  63     add_dbg_packages(d)
  64     packages = d.getVar("PACKAGES", True).split()
  65     desc = d.getVar("PACKAGE_DBG_DESC", True)
  66
  67     done = []
  68     for pkgname in tuple(packages):
  69         files = tuple(oe.package.files(pkgname, d))
  70         dbg = [join(dirname(file), ".debug", basename(file))
  71                for file in files
  72                if not file in done]
  73         done.extend(files)
  74
  75         if dbg:
  76             setVar("FILES_%s-dbg" % pkgname, " ".join(dbg))
  77             setVar("DESCRIPTION_%s-dbg" % pkgname, desc % pkgname)
  78             setVar("RDEPENDS_%s-dbg" % pkgname, pkgname)
  79         else:
  80             try:
  81                 packages.remove("%s-dbg" % pkgname)
  82             except ValueError:
  83                 pass
  84     d.setVar("PACKAGES", " ".join(packages))
  85 }