recipes/splashutils/splashutils_1.5.4.2.bb

   1 DESCRIPTION = "Framebuffer splash utilities."
   2 SECTION = "media-gfx"
   3 LICENSE = "GPL"
   4 PR = "r1"
   5
   6 SRC_URI = "http://dev.gentoo.org/~spock/projects/gensplash/archive/splashutils-${PV}.tar.bz2"
   7
   8 DEPENDS = "jpeg klcc-cross"
   9
  10 inherit autotools
  11
  12 PARALLEL_MAKE = ""
  13
  14 # klcc doesn't work with -isystem
  15 export TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}/${layout_includedir}"
  16 export BUILD_CPPFLAGS = "-I${STAGING_DIR_NATIVE}${layout_includedir}"
  17
  18 do_configure_prepend() {
  19         if [ -f "${S}"/src/Makefile.am ] ; then
  20                 sed -i "s#^INCLUDES = \(.*\)#INCLUDES = \1 $CPPFLAGS#" "${S}"/src/Makefile.am
  21         fi
  22 }
  23
  24 EXTRA_OECONF = "--without-gpm --without-png --without-mng --without-ttf --without-ttf-kernel"
  25
  26 # fbcondecor_helper is also useful outside of the main package.
  27 RDEPENDS_${PN} = "${PN}-helper"
  28
  29 PACKAGES =+ "${PN}-helper"
  30 FILES_${PN}-helper = "${base_sbindir}/fbcondecor_helper ${base_sbindir}/splash_helper"
  31 FILES_${PN} += "/lib"
  32
  33 do_install_append () {
  34         if [ -f "${S}"/debian/splashutils.dirs ] ; then
  35                 for dir in $(cat debian/splashutils.dirs) ; do
  36                         mkdir -p ${D}/$dir
  37                 done
  38         fi
  39
  40         ln -s fbcondecor_helper ${D}${base_sbindir}/splash_helper
  41
  42 }
  43
  44 SRC_URI[md5sum] = "00dce0efb5e6389cacbf15c62d18e413"
  45 SRC_URI[sha256sum] = "05265dbc948a690dc5b5710da23eb7093fa4eaabbfebd58463a2be4ab9b848b4"