recipes/xfce-base/xfce4-panel_4.4.2.bb

   1 # xfce4-panel OE build file
   2 # Copyright (C) 2004, Advanced Micro Devices, Inc.  All Rights Reserved
   3 # Released under the MIT license (see COPYING.MIT)
   4
   5 DESCRIPTION = "XFCE4 Panel"
   6 SECTION = "x11"
   7 DEPENDS = "startup-notification virtual/libx11 libxfcegui4 libxfce4mcs xfce-mcs-manager libxml2"
   8
   9 inherit pkgconfig xfce
  10
  11 PR = "r1"
  12
  13 EXTRA_OECONF += " --enable-startup-notification"
  14
  15 do_install() {
  16     oe_runmake DESTDIR=${D} install
  17 }
  18
  19 python populate_packages_prepend() {
  20         plugin_dir = bb.data.expand('${libdir}/xfce4/panel-plugins/', d)
  21         plugin_name = bb.data.expand('${PN}-plugin-%s', d)
  22         do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name,
  23                           '${PN} plugin for %s', extra_depends='', prepend=True,
  24                           aux_files_pattern=['${datadir}/xfce4/panel-plugins/%s.desktop',
  25                                              '${sysconfdir}/xdg/xfce/panel/%s-*',
  26                                              '${datadir}/icons/hicolor/48x48/apps/*-%s.png',
  27                                              '${bindir}/*%s*'])
  28 }
  29
  30 PACKAGES += "${PN}-mcs-plugins"
  31 PACKAGES_DYNAMIC = "${PN}-plugin-*"
  32
  33 FILES_${PN}-mcs-plugins += "${libdir}/xfce4/mcs-plugins/"
  34 FILES_${PN}-dbg += "${libdir}/xfce4/mcs-plugins/.debug"
  35
  36 SRC_URI[md5sum] = "8f26b32c442bf9926f98f285a3c251dd"
  37 SRC_URI[sha256sum] = "ddabfb0ccf04366820efdeb7c640ee3a648a55e51b5177c9861a5ab896e96ddd"