recipes/glib-2.0/glib-2.0_2.22.4.bb

   1 DESCRIPTION = "GLib is a general-purpose utility library, \
   2 which provides many useful data types, macros, \
   3 type conversions, string utilities, file utilities, a main \
   4 loop abstraction, and so on. It works on many \
   5 UNIX-like platforms, Windows, OS/2 and BeOS."
   6 LICENSE = "LGPLv2+"
   7 SECTION = "libs"
   8 PRIORITY = "optional"
   9 DEPENDS = "glib-2.0-native gtk-doc virtual/libiconv virtual/libintl"
  10
  11 SRC_URI = "\
  12   http://ftp.gnome.org/pub/GNOME/sources/glib/2.22/glib-${PV}.tar.bz2;name=archive \
  13   file://glibconfig-sysdefs.h \
  14   file://configure-libtool.patch \
  15   file://g_once_init_enter.patch \
  16   file://uclibc-res_query.patch \
  17   file://glib-mkenums-interpreter.patch \
  18 "
  19 SRC_URI[archive.md5sum] = "d91bcbe27556430ddecce65086355708"
  20 SRC_URI[archive.sha256sum] = "0d1f6bf8aaeab772f2370229eefda45bef434e3f29a7d1d8e5dfafeaa1d8ad14"
  21
  22 SRC_URI_append_arm = " file://atomic-thumb.patch"
  23 SRC_URI_append_armv6 = " file://gatomic_armv6.patch"
  24 SRC_URI_append_armv7a = " file://gatomic_armv6.patch"
  25
  26 PR = "r2"
  27
  28 inherit autotools gettext
  29
  30 S = "${WORKDIR}/glib-${PV}"
  31
  32 EXTRA_OECONF = "--disable-debug "
  33
  34 # Add and entry for your favourite arch if your (g)libc has a sane printf
  35 EXTRA_OECONF_append_glibc_arm = "  --enable-included-printf=no "
  36
  37 do_configure_prepend () {
  38         install -m 0644 ${WORKDIR}/glibconfig-sysdefs.h .
  39 }
  40
  41 do_install_append() {
  42         sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g ${D}${bindir}/glib-mkenums || true
  43 }
  44
  45 DEPENDS_virtclass-native = "gettext-native gtk-doc-native \
  46                             pkgconfig-native"
  47 EXTRA_OECONF_virtclass-native = ""
  48
  49 do_configure_prepend_virtclass-native() {
  50     if [ -e ${S}/${TARGET_SYS}-libtool ] ; then
  51                 echo "${TARGET_SYS}-libtool already present"
  52     else
  53         cp ${STAGING_BINDIR}/${TARGET_SYS}-libtool ${S}
  54     fi
  55
  56 }
  57
  58 BBCLASSEXTEND = "native"
  59
  60 PACKAGES =+ "gobject-2.0 gmodule-2.0 gthread-2.0 gio-2.0 glib-2.0-utils "
  61 LEAD_SONAME = "libglib-2.0.*"
  62 FILES_glib-2.0-utils = "${bindir}/*"
  63 FILES_${PN} = "${libdir}/lib*so.* ${libdir}/gio/modules/*.so"
  64 FILES_${PN}-dev += "${libdir}/glib-2.0 ${datadir}/glib-2.0 ${libdir}/gio/modules/*.la"
  65 FILES_${PN}-dbg += "${libdir}/gio/modules/.debug"
  66 FILES_gmodule-2.0 = "${libdir}/libgmodule-2.0.so.*"
  67 FILES_gobject-2.0 = "${libdir}/libgobject-2.0.so.*"
  68 FILES_gio-2.0 = "${libdir}/libgio-2.0.so.*"
  69 FILES_gthread-2.0 = "${libdir}/libgthread-2.0.so.*"
  70
  71 # Let various glib components end up in glib package
  72 # for compatibility (with binary packages from Maemo).
  73 FILES_gthread-2.0_chinook-compat = ""
  74 FILES_gmodule-2.0_chinook-compat = ""
  75 FILES_gobject-2.0_chinook-compat = ""
  76 FILES_gio-2.0_chinook-compat = ""