recipes/clamsmtp/clamsmtp_1.8.bb

   1 DESCRIPTION = "ClamSMTP is an SMTP filter that allows you to check for \
   2 viruses using the ClamAV anti-virus software. It accepts SMTP connections \
   3 and forwards the SMTP commands and responses to another SMTP server. The \
   4 'DATA' email body is intercepted and scanned before forwarding. ClamSMTP \
   5 has an optional transparent proxy mode."
   6 HOMEPAGE = "http://memberwebs.com/nielsen/software/clamsmtp/"
   7 SECTION = "network"
   8 LICENSE = "BSD"
   9 DEPENDS = "clamav"
  10 RDEPENDS_${PN} = "clamav-daemon"
  11 PR = "r2"
  12
  13 SRC_URI = "http://memberwebs.com/nielsen/software/clamsmtp/clamsmtp-${PV}.tar.gz \
  14            file://update-config.patch \
  15            file://clamsmtp.init \
  16            file://doc.configure.txt"
  17
  18 inherit autotools update-rc.d
  19
  20 do_configure () {
  21         # no autoreconf please
  22         aclocal
  23         autoconf
  24         libtoolize --force
  25         oe_runconf
  26 }
  27 do_install_append () {
  28         install -m 0755 -d ${D}${sysconfdir}/init.d \
  29                            ${D}${docdir}/clamsmtp
  30         install -m 755 ${WORKDIR}/clamsmtp.init ${D}${sysconfdir}/init.d/clamsmtpd
  31         install -m 644 doc/clamsmtpd.conf ${D}${sysconfdir}/clamsmtpd.conf
  32         install -m 644 README ${D}${docdir}/clamsmtp
  33         install -m 644 ${WORKDIR}/doc.configure.txt ${D}${docdir}/clamsmtp/configure.txt
  34         install -m 644 scripts/virus_action.sh ${D}${docdir}/clamsmtp
  35 }
  36
  37 CONFFILES_${PN} = "${sysconfdir}/clamsmtpd.conf"
  38
  39 INITSCRIPT_NAME = "clamsmtpd"
  40 INITSCRIPT_PARAMS = "defaults 65 35"
  41
  42 SRC_URI[md5sum] = "04da6aab94934641fcf9e7a7598346fb"
  43 SRC_URI[sha256sum] = "c09b24c82f858845e235df4c8b2639240a7b786de66b595e351be86ab60663a5"