recipes/glib-2.0/glib-2.0_2.24.0.bb

   1 DESCRIPTION = "GLib is a general-purpose utility library, \
   2 which provides many useful data types, macros, \
   3 type conversions, string utilities, file utilities, a main \
   4 loop abstraction, and so on. It works on many \
   5 UNIX-like platforms, Windows, OS/2 and BeOS."
   6 LICENSE = "LGPL"
   7 SECTION = "libs"
   8 PRIORITY = "optional"
   9 DEPENDS = "glib-2.0-native gtk-doc virtual/libiconv virtual/libintl zlib"
  10
  11 PR = "r1"
  12
  13 SRC_URI = "\
  14   http://ftp.gnome.org/pub/GNOME/sources/glib/2.24/glib-${PV}.tar.bz2;name=archive \
  15   file://glibconfig-sysdefs.h \
  16   file://configure-libtool.patch;patch=1 \
  17   file://g_once_init_enter.patch;patch=1 \
  18   file://gatomic-proper-pointer-get-cast.patch;patch=1 \
  19   file://gio.patch;patch=1 \
  20 "
  21
  22 SRC_URI[archive.md5sum] = "45a8bc697d07f859566c0b64c40382a8"
  23 SRC_URI[archive.sha256sum] = "7b6aa2cf21e734a6092a711bf196b8d2ddc589b971f93337610c10fa4f23400d"
  24
  25 SRC_URI_append_arm = " file://atomic-thumb.patch;patch=1"
  26 SRC_URI_append_armv6 = " file://gatomic_armv6.patch;patch=1"
  27 SRC_URI_append_armv7a = " file://gatomic_armv6.patch;patch=1"
  28
  29 inherit autotools gettext
  30
  31 S = "${WORKDIR}/glib-${PV}"
  32
  33 EXTRA_OECONF = "--disable-debug "
  34
  35 # Add and entry for your favourite arch if your (g)libc has a sane printf
  36 EXTRA_OECONF_append_glibc_arm = "  --enable-included-printf=no "
  37
  38 do_configure_prepend () {
  39         install -m 0644 ${WORKDIR}/glibconfig-sysdefs.h .
  40 }
  41
  42 do_install_append() {
  43         sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g ${D}${bindir}/glib-mkenums || true
  44 }
  45
  46 DEPENDS_virtclass-native = "gettext-native gtk-doc-native \
  47                             pkgconfig-native"
  48 EXTRA_OECONF_virtclass-native = ""
  49
  50 do_configure_prepend_virtclass-native() {
  51     if [ -e ${S}/${TARGET_SYS}-libtool ] ; then
  52                 echo "${TARGET_SYS}-libtool already present"
  53     else
  54         cp ${STAGING_BINDIR}/${TARGET_SYS}-libtool ${S}
  55     fi
  56
  57 }
  58
  59 BBCLASSEXTEND = "native"
  60
  61 PACKAGES =+ "gobject-2.0 gmodule-2.0 gthread-2.0 gio-2.0 glib-2.0-utils "
  62 LEAD_SONAME = "libglib-2.0.*"
  63 FILES_glib-2.0-utils = "${bindir}/*"
  64 FILES_${PN} = "${libdir}/lib*so.* ${libdir}/gio/modules/*.so"
  65 FILES_${PN}-dev += "${libdir}/glib-2.0 ${datadir}/glib-2.0 ${libdir}/gio/modules/*.la"
  66 FILES_${PN}-dbg += "${libdir}/gio/modules/.debug"
  67 FILES_gmodule-2.0 = "${libdir}/libgmodule-2.0.so.*"
  68 FILES_gobject-2.0 = "${libdir}/libgobject-2.0.so.*"
  69 FILES_gio-2.0 = "${libdir}/libgio-2.0.so.*"
  70 FILES_gthread-2.0 = "${libdir}/libgthread-2.0.so.*"
  71
  72 # Let various glib components end up in glib package
  73 # for compatibility (with binary packages from Maemo).
  74 FILES_gthread-2.0_chinook-compat = ""
  75 FILES_gmodule-2.0_chinook-compat = ""
  76 FILES_gobject-2.0_chinook-compat = ""
  77 FILES_gio-2.0_chinook-compat = ""