recipes/mozilla/firefox-l10n.inc

   1 # Copyright (C) 2009, O.S. Systems Software Ltda. All Rights Reserved
   2 # Released under the MIT license (see packages/COPYING)
   3
   4 def get_language_name(package):
   5     lang = package.replace('firefox-l10n-', '')
   6
   7     if lang.find('-'):
   8         lang = lang.split('-')
   9         lang[1] = lang[1].upper()
  10         lang = '-'.join(lang)
  11
  12     return lang
  13
  14 DEPENDS = "unzip-native"
  15 RDEPENDS_${PN} = "firefox"
  16 LANGUAGE = "${@get_language_name('${PN}')}"
  17
  18 SRC_URI = "http://releases.mozilla.org/pub/mozilla.org/firefox/releases/${PV}/linux-i686/xpi/${LANGUAGE}.xpi"
  19 S = "${WORKDIR}"
  20
  21 do_configure() {
  22         unzip -o -q -d ${LANGUAGE} ${LANGUAGE}.xpi
  23 }
  24
  25 INC_PR = "r2"
  26
  27 do_install() {
  28         cd ${S}/${LANGUAGE}
  29
  30         # Get extension UUID
  31         EXTENSION=`cat install.rdf | sed --posix '/em:id=/!d;s/[ ]*em:id="//;s/".*//'`
  32
  33         mkdir -p ${D}/usr/lib/firefox-${PV}/extensions/${EXTENSION}/chrome
  34         mkdir -p ${D}/usr/lib/firefox-${PV}/extensions/${EXTENSION}/uninstall
  35         install -m 644 chrome/*.jar ${D}/usr/lib/firefox-${PV}/extensions/${EXTENSION}/chrome
  36         install -m 644 install.rdf ${D}/usr/lib/firefox-${PV}/extensions/${EXTENSION}
  37         install -m 644 chrome.manifest ${D}/usr/lib/firefox-${PV}/extensions/${EXTENSION}
  38
  39         cat install.rdf \
  40            | sed --posix '/<em:locale>/!d' \
  41            | sed --posix "s/.*/register      global  locale  ${LANGUAGE}/" \
  42            > ${D}/usr/lib/firefox-${PV}/extensions/${EXTENSION}/uninstall/Uninstall
  43 }
  44
  45 FILES_${PN} += "/usr/lib/firefox-${PV}"
  46 PACKAGE_ARCH = "all"