classes/image.bbclass

   1 inherit rootfs_${IMAGE_PKGTYPE}
   2 inherit kernel-arch
   3
   4 LICENSE = "MIT"
   5 PACKAGES = ""
   6
   7 #
   8 # udev, devfsd, busybox-mdev (from busybox) or none
   9 #
  10 IMAGE_DEV_MANAGER ?= "${@base_contains("MACHINE_FEATURES", "kernel26",  "udev","",d)} "
  11 #
  12 # sysvinit, upstart
  13 #
  14 IMAGE_INIT_MANAGER ?= "sysvinit sysvinit-pidof"
  15 IMAGE_INITSCRIPTS ?= "initscripts"
  16 #
  17 # tinylogin, getty
  18 #
  19 IMAGE_LOGIN_MANAGER ?= "tinylogin"
  20
  21 # set sane default for the SPLASH variable
  22 SPLASH ?= ""
  23
  24 IMAGE_KEEPROOTFS ?= ""
  25 IMAGE_KEEPROOTFS[doc] = "Set to non-empty to keep ${IMAGE_ROOTFS} around after image creation."
  26
  27 IMAGE_BOOT ?= "${IMAGE_INITSCRIPTS} \
  28 ${IMAGE_DEV_MANAGER} \
  29 ${IMAGE_INIT_MANAGER} \
  30 ${IMAGE_LOGIN_MANAGER} "
  31
  32 RDEPENDS += "${IMAGE_INSTALL} ${IMAGE_BOOT}"
  33
  34 # "export IMAGE_BASENAME" not supported at this time
  35 IMAGE_BASENAME[export] = "1"
  36 export PACKAGE_INSTALL ?= "${IMAGE_INSTALL} ${IMAGE_BOOT}"
  37
  38 # We need to recursively follow RDEPENDS and RRECOMMENDS for images
  39 do_rootfs[recrdeptask] += "do_deploy do_populate_sysroot"
  40
  41 # Images are generally built explicitly, do not need to be part of world.
  42 EXCLUDE_FROM_WORLD = "1"
  43
  44 USE_DEVFS ?= "0"
  45
  46 PID = "${@os.getpid()}"
  47
  48 PACKAGE_ARCH = "${MACHINE_ARCH}"
  49
  50 do_rootfs[depends] += "makedevs-native:do_populate_sysroot fakeroot-native:do_populate_sysroot"
  51
  52 python () {
  53     import bb
  54
  55     deps = bb.data.getVarFlag('do_rootfs', 'depends', d) or ""
  56     for type in (bb.data.getVar('IMAGE_FSTYPES', d, True) or "").split():
  57         for dep in ((bb.data.getVar('IMAGE_DEPENDS_%s' % type, d) or "").split() or []):
  58             deps += " %s:do_populate_sysroot" % dep
  59     for dep in (bb.data.getVar('EXTRA_IMAGEDEPENDS', d, True) or "").split():
  60         deps += " %s:do_populate_sysroot" % dep
  61     bb.data.setVarFlag('do_rootfs', 'depends', deps, d)
  62
  63     runtime_mapping_rename("PACKAGE_INSTALL", d)
  64 }
  65
  66 #
  67 # Get a list of files containing tables of devices to be created.
  68 # * IMAGE_DEVICE_TABLE is the old name to an absolute path to a device table file
  69 # * IMAGE_DEVICE_TABLES is a new name for a file, or list of files, searched
  70 #   for in the BBPATH
  71 # If neither are specified then the default name of files/device_table-minimal.txt
  72 # is searched for in the BBPATH (same as the old version.)
  73 #
  74 def get_devtable_list(d):
  75     import bb
  76     devtable = bb.data.getVar('IMAGE_DEVICE_TABLE', d, 1)
  77     if devtable != None:
  78         return devtable
  79     devtables = bb.data.getVar('IMAGE_DEVICE_TABLES', d, 1)
  80     if devtables == None:
  81         devtables = 'files/device_table-minimal.txt'
  82     return " ".join([ bb.which(bb.data.getVar('BBPATH', d, 1), devtable)
  83                       for devtable in devtables.split() ])
  84
  85 def get_imagecmds(d):
  86     import bb
  87     cmds = "\n"
  88     old_overrides = bb.data.getVar('OVERRIDES', d, 0)
  89     for type in bb.data.getVar('IMAGE_FSTYPES', d, True).split():
  90         localdata = bb.data.createCopy(d)
  91         bb.data.setVar('OVERRIDES', '%s:%s' % (type, old_overrides), localdata)
  92         bb.data.update_data(localdata)
  93         cmd  = "\t#Code for image type " + type + "\n"
  94         cmd += "\t${IMAGE_CMD_" + type + "}\n"
  95         cmd += "\tcd ${DEPLOY_DIR_IMAGE}/\n"
  96         cmd += "\trm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}." + type + "\n"
  97         cmd += "\tln -s ${IMAGE_NAME}.rootfs." + type + " ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}." + type + "\n\n"
  98         cmds += bb.data.expand(cmd, localdata)
  99     return cmds
 100
 101 IMAGE_POSTPROCESS_COMMAND ?= ""
 102 MACHINE_POSTPROCESS_COMMAND ?= ""
 103 ROOTFS_POSTPROCESS_COMMAND ?= ""
 104
 105 # some default locales
 106 IMAGE_LINGUAS ?= "de-de fr-fr en-gb"
 107
 108 LINGUAS_INSTALL = "${@" ".join(map(lambda s: "locale-base-%s" % s, bb.data.getVar('IMAGE_LINGUAS', d, 1).split()))}"
 109
 110 do_rootfs[nostamp] = "1"
 111 do_rootfs[dirs] = "${TOPDIR}"
 112 do_build[nostamp] = "1"
 113
 114 # Must call real_do_rootfs() from inside here, rather than as a separate
 115 # task, so that we have a single fakeroot context for the whole process.
 116 fakeroot do_rootfs () {
 117         set -x
 118         rm -rf ${IMAGE_ROOTFS}
 119         mkdir -p ${IMAGE_ROOTFS}
 120         mkdir -p ${DEPLOY_DIR_IMAGE}
 121
 122         mkdir -p ${IMAGE_ROOTFS}/etc
 123
 124         if [ "${USE_DEVFS}" != "1" ]; then
 125                 rm -rf ${IMAGE_ROOTFS}/etc/device_table
 126                 for devtable in ${@get_devtable_list(d)}; do
 127                         cat $devtable >> ${IMAGE_ROOTFS}/etc/device_table
 128                         makedevs -r ${IMAGE_ROOTFS} -D $devtable
 129                 done
 130         fi
 131
 132         rootfs_${IMAGE_PKGTYPE}_do_rootfs
 133
 134         insert_feed_uris
 135
 136         ${IMAGE_PREPROCESS_COMMAND}
 137
 138         ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = ${IMAGE_EXTRA_SPACE} + $1; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
 139         ${@get_imagecmds(d)}
 140
 141         ${IMAGE_POSTPROCESS_COMMAND}
 142
 143         ${MACHINE_POSTPROCESS_COMMAND}
 144         ${@['rm -rf ${IMAGE_ROOTFS}', ''][bool(d.getVar("IMAGE_KEEPROOTFS", 1))]}
 145 }
 146
 147 do_deploy_to[nostamp] = "1"
 148 do_deploy_to () {
 149         # A standalone task to deploy built image to the location specified
 150         # by DEPLOY_TO variable (likely passed via environment).
 151         # Assumes ${IMAGE_FSTYPES} is a single value!
 152         cp "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.${IMAGE_FSTYPES}" ${DEPLOY_TO}
 153 }
 154
 155 insert_feed_uris () {
 156
 157         echo "Building feeds for [${DISTRO}].."
 158
 159         for line in ${FEED_URIS}
 160         do
 161                 # strip leading and trailing spaces/tabs, then split into name and uri
 162                 line_clean="`echo "$line"|sed 's/^[ \t]*//;s/[ \t]*$//'`"
 163                 feed_name="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\1/p'`"
 164                 feed_uri="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\2/p'`"
 165
 166                 echo "Added $feed_name feed with URL $feed_uri"
 167
 168                 # insert new feed-sources
 169                 echo "src/gz $feed_name $feed_uri" >> ${IMAGE_ROOTFS}/etc/opkg/${feed_name}-feed.conf
 170         done
 171
 172         # Allow to use package deploy directory contents as quick devel-testing
 173         # feed. This creates individual feed configs for each arch subdir of those
 174         # specified as compatible for the current machine.
 175         # NOTE: Development-helper feature, NOT a full-fledged feed.
 176         if [ -n "${FEED_DEPLOYDIR_BASE_URI}" ]; then
 177             for arch in ${PACKAGE_ARCHS}
 178             do
 179                 echo "src/gz local-$arch ${FEED_DEPLOYDIR_BASE_URI}/$arch" >> ${IMAGE_ROOTFS}/etc/opkg/local-$arch-feed.conf
 180             done
 181         fi
 182 }
 183
 184 log_check() {
 185         set +x
 186         for target in $*
 187         do
 188                 lf_path="${WORKDIR}/temp/log.do_$target.${PID}"
 189
 190                 echo "log_check: Using $lf_path as logfile"
 191
 192                 if test -e "$lf_path"
 193                 then
 194                         rootfs_${IMAGE_PKGTYPE}_log_check $target $lf_path
 195                 else
 196                         echo "Cannot find logfile [$lf_path]"
 197                 fi
 198                 echo "Logfile is clean"
 199         done
 200
 201         set -x
 202 }
 203
 204 # set '*' as the rootpassword so the images
 205 # can decide if they want it or not
 206
 207 zap_root_password () {
 208         sed 's%^root:[^:]*:%root:*:%' < ${IMAGE_ROOTFS}/etc/passwd >${IMAGE_ROOTFS}/etc/passwd.new
 209         mv ${IMAGE_ROOTFS}/etc/passwd.new ${IMAGE_ROOTFS}/etc/passwd
 210 }
 211
 212 create_etc_timestamp() {
 213         date +%2m%2d%2H%2M%Y >${IMAGE_ROOTFS}/etc/timestamp
 214 }
 215
 216 # Turn any symbolic /sbin/init link into a file
 217 remove_init_link () {
 218         if [ -h ${IMAGE_ROOTFS}/sbin/init ]; then
 219                 LINKFILE=${IMAGE_ROOTFS}`readlink ${IMAGE_ROOTFS}/sbin/init`
 220                 rm ${IMAGE_ROOTFS}/sbin/init
 221                 cp $LINKFILE ${IMAGE_ROOTFS}/sbin/init
 222         fi
 223 }
 224
 225 make_zimage_symlink_relative () {
 226         if [ -L ${IMAGE_ROOTFS}/boot/zImage ]; then
 227                 (cd ${IMAGE_ROOTFS}/boot/ && for i in `ls zImage-* | sort`; do ln -sf $i zImage; done)
 228         fi
 229 }
 230
 231 # Make login manager(s) enable automatic login.
 232 # Useful for devices where we do not want to log in at all (e.g. phones)
 233 set_image_autologin () {
 234         sed -i 's%^AUTOLOGIN=\"false"%AUTOLOGIN="true"%g' ${IMAGE_ROOTFS}/etc/sysconfig/gpelogin
 235 }
 236
 237 # Can be use to create /etc/timestamp during image construction to give a reasonably
 238 # sane default time setting
 239 rootfs_update_timestamp () {
 240         date "+%m%d%H%M%Y" >${IMAGE_ROOTFS}/etc/timestamp
 241 }
 242
 243 # Install locales into image for every entry in IMAGE_LINGUAS
 244 install_linguas() {
 245 if [ -e ${IMAGE_ROOTFS}/usr/bin/opkg-cl ] ; then
 246         OPKG="opkg-cl ${IPKG_ARGS}"
 247
 248         ${OPKG} update || true
 249         ${OPKG} list_installed | awk '{print $1}' |sort | uniq > /tmp/installed-packages
 250
 251         for i in $(cat /tmp/installed-packages | grep -v locale) ; do
 252                 for translation in ${IMAGE_LINGUAS}; do
 253                         translation_split=$(echo ${translation} | awk -F '-' '{print $1}')
 254                         echo ${i}-locale-${translation}
 255                         echo ${i}-locale-${translation_split}
 256                 done
 257         done | sort | uniq > /tmp/wanted-locale-packages
 258
 259         ${OPKG} list | awk '{print $1}' |grep locale |sort | uniq > /tmp/available-locale-packages
 260
 261         cat /tmp/wanted-locale-packages /tmp/available-locale-packages | sort | uniq -d > /tmp/pending-locale-packages
 262
 263         if [ -s /tmp/pending-locale-packages ] ; then
 264                 cat /tmp/pending-locale-packages | xargs ${OPKG} -nodeps install
 265         fi
 266         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/lists/*
 267
 268     for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.preinst; do
 269         if [ -f $i ] && ! sh $i; then
 270             opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .preinst`
 271         fi
 272     done
 273
 274     for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.postinst; do
 275         if [ -f $i ] && ! sh $i configure; then
 276             opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .postinst`
 277         fi
 278     done
 279
 280 fi
 281 }
 282
 283 # export the zap_root_password, create_etc_timestamp and remote_init_link
 284 EXPORT_FUNCTIONS zap_root_password create_etc_timestamp remove_init_link do_rootfs make_zimage_symlink_relative set_image_autologin rootfs_update_timestamp install_linguas
 285
 286 addtask rootfs before do_build after do_install
 287 addtask deploy_to after do_rootfs