recipes/networkmanager/network-manager-applet_0.7.1.997.bb

   1 DESCRIPTION = "GTK+ applet for NetworkManager"
   2 LICENSE = "GPL"
   3 DEPENDS = "policykit-gnome libnotify networkmanager dbus-glib libglade gconf gnome-keyring"
   4 RDEPENDS_${PN} = "networkmanager"
   5 PR = "r1"
   6
   7 inherit gnome
   8
   9 SRC_URI += "file://nm-applet.conf"
  10
  11 do_configure_append() {
  12         rm config.log
  13         # Sigh... --enable-compile-warnings=no doesn't actually turn off -Werror
  14         for i in $(find ${S} -name "Makefile") ; do
  15             sed -i -e s:-Werror::g $i
  16         done
  17 }
  18
  19 # Hack around dbus a_console problems
  20 do_install_append() {
  21         install -m 0644 ${WORKDIR}/nm-applet.conf ${D}${sysconfdir}/dbus-1/system.d/
  22 }
  23
  24 FILES_${PN} += "${datadir}/nm-applet/ \
  25         ${datadir}/gnome-vpn-properties/ \
  26         ${datadir}/gnome/autostart/ \
  27         "
  28
  29 SRC_URI[archive.md5sum] = "3183f5ae3553da0ce9c381dadbcc19e0"
  30 SRC_URI[archive.sha256sum] = "34316707a323b883f347b2566fd2dc7a3134b2bf432fb3a8b31d88829b0947e3"