classes/glibc-package.bbclass

   1 #
   2 # This class knows how to package up glibc. Its shared since prebuild binary toolchains
   3 # may need packaging and its pointless to duplicate this code.
   4 #
   5 # Caller should set GLIBC_INTERNAL_USE_BINARY_LOCALE to one of:
   6 #  "compile" - Use QEMU to generate the binary locale files
   7 #  "precompiled" - The binary locale files are pregenerated and already present
   8 #  "ondevice" - The device will build the locale files upon first boot through the postinst
   9
  10 inherit qemu
  11
  12 GLIBC_INTERNAL_USE_BINARY_LOCALE ?= "ondevice"
  13
  14 PACKAGES = "glibc-dbg glibc catchsegv sln nscd ldd localedef glibc-utils glibc-pic glibc-dev glibc-static glibc-doc glibc-locale libcidn libmemusage libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
  15 PACKAGES_DYNAMIC = "glibc-gconv-* glibc-charmap-* glibc-localedata-* locale-base-* glibc-binary-localedata-*"
  16
  17 INSANE_SKIP_glibc-dbg = True
  18
  19 libc_baselibs = "${base_libdir}/libcrypt*.so.* ${base_libdir}/libcrypt-*.so ${base_libdir}/libc*.so.* ${base_libdir}/libc-*.so ${base_libdir}/libm*.so.* ${base_libdir}/libm-*.so ${base_libdir}/ld*.so.* ${base_libdir}/ld-*.so ${base_libdir}/libpthread*.so.* ${base_libdir}/libpthread-*.so ${base_libdir}/libresolv*.so.* ${base_libdir}/libresolv-*.so ${base_libdir}/librt*.so.* ${base_libdir}/librt-*.so ${base_libdir}/libutil*.so.* ${base_libdir}/libutil-*.so ${base_libdir}/libnsl*.so.* ${base_libdir}/libnsl-*.so ${base_libdir}/libnss_files*.so.* ${base_libdir}/libnss_files-*.so ${base_libdir}/libnss_compat*.so.* ${base_libdir}/libnss_compat-*.so ${base_libdir}/libnss_dns*.so.* ${base_libdir}/libnss_dns-*.so ${base_libdir}/libdl*.so.* ${base_libdir}/libdl-*.so ${base_libdir}/libanl*.so.* ${base_libdir}/libanl-*.so ${base_libdir}/libBrokenLocale*.so.* ${base_libdir}/libBrokenLocale-*.so"
  20
  21 # The problem is that if PN = "glibc", FILES_${PN} will overwrite FILES_glibc
  22 # Solution: Make them both the same thing, then it doesn't matter
  23
  24 glibcfiles = "${libc_baselibs} ${libexecdir}/* ${datadir}/zoneinfo ${@base_conditional('USE_LDCONFIG', '1', '${base_sbindir}/ldconfig', '', d)}"
  25 glibcdbgfiles = "${bindir}/.debug ${sbindir}/.debug ${libdir}/.debug \
  26                   ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug \
  27                   ${libdir}/gconv/.debug ${libexecdir}/*/.debug"
  28 glibcpicfiles = "${libdir}/*_pic.a ${libdir}/*_pic.map ${libdir}/libc_pic/"
  29 glibcdevfiles = "${bindir}/rpcgen ${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
  30                 ${libdir}/*.a ${libdir}/*.o ${libdir}/pkgconfig ${libdir}/*nonshared.a \
  31                 ${base_libdir}/*.a ${base_libdir}/*.o ${datadir}/aclocal"
  32
  33 FILES_glibc = "${glibcfiles}"
  34 FILES_${PN} = "${glibcfiles}"
  35 FILES_ldd = "${bindir}/ldd"
  36 FILES_libsegfault = "${base_libdir}/libSegFault*"
  37 FILES_libcidn = "${base_libdir}/libcidn*.so"
  38 FILES_libmemusage = "${base_libdir}/libmemusage.so"
  39 FILES_glibc-extra-nss = "${base_libdir}/libnss*"
  40 FILES_sln = "${base_sbindir}/sln"
  41 FILES_glibc-pic = "${glibcpicfiles}"
  42 FILES_${PN}-pic = "${glibcpicfiles}"
  43 FILES_glibc-dev = "${glibcdevfiles}"
  44 FILES_${PN}-dev = "${glibcdevfiles}"
  45 FILES_glibc-dbg = "${glibcdbgfiles}"
  46 FILES_${PN}-dbg = "${glibcdbgfiles}"
  47 FILES_nscd = "${sbindir}/nscd* ${sysconfdir}/nscd* ${sysconfdir}/init.d/nscd*"
  48 FILES_glibc-utils = "${bindir}/* ${sbindir}/*"
  49 FILES_glibc-gconv = "${libdir}/gconv/*"
  50 FILES_catchsegv = "${bindir}/catchsegv"
  51 RDEPENDS_catchsegv = "libsegfault"
  52 FILES_glibc-pcprofile = "${base_libdir}/libpcprofile.so"
  53 FILES_glibc-thread-db = "${base_libdir}/libthread_db*"
  54 FILES_localedef = "${bindir}/localedef"
  55 RPROVIDES_glibc-dev += "libc-dev"
  56
  57 DESCRIPTION_sln = "glibc: create symbolic links between files"
  58 DESCRIPTION_nscd = "glibc: name service cache daemon for passwd, group, and hosts"
  59 DESCRIPTION_glibc-extra-nss = "glibc: nis, nisplus and hesiod search services"
  60 DESCRIPTION_ldd = "glibc: print shared library dependencies"
  61 DESCRIPTION_localedef = "glibc: compile locale definition files"
  62 DESCRIPTION_glibc-utils = "glibc: misc utilities like iconf, local, gencat, tzselect, rpcinfo, ..."
  63
  64 TMP_LOCALE="/tmp/locale${libdir}/locale"
  65
  66 locale_base_postinst() {
  67 #!/bin/sh
  68
  69 if [ "x$D" != "x" ]; then
  70   exit 1
  71 fi
  72
  73 rm -rf ${TMP_LOCALE}
  74 mkdir -p ${TMP_LOCALE}
  75 if [ -f ${libdir}/locale/locale-archive ]; then
  76         cp ${libdir}/locale/locale-archive ${TMP_LOCALE}/
  77 fi
  78 localedef --inputfile=${datadir}/i18n/locales/%s --charmap=%s --prefix=/tmp/locale %s
  79 mkdir -p ${libdir}/locale/
  80 mv ${TMP_LOCALE}/locale-archive ${libdir}/locale/
  81 rm -rf ${TMP_LOCALE}
  82 }
  83
  84 locale_base_postrm() {
  85 #!/bin/sh
  86
  87 rm -rf ${TMP_LOCALE}
  88 mkdir -p ${TMP_LOCALE}
  89 if [ -f ${libdir}/locale/locale-archive ]; then
  90         cp ${libdir}/locale/locale-archive ${TMP_LOCALE}/
  91 fi
  92 localedef --delete-from-archive --inputfile=${datadir}/locales/%s --charmap=%s --prefix=/tmp/locale %s
  93 mv ${TMP_LOCALE}/locale-archive ${libdir}/locale/
  94 rm -rf ${TMP_LOCALE}
  95 }
  96
  97 do_prep_locale_tree() {
  98         treedir=${WORKDIR}/locale-tree
  99         rm -rf $treedir
 100         mkdir -p $treedir/bin $treedir/lib $treedir/${datadir} $treedir/${libdir}/locale
 101         cp -pPR ${PKGD}${datadir}/i18n $treedir/${datadir}/i18n
 102         # unzip to avoid parsing errors
 103         for i in $treedir/${datadir}/i18n/charmaps/*gz; do
 104                 gunzip $i
 105         done
 106         ls -d ${PKGD}${base_libdir}/* | xargs -iBLAH cp -pPR BLAH $treedir/lib
 107         if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so ]; then
 108                 cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so $treedir/lib
 109         fi
 110         if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.* ]; then
 111                 cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.* $treedir/lib
 112         fi
 113         install -m 0755 ${PKGD}${bindir}/localedef $treedir/bin
 114 }
 115
 116 do_collect_bins_from_locale_tree() {
 117         treedir=${WORKDIR}/locale-tree
 118
 119         mkdir -p ${PKGD}${libdir}
 120         cp -pPR $treedir/${libdir}/locale ${PKGD}${libdir}
 121 }
 122
 123 python package_do_split_gconvs () {
 124         import os, re
 125         if (bb.data.getVar('PACKAGE_NO_GCONV', d, 1) == '1'):
 126                 bb.note("package requested not splitting gconvs")
 127                 return
 128
 129         if not bb.data.getVar('PACKAGES', d, 1):
 130                 return
 131
 132         libdir = bb.data.getVar('libdir', d, 1)
 133         if not libdir:
 134                 bb.error("libdir not defined")
 135                 return
 136         datadir = bb.data.getVar('datadir', d, 1)
 137         if not datadir:
 138                 bb.error("datadir not defined")
 139                 return
 140
 141         gconv_libdir = base_path_join(libdir, "gconv")
 142         charmap_dir = base_path_join(datadir, "i18n", "charmaps")
 143         locales_dir = base_path_join(datadir, "i18n", "locales")
 144         binary_locales_dir = base_path_join(libdir, "locale")
 145
 146         do_split_packages(d, gconv_libdir, file_regex='^(.*)\.so$', output_pattern='glibc-gconv-%s', description='gconv module for character set %s', extra_depends='glibc-gconv')
 147
 148         do_split_packages(d, charmap_dir, file_regex='^(.*)\.gz$', output_pattern='glibc-charmap-%s', description='character map for %s encoding', extra_depends='')
 149
 150         def calc_locale_deps(fn, pkg, file_regex, output_pattern, group):
 151                 deps = []
 152                 f = open(fn, "r")
 153                 c_re = re.compile('^copy "(.*)"')
 154                 i_re = re.compile('^include "(\w+)".*')
 155                 for l in f.readlines():
 156                         m = c_re.match(l) or i_re.match(l)
 157                         if m:
 158                                 dp = legitimize_package_name('glibc-localedata-%s' % m.group(1))
 159                                 if not dp in deps:
 160                                         deps.append(dp)
 161                 f.close()
 162                 if deps != []:
 163                         bb.data.setVar('RDEPENDS_%s' % pkg, " ".join(deps), d)
 164
 165         do_split_packages(d, locales_dir, file_regex='(.*)', output_pattern='glibc-localedata-%s', description='locale definition for %s', hook=calc_locale_deps, extra_depends='')
 166         bb.data.setVar('PACKAGES', bb.data.getVar('PACKAGES', d) + ' glibc-gconv', d)
 167
 168         use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
 169
 170         dot_re = re.compile("(.*)\.(.*)")
 171
 172         if use_bin != "precompiled":
 173                 supported = bb.data.getVar('GLIBC_GENERATE_LOCALES', d, 1)
 174                 if not supported or supported == "all":
 175                     f = open(base_path_join(bb.data.getVar('WORKDIR', d, 1), "SUPPORTED"), "r")
 176                     supported = f.readlines()
 177                     f.close()
 178                 else:
 179                     supported = supported.split()
 180                     supported = map(lambda s:s.replace(".", " ") + "\n", supported)
 181         else:
 182                 supported = []
 183                 full_bin_path = bb.data.getVar('PKGD', d, True) + binary_locales_dir
 184                 for dir in os.listdir(full_bin_path):
 185                         dbase = dir.split(".")
 186                         d2 = "  "
 187                         if len(dbase) > 1:
 188                                 d2 = "." + dbase[1].upper() + "  "
 189                         supported.append(dbase[0] + d2)
 190
 191         # Collate the locales by base and encoding
 192         utf8_only = int(bb.data.getVar('LOCALE_UTF8_ONLY', d, 1) or 0)
 193         encodings = {}
 194         for l in supported:
 195                 l = l[:-1]
 196                 (locale, charset) = l.split(" ")
 197                 if utf8_only and charset != 'UTF-8':
 198                         continue
 199                 m = dot_re.match(locale)
 200                 if m:
 201                         locale = m.group(1)
 202                 if not encodings.has_key(locale):
 203                         encodings[locale] = []
 204                 encodings[locale].append(charset)
 205
 206         def output_locale_source(name, pkgname, locale, encoding):
 207                 bb.data.setVar('RDEPENDS_%s' % pkgname, 'localedef glibc-localedata-%s glibc-charmap-%s' % (legitimize_package_name(locale), legitimize_package_name(encoding)), d)
 208                 bb.data.setVar('pkg_postinst_%s' % pkgname, bb.data.getVar('locale_base_postinst', d, 1) % (locale, encoding, locale), d)
 209                 bb.data.setVar('pkg_postrm_%s' % pkgname, bb.data.getVar('locale_base_postrm', d, 1) % (locale, encoding, locale), d)
 210
 211         def output_locale_binary_rdepends(name, pkgname, locale, encoding):
 212                 m = re.match("(.*)\.(.*)", name)
 213                 if m:
 214                         glibc_name = "%s.%s" % (m.group(1), m.group(2).lower().replace("-",""))
 215                 else:
 216                         glibc_name = name
 217                 bb.data.setVar('RDEPENDS_%s' % pkgname, legitimize_package_name('glibc-binary-localedata-%s' % glibc_name), d)
 218
 219         def output_locale_binary(name, pkgname, locale, encoding):
 220                 # This is a hack till linux-libc-headers gets patched for the missing arm syscalls and all arm device kernels as well
 221                 if bb.data.getVar("DISTRO_NAME", d, 1) == "Angstrom":
 222                         kernel_ver = "2.6.24"
 223                 elif bb.data.getVar("DISTRO_NAME", d, 1) == "KaeilOS":
 224                         kernel_ver = "2.6.24"
 225                 else:
 226                         kernel_ver = bb.data.getVar("OLDEST_KERNEL", d, 1)
 227
 228                 qemu = qemu_target_binary(d) + " -s 1048576"
 229                 if kernel_ver:
 230                         qemu += " -r %s" % (kernel_ver)
 231                 pkgname = 'locale-base-' + legitimize_package_name(name)
 232
 233                 treedir = base_path_join(bb.data.getVar("WORKDIR", d, 1), "locale-tree")
 234                 ldlibdir = "%s/lib" % treedir
 235                 path = bb.data.getVar("PATH", d, 1)
 236                 i18npath = base_path_join(treedir, datadir, "i18n")
 237
 238                 localedef_opts = "--force --old-style --no-archive --prefix=%s --inputfile=%s/i18n/locales/%s --charmap=%s %s" % (treedir, datadir, locale, encoding, name)
 239
 240                 qemu_options = bb.data.getVar("QEMU_OPTIONS_%s" % bb.data.getVar('PACKAGE_ARCH', d, 1), d, 1)
 241                 if not qemu_options:
 242                         qemu_options = bb.data.getVar('QEMU_OPTIONS', d, 1)
 243
 244                 cmd = "PATH=\"%s\" I18NPATH=\"%s\" %s -L %s -E LD_LIBRARY_PATH=%s %s %s/bin/localedef %s" % (path, i18npath, qemu, treedir, ldlibdir, qemu_options, treedir, localedef_opts)
 245                 bb.note("generating locale %s (%s)" % (locale, encoding))
 246                 if os.system(cmd):
 247                         raise bb.build.FuncFailed("localedef returned an error (command was %s)." % cmd)
 248
 249         def output_locale(name, locale, encoding):
 250                 pkgname = 'locale-base-' + legitimize_package_name(name)
 251                 bb.data.setVar('ALLOW_EMPTY_%s' % pkgname, '1', d)
 252                 bb.data.setVar('PACKAGES', '%s %s' % (pkgname, bb.data.getVar('PACKAGES', d, 1)), d)
 253                 rprovides = 'virtual-locale-%s' % legitimize_package_name(name)
 254                 m = re.match("(.*)_(.*)", name)
 255                 if m:
 256                         rprovides += ' virtual-locale-%s' % m.group(1)
 257                 bb.data.setVar('RPROVIDES_%s' % pkgname, rprovides, d)
 258                 if use_bin == "compile":
 259                         output_locale_binary_rdepends(name, pkgname, locale, encoding)
 260                         output_locale_binary(name, pkgname, locale, encoding)
 261                 elif use_bin == "precompiled":
 262                         output_locale_binary_rdepends(name, pkgname, locale, encoding)
 263                 else:
 264                         output_locale_source(name, pkgname, locale, encoding)
 265
 266         if use_bin == "compile":
 267                 bb.note("preparing tree for binary locale generation")
 268                 bb.build.exec_func("do_prep_locale_tree", d)
 269
 270         # Reshuffle names so that UTF-8 is preferred over other encodings
 271         non_utf8 = []
 272         for l in encodings.keys():
 273                 if len(encodings[l]) == 1:
 274                         output_locale(l, l, encodings[l][0])
 275                         if encodings[l][0] != "UTF-8":
 276                                 non_utf8.append(l)
 277                 else:
 278                         if "UTF-8" in encodings[l]:
 279                                 output_locale(l, l, "UTF-8")
 280                                 encodings[l].remove("UTF-8")
 281                         else:
 282                                 non_utf8.append(l)
 283                         for e in encodings[l]:
 284                                 output_locale('%s.%s' % (l, e), l, e)
 285
 286         if non_utf8 != [] and use_bin != "precompiled":
 287                 bb.note("the following locales are supported only in legacy encodings:")
 288                 bb.note("  " + " ".join(non_utf8))
 289
 290         if use_bin == "compile":
 291                 bb.note("collecting binary locales from locale tree")
 292                 bb.build.exec_func("do_collect_bins_from_locale_tree", d)
 293                 do_split_packages(d, binary_locales_dir, file_regex='(.*)', output_pattern='glibc-binary-localedata-%s', description='binary locale definition for %s', extra_depends='', allow_dirs=True)
 294         elif use_bin == "precompiled":
 295                 do_split_packages(d, binary_locales_dir, file_regex='(.*)', output_pattern='glibc-binary-localedata-%s', description='binary locale definition for %s', extra_depends='', allow_dirs=True)
 296         else:
 297                 bb.note("generation of binary locales disabled. this may break i18n!")
 298
 299 }
 300
 301 # We want to do this indirection so that we can safely 'return'
 302 # from the called function even though we're prepending
 303 python populate_packages_prepend () {
 304         if bb.data.getVar('DEBIAN_NAMES', d, 1):
 305                 bb.data.setVar('PKG_glibc', 'libc6', d)
 306                 bb.data.setVar('PKG_glibc-dev', 'libc6-dev', d)
 307         bb.build.exec_func('package_do_split_gconvs', d)
 308 }