recipes/ppp/ppp_2.4.5.bb

   1 SECTION = "console/network"
   2 DESCRIPTION = "Point-to-Point Protocol (PPP) daemon"
   3 HOMEPAGE = "http://samba.org/ppp/"
   4 DEPENDS = "libpcap"
   5 LICENSE = "BSD GPLv2"
   6 PR = "r1"
   7 # Not well tested
   8 DEFAULT_PREFERENCE = "-1"
   9
  10 PARALLEL_MAKE = ""
  11
  12 SRC_URI = "http://ppp.samba.org/ftp/ppp/ppp-${PV}.tar.gz \
  13         file://ppp-2.4.4-mppe-mppc.1.1.patch \
  14         file://makefile.patch \
  15         file://cifdefroute.patch \
  16         file://pppd-resolv-varrun.patch \
  17         file://enable-ipv6.patch \
  18         file://makefile-remove-hard-usr-reference.patch \
  19         file://ldflags.patch \
  20         file://pon \
  21         file://poff \
  22         file://init \
  23         file://ip-up \
  24         file://ip-down \
  25         file://08setupdns \
  26         file://92removedns"
  27
  28 inherit autotools
  29
  30 TARGET_CC_ARCH += " ${LDFLAGS}"
  31 EXTRA_OEMAKE = "STRIPPROG=${STRIP} MANDIR=${D}${datadir}/man/man8 INCDIR=${D}${includedir} LIBDIR=${D}${libdir}/pppd/${PV} BINDIR=${D}${sbindir}"
  32 EXTRA_OECONF = "--disable-strip"
  33
  34 do_install_append () {
  35         make INCDIR=${D}/${includedir} install-devel
  36         make install-etcppp ETCDIR=${D}/${sysconfdir}/ppp
  37         mkdir -p ${D}${bindir}/ ${D}${sysconfdir}/init.d
  38         mkdir -p ${D}${sysconfdir}/ppp/ip-up.d/
  39         mkdir -p ${D}${sysconfdir}/ppp/ip-down.d/
  40         mkdir -p ${D}${sysconfdir}/ppp/peers/
  41         install -m 0755 ${WORKDIR}/pon ${D}${bindir}/pon
  42         install -m 0755 ${WORKDIR}/poff ${D}${bindir}/poff
  43         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ppp
  44         install -m 0755 ${WORKDIR}/ip-up ${D}${sysconfdir}/ppp/
  45         install -m 0755 ${WORKDIR}/ip-down ${D}${sysconfdir}/ppp/
  46         install -m 0755 ${WORKDIR}/08setupdns ${D}${sysconfdir}/ppp/ip-up.d/
  47         install -m 0755 ${WORKDIR}/92removedns ${D}${sysconfdir}/ppp/ip-down.d/
  48         rm -rf ${D}/${mandir}/man8/man8
  49 }
  50
  51 CONFFILES_${PN} = "${sysconfdir}/ppp/pap-secrets ${sysconfdir}/ppp/chap-secrets ${sysconfdir}/ppp/options"
  52 PACKAGES =+ "ppp-oa ppp-oe ppp-radius ppp-winbind ppp-minconn ppp-password ppp-tools"
  53 FILES_${PN}        = "${sysconfdir} ${bindir} ${sbindir}/chat ${sbindir}/pppd"
  54 FILES_${PN}_nylon  = "${sysconfdir} ${bindir} ${sbindir}/chat ${sbindir}/pppd ${sbindir}/tdbread"
  55 FILES_${PN}-dbg += "${libdir}/pppd/${PV}/.debug"
  56 FILES_${PN}-oa       = "${libdir}/pppd/${PV}/pppoatm.so"
  57 FILES_${PN}-oe       = "${sbindir}/pppoe-discovery ${libdir}/pppd/${PV}/rp-pppoe.so"
  58 FILES_${PN}-radius   = "${libdir}/pppd/${PV}/radius.so ${libdir}/pppd/${PV}/radattr.so ${libdir}/pppd/${PV}/radrealms.so"
  59 FILES_${PN}-winbind  = "${libdir}/pppd/${PV}/winbind.so"
  60 FILES_${PN}-minconn  = "${libdir}/pppd/${PV}/minconn.so"
  61 FILES_${PN}-password = "${libdir}/pppd/${PV}/pass*.so"
  62 FILES_${PN}-tools    = "${sbindir}/pppstats ${sbindir}/pppdump"
  63 DESCRIPTION_ppp-oa       = "Plugin for PPP needed for PPP-over-ATM"
  64 DESCRIPTION_ppp-oe       = "Plugin for PPP needed for PPP-over-Ethernet"
  65 DESCRIPTION_ppp-radius   = "Plugin for PPP that are related to RADIUS"
  66 DESCRIPTION_ppp-winbind  = "Plugin for PPP to authenticate against Samba or Windows"
  67 DESCRIPTION_ppp-minconn  = "Plugin for PPP to specify a minimum connect time before the idle timeout applies"
  68 DESCRIPTION_ppp-password = "Plugin for PPP to get passwords via a pipe"
  69 DESCRIPTION_ppp-tools    = "The pppdump and pppstats utitilities"
  70 RDEPENDS_ppp_minconn    += "libpcap0.8"
  71
  72 pkg_postinst_${PN}() {
  73 if test "x$D" != "x"; then
  74         exit 1
  75 else
  76         chmod u+s ${sbindir}/pppd
  77 fi
  78 }
  79
  80 SRC_URI[md5sum] = "4621bc56167b6953ec4071043fe0ec57"
  81 SRC_URI[sha256sum] = "43317afec9299f9920b96f840414c977f0385410202d48e56d2fdb8230003505"
  82