recipes/iptraf/iptraf_3.0.0.bb

   1 DESCRIPTION = "Heavyweight console network bandwidth monitor"
   2 LICENSE = "GPLv2"
   3 DEPENDS = "ncurses"
   4 PR = "r0"
   5
   6 SRC_URI = " \
   7     ${DEBIAN_MIRROR}/main/i/iptraf/iptraf_${PV}.orig.tar.gz;name=archive \
   8     ${DEBIAN_MIRROR}/main/i/iptraf/iptraf_3.0.0-6.diff.gz;name=patch \
   9     file://support-makefile.patch \
  10 "
  11
  12 # iptraf will store user filters etc. in /var/run/iptraf, which is probably
  13 # volatile.
  14 EXTRA_OEMAKE_append = " \
  15     TARGET=${bindir} WORKDIR=${localstatedir}/run/iptraf DESTDIR=${D} \
  16     INCLUDEDIR=-I../support \
  17 "
  18
  19 do_compile(){
  20     oe_runmake -C ${S}/src
  21 }
  22
  23 do_install() {
  24     install -d ${D}${bindir}
  25     install -m 0755 ${S}/src/iptraf ${D}${bindir}
  26     install -m 0755 ${S}/src/rvnamed ${D}${bindir}
  27
  28     install -d ${D}${mandir}/man8
  29     install -m 0644 ${S}/Documentation/iptraf.8 ${D}${mandir}/man8
  30 }
  31
  32 PACKAGES =+ "${PN}-dns"
  33 DESCRIPTION_${PN}-dns = "Asynchronous reverse DNS lookup daemon for iptraf"
  34 FILES_${PN}-dns = "${bindir}/rvnamed"
  35
  36 SRC_URI[archive.md5sum] = "377371c28ee3c21a76f7024920649ea8"
  37 SRC_URI[archive.sha256sum] = "9ee433d95573d612539da4b452e6cdcbca6ab6674a88bfbf6eaf12d4902b5163"
  38 SRC_URI[patch.md5sum] = "fe0e2944addbd5803b42e91f7e4ec5d7"
  39 SRC_URI[patch.sha256sum] = "5803c3f3653887896b75567daf617a8f200cecdd28beb870219b3954d9931efa"