recipes/avr-evtd/avr-evtd_1.7.2.bb

   1 DESCRIPTION = "A simple and small user space interface daemon to the Linkstation/Kuro AVR micro-controller"
   2 HOMEPAGE = "http://sourceforge.net/projects/ppc-evtd"
   3 SECTION = "console/network"
   4 PR = "r1"
   5 LICENSE = "GPL"
   6
   7 SRC_URI = "${SOURCEFORGE_MIRROR}/ppc-evtd/avr_evtd_${PV}.release.tar.gz \
   8            file://dont-ignore-config.patch;patch=1 \
   9            file://avr_evtd.conf \
  10            file://EventScript \
  11            file://init"
  12 S = "${WORKDIR}/usr/src/avr_evtd"
  13
  14 inherit update-rc.d
  15
  16 COMPATIBLE_MACHINE = "(lsppchd|lsppchg|lsmipsel)"
  17 INITSCRIPT_NAME = "avr-evtd"
  18 INITSCRIPT_PARAMS = "defaults"
  19
  20 # This is a simple thing and we will only ever need this for powerpc and mipsel
  21 # on the platforms above. Pretty important though to stop death by watchdog.
  22
  23 do_compile_powerpc() {
  24         ${CC} ${CFLAGS} ${LDFLAGS} -o PPC/avr_evtd avr_evtd.c -DNO_MELCO -DUBOOT
  25 }
  26
  27 do_compile_mipsel() {
  28         ${CC} ${CFLAGS} ${LDFLAGS} -o MIPS/avr_evtd avr_evtd.c -DNO_MELCO -DUBOOT -DMIPS
  29 }
  30
  31 do_install() {
  32         install -D -m 0644 ${WORKDIR}/avr_evtd.conf ${D}${sysconfdir}/default/avr_evtd
  33         install -D -m 0755 ${WORKDIR}/EventScript ${D}${sysconfdir}/avr_evtd/EventScript
  34         install -D -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/avr-evtd
  35 }
  36
  37 do_install_append_powerpc() {
  38         install -D -m 0755 ${S}/PPC/avr_evtd ${D}${sbindir}/avr_evtd
  39 }
  40
  41 do_install_append_mipsel() {
  42         install -D -m 0755 ${S}/MIPS/avr_evtd ${D}${sbindir}/avr_evtd
  43 }
  44
  45 SRC_URI[md5sum] = "782600479e7967ab104309ee467b57b0"
  46 SRC_URI[sha256sum] = "bf52cccf8d4a36f75ba364310c602210498b7642951aed5b838de2750d347d22"