recipes/icu/icu_3.6.bb

   1 require icu-3.6.inc
   2
   3 DEPENDS += "icu-native"
   4 PR = "${INC_PR}.1"
   5
   6 SRC_URI += "file://use-g++-for-linking.patch \
   7             file://rematch-gcc-bug.patch"
   8
   9 do_configure_append() {
  10         for i in */Makefile */*.inc */*/Makefile */*/*.inc icudefs.mk ; do
  11                 sed -i -e 's:$(INVOKE) $(BINDIR)/:$(INVOKE) :g' $i
  12                 sed -i -e 's:$(BINDIR)/::g' $i
  13                 sed -i -e 's:LD_LIBRARY_PATH:LD_LIBRARY_PATH_FAKE:g' $i
  14         done
  15         sed -i -e 's:$(BINDIR)/::g' extra/uconv/pkgdata.inc || true
  16         sed -i -e 's:$(BINDIR)/::g' extra/uconv/pkgdata.inc.in || true
  17 }
  18
  19 do_compile() {
  20         oe_runmake 'CXX=${CXX}'
  21 }
  22
  23 do_install_append() {
  24         chmod +x ${D}${libdir}/lib*
  25 }
  26
  27 PACKAGES =+ "libicudata libicuuc libicui18n libicule libiculx libicutu libicuio"
  28
  29 FILES_libicudata = "${libdir}/libicudata.so.*"
  30 FILES_libicuuc = "${libdir}/libicuuc.so.*"
  31 FILES_libicui18n = "${libdir}/libicui18n.so.*"
  32 FILES_libicule = "${libdir}/libicule.so.*"
  33 FILES_libiculx = "${libdir}/libiculx.so.*"
  34 FILES_libicutu = "${libdir}/libicutu.so.*"
  35 FILES_libicuio = "${libdir}/libicuio.so.*"
  36
  37 SYSROOT_PREPROCESS_FUNCS += "icu_sysroot_preprocess"
  38
  39 # We need to append this so it runs *after* binconfig's preprocess function
  40 icu_sysroot_preprocess () {
  41         sed -i -e s:^prefix=:prefix=\"${STAGING_DIR_TARGET}/usr\": ${SYSROOT_DESTDIR}${STAGING_BINDIR_CROSS}/icu-config
  42 }
  43
  44
  45
  46 SRC_URI[md5sum] = "6243f7a19e03e05403ce84e597510d4c"
  47 SRC_URI[sha256sum] = "5135e8d69d6206d320515df7aeee7027711ab1aef9d8dbf29571a97a9746b041"