recipes/qt4/qt4-tools-sdk_4.5.2.bb

   1 DESCRIPTION = "SDK tools for Qt/[X11|Mac|Embedded] version 4.x"
   2 DEPENDS = "zlib-native dbus-native"
   3 SECTION = "libs"
   4 HOMEPAGE = "http://www.trolltech.com"
   5 PRIORITY = "optional"
   6 LICENSE = "LGPLv2.1 GPLv3"
   7
   8 inherit sdk
   9
  10 SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-embedded-linux-opensource-src-${PV}.tar.bz2 \
  11            file://configure-lflags.patch \
  12            file://qt-config.patch \
  13            file://g++.conf \
  14            file://linux.conf"
  15 S = "${WORKDIR}/qt-embedded-linux-opensource-src-${PV}"
  16
  17 # FIXME: make it work with "${STAGING_BINDIR_NATIVE}/pkg-config --cflags dbus-1"
  18 EXTRA_OECONF = "-prefix ${prefix} \
  19                 -qt-libjpeg -qt-gif -system-zlib \
  20                 -no-libjpeg -no-libpng \
  21                 -no-accessibility \
  22                 -no-cups \
  23                 -no-exceptions  \
  24                 -no-nas-sound \
  25                 -no-nis \
  26                 -verbose -release -fast -static \
  27                 -qt3support \
  28                 -I${STAGING_DIR_NATIVE}/usr/include \
  29                 -I${STAGING_DIR_NATIVE}/usr/include/dbus-1.0 \
  30                 -I${STAGING_DIR_NATIVE}/usr/lib/dbus-1.0/include"
  31
  32 # yank default -e, otherwise we get the following error:
  33 # moc_qbuffer.cpp: No such file or directory
  34 EXTRA_OEMAKE = " "
  35
  36 do_configure() {
  37    (echo o; echo yes) | ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
  38 }
  39
  40 TOBUILD = "\
  41   src/tools/bootstrap \
  42   src/tools/moc \
  43   src/corelib \
  44   src/sql \
  45   src/dbus \
  46   src/qt3support \
  47   src/xml \
  48   src/tools/uic \
  49   src/tools/rcc \
  50   src/network \
  51   src/gui \
  52   src/tools/uic3 \
  53   tools/linguist/lrelease \
  54   tools/linguist/lupdate \
  55   tools/qdbus \
  56 "
  57
  58 do_compile() {
  59     for i in ${TOBUILD}; do
  60         cd ${S}/$i && oe_runmake CC="${CC}" CXX="${CXX}"
  61     done
  62 }
  63
  64 do_install() {
  65     install -d ${D}${bindir}
  66     install -m 0755 bin/qmake ${D}${bindir}/qmake2
  67     for i in moc uic uic3 rcc lrelease lupdate qdbuscpp2xml qdbusxml2cpp; do
  68         install -m 0755 bin/${i} ${D}${bindir}/${i}4
  69     done
  70 }
  71
  72
  73 SRC_URI[md5sum] = "62186345c609a72b89f16d83bc7a130f"
  74 SRC_URI[sha256sum] = "272301a27e2f7bcd44c8d09f496e1c749c80b86d9489ea9c30bb265bf2dd02fc"