recipes/gtk+/gtk+_2.20.1.bb

   1 require gtk+.inc
   2
   3 SRC_URI_append_virtclass-native = " file://no-demos.patch \
   4 "
   5 SRC_URI_append = "file://gtk-dnd-grab-deadlock-fix.patch \
   6                   file://cross-nm.patch \
   7                   file://xkb-ifdef.patch \
   8                  "
   9
  10 SRC_URI[gtk.md5sum] = "53e6f3a93bd22934878fc4a4a34c68aa"
  11 SRC_URI[gtk.sha256sum] = "0e081731d21e34ff45c82199490c2889504fa8b3c7e117c043e82ababaec0f65"
  12
  13 PR = "${INC_PR}.4"
  14
  15 BBCLASSEXTEND = "native"
  16
  17 ARM_INSTRUCTION_SET = "arm"
  18
  19 DEPENDS_virtclass-native = "libpng-native atk-native pango-native cairo-native libxrender-native libxext-native libgcrypt-native"
  20 PROVIDES_virtclass-native = "gdk-pixbuf-csource-native"
  21
  22 # Enable xkb selectively
  23 XKBTOGGLE = " --disable-xkb"
  24 XKBTOGGLE_angstrom = ""
  25
  26 EXTRA_OECONF = " --enable-introspection=no --with-libtiff ${XKBTOGGLE} --disable-glibtest gio_can_sniff=yes"
  27 EXTRA_OECONF_append_virtclass-native = " --without-libtiff --without-libjpeg --disable-cups"
  28
  29 PACKAGES_DYNAMIC = "gtk-module-* gdk-pixbuf-loader-* gtk-immodule-* gtk-printbackend-*"
  30
  31 python populate_packages_prepend () {
  32         import os.path
  33
  34         prologue = bb.data.getVar("postinst_prologue", d, 1)
  35
  36         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  37         loaders_root = os.path.join(gtk_libdir, 'loaders')
  38         immodules_root = os.path.join(gtk_libdir, 'immodules')
  39         printmodules_root = os.path.join(gtk_libdir, 'printbackends');
  40         modules_root = bb.data.expand('${libdir}/gtk-2.0/modules/',d)
  41
  42         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders', extra_depends='')
  43         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules', extra_depends='')
  44         do_split_packages(d, printmodules_root, '^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s', extra_depends='')
  45         do_split_packages(d, modules_root, '^lib(.*)\.so$', 'gtk-module-%s', 'GTK module for %s', extra_depends='')
  46
  47         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  48                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  49 }
  50
  51 # gail is part of gtk+ since gtk+-2.13.0 (targetting >=GNOME 2.23):
  52 PROVIDES = "virtual/gail"
  53 RPROVIDES_${PN} = "libgailutil18"
  54 RCONFLICTS_${PN} = "libgailutil18"
  55 RREPLACES_${PN} = "libgailutil18"
  56 RPROVIDES_${PN}-dev = "libgailutil-dev"
  57 RCONFLICTS_${PN}-dev = "libgailutil-dev"
  58 RREPLACES_${PN}-dev = "libgailutil-dev"
  59 RPROVIDES_${PN}-doc = "libgailutil-doc"
  60 RCONFLICTS_${PN}-doc = "libgailutil-doc"
  61 RREPLACES_${PN}-doc = "libgailutil-doc"
  62 RPROVIDES_${PN}-dbg = "libgailutil-dbg"
  63 RCONFLICTS_${PN}-dbg = "libgailutil-dbg"
  64 RREPLACES_${PN}-dbg = "libgailutil-dbg"
  65 # FIXME: replace locales as well
  66