recipes/angstrom/e-wm-config-angstrom.bb

   1 DESCRIPTION = "Enlightenment DR17 theme for Angstrom"
   2 LICENSE = "MIT/BSD"
   3 DEPENDS = "edje-native eet-native e-wm places gnome-icon-theme"
   4
   5 PACKAGES_DYNAMIC = "e-wm-config-angstrom*"
   6
   7 PR = "r14"
   8
   9 SRC_URI = " \
  10           file://configs \
  11           "
  12 S = "${WORKDIR}/configs"
  13
  14 # [09:16:17] * koen mumbles something about binary config file
  15 # [09:16:19] <raster> eet -d e.cfg config e.src
  16 # [09:16:29] <raster> will get u a test dump of it (as e.src)
  17 # [09:17:09] <raster> eet -e e.cfg config e.src 1
  18 # [09:17:12] <raster> will re-encode
  19
  20 do_compile() {
  21 rm ${S}/patches -rf
  22 for dir in ${S}/* ; do
  23         cd $dir
  24         for i in *.src ; do
  25                 eet -e $(echo $i | sed s:src:cfg:g) config $i 1
  26         done
  27 done
  28 }
  29
  30 do_install() {
  31         for i in ${WORKDIR}/configs/* ; do
  32                 install -d ${D}${datadir}/enlightenment/data/config/$(basename $i)/
  33
  34                 install -m 0644 ${S}/$(basename $i)/*.cfg ${D}${datadir}/enlightenment/data/config/$(basename $i)/
  35                 install -m 0644 ${S}/$(basename $i)/*.desktop ${D}${datadir}/enlightenment/data/config/$(basename $i)/
  36                 install -m 0644 ${S}/$(basename $i)/*.png ${D}${datadir}/enlightenment/data/config/$(basename $i)/
  37         done
  38 }
  39
  40 RDEPENDS_${PN} = "e-wm places gnome-icon-theme"
  41
  42 python populate_packages_prepend () {
  43         angstrom_e_dir = bb.data.expand('${datadir}/enlightenment/data/config', d)
  44         do_split_packages(d, angstrom_e_dir, '(.*)', 'e-wm-config-%s', 'E17 window manager %s config', extra_depends='e-wm places gnome-icon-theme', allow_links=True, allow_dirs=True)
  45 }
  46
  47 PACKAGE_ARCH = "all"
  48