recipes/openmoko2/openmoko-icon-theme-standard2-qvga_svn.bb

   1 DESCRIPTION = "Standard Gtk+ icon theme for the Openmoko framework, QVGA edition"
   2 SECTION = "openmoko/base"
   3 DEPENDS = "imagemagick-native librsvg-native"
   4 SRCREV = "4232"
   5 PV = "0.1.0+svnr${SRCPV}"
   6 PR = "r2"
   7
   8 EXCLUDE_FROM_WORLD = "1"
   9
  10 inherit openmoko2
  11
  12 SRC_URI = "svn://svn.openmoko.org/trunk/src/target/OM-2007.2/artwork/;module=icons;proto=http"
  13 S = "${WORKDIR}/icons"
  14
  15 pkg_postinst_${PN} () {
  16     if [ "x$D" != "x" ]; then
  17         exit 1
  18     fi
  19     gtk-update-icon-cache -q /usr/share/icons/openmoko-standard
  20 }
  21
  22 do_configure_prepend () {
  23         cd ${S}
  24         #
  25         # don't include 36x36 and 128x128 icons, 32x32 and 48x48 stock icons
  26         #
  27         sed -i -e "/\(36\|128\)/d" -e "/\(32\|48\)\/stock/d" configure.ac
  28         cd openmoko-standard
  29         sed -i -e "s/\(36x36\|128x128\) //g" Makefile.am
  30         sed -i "/^SUBDIRS=/s/ stock//" {32x32,48x48}/Makefile.am
  31         #
  32         # rescale stock icons to 22x22
  33         #
  34         for png in $(ls */stock/*.png | sed "s,.*/,," | sort | uniq); do
  35                 svg=scalable/stock/$(basename $png .png).svg
  36                 out=22x22/stock/$png
  37                 if [ -f $svg ]; then
  38                         #
  39                         # if there are vector graphics, rerender
  40                         #
  41                         rsvg -w 22 -h 22 $svg $out
  42                 else
  43                         #
  44                         # otherwise rescale biggest existing bitmap
  45                         #
  46                         png=$(echo */stock/$png | sed "s/.* //")
  47                         convert -scale 22x22 $png $out
  48                 fi
  49         done
  50         #
  51         # register the rescaled icons with automake
  52         #
  53         cd 22x22/stock
  54         sed -i "/^icons_DATA/s/=.*/= $(echo *.png)/" Makefile.am
  55         cd ${S}
  56 }
  57
  58 PACKAGE_ARCH = "all"