recipes/gnome/gnome-vfs_2.22.0.bb

   1 LICENSE = "GPL"
   2 DEPENDS = "libxml2 gconf gnutls avahi dbus dbus-glib bzip2 gnome-mime-data zlib"
   3 RRECOMMENDS = "gnome-vfs-plugin-file shared-mime-info"
   4 # Some legacy packages will require gnome-mime-data to be installed, but use of
   5 # it is deprecated.
   6 PR = "r1"
   7
   8 inherit gnome
   9
  10 SRC_URI += "file://gconftool-lossage.patch;patch=1;pnum=1 \
  11             file://gnome-vfs-no-kerberos.patch;patch=1;pnum=0"
  12
  13 # This is to provide compatibility with the gnome-vfs DBus fork
  14 PROVIDES = "gnome-vfs-plugin-dbus"
  15 RREPLACES = "gnome-vfs-dbus"
  16
  17 EXTRA_OECONF = " \
  18                  --disable-openssl \
  19                  --enable-gnutls \
  20                  --enable-avahi \
  21                  --with-samba-includes=${STAGING_INCDIR} \
  22                "
  23
  24 FILES_${PN} += "${libdir}/vfs ${datadir}/dbus-1/services"
  25 FILES_${PN}-dbg += "${libdir}/gnome-vfs-2.0/modules/.debug"
  26 FILES_${PN}-dev += "\
  27   ${libdir}/gnome-vfs-2.0/include \
  28   ${libdir}/gnome-vfs-2.0/modules/*.a \
  29   ${libdir}/gnome-vfs-2.0/modules/*.la \
  30 "
  31 FILES_${PN}-doc += "${datadir}/gtk-doc"
  32
  33 do_stage () {
  34 autotools_stage_all
  35 }
  36
  37 PACKAGES_DYNAMIC = "gnome-vfs-plugin-*"
  38
  39 python populate_packages_prepend () {
  40         print bb.data.getVar('FILES_gnome-vfs', d, 1)
  41
  42         plugindir = bb.data.expand('${libdir}/gnome-vfs-2.0/modules/', d)
  43         do_split_packages(d, plugindir, '^lib(.*)\.so$', 'gnome-vfs-plugin-%s', 'GNOME VFS plugin for %s')
  44 }
  45
  46