recipes/gnome/gdm_2.30.0.bb

   1 DESCRIPTION = "Graphical login manager"
   2 LICENSE = "GPL"
   3
   4 DEPENDS = "xinput gnome-panel tcp-wrappers libcanberra libxklavier grep consolekit libpam gnome-doc-utils gtk+ libglade libgnomecanvas librsvg libxml2 libart-lgpl xrdb"
   5
   6 inherit gnome update-rc.d
   7
   8 RDEPENDS_${PN} += "grep dbus-x11 shadow libpam-base-files"
   9
  10 SRC_URI += " \
  11             file://cross-xdetection.diff \
  12             file://%gconf-tree.xml \
  13             file://gdm \
  14             file://gdm.conf \
  15             file://gdm-pam \
  16            "
  17
  18 SRC_URI[archive.md5sum] = "0da84637abbcbf1666529d6192a81e6b"
  19 SRC_URI[archive.sha256sum] = "ac2c367766b8fa20ebeb41033931fc4d91482ad3d377823f1c7ad84eee12dc15"
  20
  21 EXTRA_OECONF = " --enable-authentication-scheme=shadow \
  22                  --enable-debug=yes \
  23                  --with-console-kit \
  24                  --disable-scrollkeeper "
  25
  26 do_install_prepend() {
  27         mkdir -p ${D}/var/lib/gdm/.gconf.mandatory
  28         cp ${WORKDIR}/%gconf-tree.xml ${D}/var/lib/gdm/.gconf.mandatory/
  29 }
  30
  31 do_install_append() {
  32         install -d ${D}/${sysconfdir}/init.d
  33         install -m 0755 ${WORKDIR}/gdm ${D}/${sysconfdir}/init.d/
  34
  35         install -d ${D}/${sysconfdir}/gdm
  36         install -m 0644 ${WORKDIR}/gdm.conf ${D}/${sysconfdir}/gdm/
  37
  38         install -d ${D}/${sysconfdir}/pam.d
  39         install -m 0755 ${WORKDIR}/gdm-pam       ${D}/${sysconfdir}/pam.d/gdm
  40 }
  41
  42 FILES_${PN} += "${datadir}/icon* \
  43                 ${datadir}/xsession* \
  44                "
  45
  46 CONFFILES_${PN} += "${sysconfdir}/gdm/gdm.conf ${sysconfdir}/init.d/gdm"
  47
  48 INITSCRIPT_NAME = "gdm"
  49 INITSCRIPT_PARAMS = "start 99 5 2 . stop 20 0 1 6 ."
  50
  51 pkg_postinst_${PN} () {
  52     # can't do this offline
  53     if [ "x$D" != "x" ]; then
  54         exit 1
  55     fi
  56     grep "^gdm:" /etc/group > /dev/null || addgroup gdm
  57     grep "^gdm:" /etc/passwd > /dev/null || adduser --disabled-password --system --home /var/lib/gdm gdm --ingroup gdm -g gdm
  58
  59 if [ -d /var/lib/gdm ]; then
  60   chown -R gdm:gdm /var/lib/gdm
  61   chmod 0750 /var/lib/gdm
  62 fi
  63
  64 # Register up as default dm
  65 mkdir -p ${sysconfdir}/X11/
  66 echo "${bindir}/gdm" > ${sysconfdir}/X11/default-display-manager
  67
  68 }
  69
  70 pkg_postrm_${PN} () {
  71     deluser gdm || true
  72     delgroup gdm || true
  73         sed -i /gdm/d ${sysconfdir}/X11/default-display-manager || true
  74 }
  75
  76
  77
  78