recipes/matchbox-wm/matchbox-wm_1.2.bb

   1 require matchbox-wm.inc
   2
   3 DEPENDS = "libmatchbox virtual/libx11 libxext libxcomposite libxfixes libxdamage libxrender startup-notification expat gconf gconf-native "
   4 RDEPENDS_${PN} = ""
   5
   6 PR = "r7"
   7
   8 SRC_URI = "http://matchbox-project.org/sources/matchbox-window-manager/1.2/matchbox-window-manager-${PV}.tar.bz2 \
   9            file://configure_fix.patch \
  10            file://select-client-crash.patch \
  11            file://gconf-2.m4 \
  12            file://kbdconfig"
  13
  14 S = "${WORKDIR}/matchbox-window-manager-${PV}"
  15
  16 inherit autotools pkgconfig update-alternatives
  17
  18 FILES_${PN} = "${bindir}/* \
  19                ${datadir}/matchbox \
  20                ${sysconfdir}/matchbox \
  21                ${sysconfdir}/gconf/ \
  22                ${datadir}/themes/blondie/matchbox \
  23                ${datadir}/themes/Default/matchbox \
  24                ${datadir}/themes/MBOpus/matchbox \
  25                /var/lib/*"
  26
  27 ALTERNATIVE_NAME = "x-window-manager"
  28 ALTERNATIVE_LINK = "${bindir}/x-window-manager"
  29 ALTERNATIVE_PATH = "${bindir}/matchbox-window-manager"
  30 ALTERNATIVE_PRIORITY = "10"
  31
  32 EXTRA_OECONF = " \
  33                 --enable-startup-notification\
  34                 --enable-gconf \
  35                  --with-expat-lib=${STAGING_LIBDIR} \
  36                  --with-expat-includes=${STAGING_INCDIR} \
  37                 --disable-xrm"
  38
  39 do_configure_prepend () {
  40     cp ${WORKDIR}/gconf-2.m4 ${S}/
  41 }
  42
  43 do_install_prepend() {
  44     install -d ${D}/var/lib/dbus
  45     install ${WORKDIR}/kbdconfig ${S}/data/kbdconfig
  46 }
  47
  48 SRC_URI[md5sum] = "3e158dcf57823b55c926d95b245500fb"
  49 SRC_URI[sha256sum] = "81a23a4af797cf350759fd5ac738797015a66dd5dba2f3d9f3c6908506c1ceff"