recipes/rox/rox-filer_2.5.bb

   1 DESCRIPTION = "File manager at the core of the ROX desktop"
   2 HOMEPAGE = "http://rox.sf.net"
   3 LICENSE = "GPL"
   4 SECTION = "x11/applications"
   5 DEPENDS = "gtk+ shared-mime-info"
   6 RDEPENDS_${PN} = "shared-mime-info"
   7 PR = "r4"
   8
   9 SRC_URI = "${SOURCEFORGE_MIRROR}/rox/${P}.tar.bz2 \
  10            file://no-strip-objcopy.patch;striplevel=3"
  11
  12 inherit mime pkgconfig
  13
  14 S = "${WORKDIR}/${P}/ROX-Filer/src/"
  15
  16 do_compile() {
  17         ../AppRun --compile
  18 }
  19
  20 do_install() {
  21         install -d ${D}${bindir}
  22         install -m 755 ../ROX-Filer ${D}${bindir}
  23
  24         install -d ${D}${datadir}/rox/Choices
  25         install -d ${D}${datadir}/rox/images
  26         install -d ${D}${datadir}/mime/packages
  27         install -d ${D}${datadir}/doc/rox/html
  28         install -d ${D}${mandir}/man1
  29
  30         gzip -c9 ${WORKDIR}/${P}/rox.1 >${D}${mandir}/man1/rox.1.gz
  31
  32         cp -R ${WORKDIR}/${P}/Choices ${D}${datadir}/rox
  33         rm -rf ${D}${datadir}rox/Choices/MIME-info/
  34         cp ${WORKDIR}/${P}/ROX-Filer/*.xml ${D}${datadir}/rox
  35
  36         cp ${WORKDIR}/${P}/ROX-Filer/Help/{Changes,README*,TODO} ${D}${datadir}/doc/rox
  37         cp ${WORKDIR}/${P}/ROX-Filer/Help/*html ${D}${datadir}/doc/rox/html
  38         cp ${WORKDIR}/${P}/ROX-Filer/style.css ${D}${datadir}/doc/rox/html
  39         cp -R ${WORKDIR}/${P}/ROX-Filer/images ${D}${datadir}/rox
  40         cp -R ${WORKDIR}/${P}/ROX-Filer/ROX ${D}${datadir}/rox
  41
  42 #       cp ROX-Filer/ROX-Filer ${D}/usr/bin/rox
  43         cp ${WORKDIR}/${P}/ROX-Filer/.DirIcon ${D}${datadir}/rox/.DirIcon
  44         cp ${WORKDIR}/${P}/rox.xml ${D}${datadir}/mime/packages
  45
  46         for f in ${WORKDIR}/${P}/ROX-Filer/Messages/*.gmo;  do
  47             export ROXTMP=`basename $f .gmo` ;
  48             if [ $ROXTMP = "sp" ]; then
  49                 export ROXTMP="es" ;
  50             fi
  51             install -d ${D}${datadir}/locale/$ROXTMP/LC_MESSAGES;
  52             cp $f ${D}${datadir}/locale/$ROXTMP/LC_MESSAGES/rox.mo;
  53         done
  54 }
  55
  56 FILES_${PN} += "${datadir}/rox/ ${datadir}/mime/packages"
  57
  58 SRC_URI[md5sum] = "56e6a29f2dbdf11d6f4b74a3f03ff959"
  59 SRC_URI[sha256sum] = "d91120d78e770c9c09822560dacb42fca641d092cbe52064ca7232f089062921"