recipes/binutils/binutils_2.16.91.0.7.bb

   1 DESCRIPTION = "A GNU collection of binary utilities"
   2 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   3 SECTION = "devel"
   4 LICENSE = "GPL"
   5 DEFAULT_PREFERENCE = "-1"
   6 INC_PR = "r5"
   7 PR = "${INC_PR}.1"
   8
   9 inherit autotools gettext
  10
  11 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  12
  13 FILES_${PN} = " \
  14         ${bindir}/${TARGET_PREFIX}* \
  15         ${libdir}/lib*-*.so \
  16         ${prefix}/${TARGET_SYS}/bin/*"
  17
  18 FILES_${PN}-dev = " \
  19         ${includedir} \
  20         ${libdir}/*.a \
  21         ${libdir}/*.la \
  22         ${libdir}/libbfd.so \
  23         ${libdir}/libopcodes.so"
  24
  25 FILES_${PN}-symlinks = " \
  26         ${bindir}/addr2line \
  27         ${bindir}/ar \
  28         ${bindir}/as \
  29         ${bindir}/c++filt \
  30         ${bindir}/gprof \
  31         ${bindir}/ld \
  32         ${bindir}/nm \
  33         ${bindir}/objcopy \
  34         ${bindir}/objdump \
  35         ${bindir}/ranlib \
  36         ${bindir}/readelf \
  37         ${bindir}/size \
  38         ${bindir}/strings \
  39         ${bindir}/strip"
  40
  41 SRC_URI = \
  42     "${KERNELORG_MIRROR}/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
  43      file://binutils-2.16.91.0.6-objcopy-rename-errorcode.patch \
  44      file://binutils-uclibc-100-uclibc-conf.patch \
  45      file://binutils-uclibc-300-001_ld_makefile_patch.patch \
  46      file://binutils-uclibc-300-006_better_file_error.patch \
  47      file://binutils-uclibc-300-012_check_ldrunpath_length.patch \
  48      file://binutils-uclibc-400-mips-ELF_MAXPAGESIZE-4K.patch \
  49      file://binutils-uclibc-702-binutils-skip-comments.patch"
  50
  51 S = "${WORKDIR}/binutils-${PV}"
  52 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  53
  54 EXTRA_OECONF = "--program-prefix=${TARGET_PREFIX} \
  55                 --enable-shared"
  56
  57 # This is necessary due to a bug in the binutils Makefiles
  58 EXTRA_OEMAKE = "configure-build-libiberty all"
  59
  60 export AR = "${HOST_PREFIX}ar"
  61 export AS = "${HOST_PREFIX}as"
  62 export LD = "${HOST_PREFIX}ld"
  63 export NM = "${HOST_PREFIX}nm"
  64 export RANLIB = "${HOST_PREFIX}ranlib"
  65 export OBJCOPY = "${HOST_PREFIX}objcopy"
  66 export OBJDUMP = "${HOST_PREFIX}objdump"
  67
  68 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  69 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  70 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  71 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  72 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  73
  74 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  75 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  76
  77 export CC_FOR_BUILD = "${BUILD_CC}"
  78 export CPP_FOR_BUILD = "${BUILD_CPP}"
  79 export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
  80
  81 export CC = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  82
  83 do_configure () {
  84         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  85         oe_runconf
  86 }
  87
  88 do_install () {
  89         autotools_do_install
  90
  91         # We don't really need these, so we'll remove them...
  92         rm -rf ${D}${libdir}/ldscripts
  93
  94         # Fix the /usr/${TARGET_SYS}/bin/* links
  95         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
  96                 rm -f $l
  97                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
  98                         | tr -s / \
  99                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 100         done
 101
 102         # Install the libiberty header
 103         install -d ${D}${includedir}
 104         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 105         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 106
 107         cd ${D}${bindir}
 108
 109         # Symlinks for ease of running these on the native target
 110         for p in ${TARGET_SYS}-* ; do
 111                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 112         done
 113 }
 114
 115 SRC_URI[md5sum] = "26c3fddb07bfe3128d2e09e628eb33a0"
 116 SRC_URI[sha256sum] = "af9cfdde06693ecaaf3b558e6a66e7245d04cb981812ce06d023de868aa92b41"