conf/bitbake.conf

   1 ##################################################################
   2 # Recipe Parsing
   3 ##################################################################
   4 BBMASK = "/(nonworking|obsolete)/"
   5
   6 ##################################################################
   7 # Standard target filesystem layout.
   8 ##################################################################
   9
  10 # Path prefixes
  11 layout_prefix = "${prefix}"
  12 layout_exec_prefix = "${exec_prefix}"
  13 layout_base_prefix = "${base_prefix}"
  14
  15 # Base paths
  16 layout_base_bindir = "${base_bindir}"
  17 layout_base_sbindir = "${base_sbindir}"
  18 layout_base_libdir = "${base_libdir}"
  19
  20 # Architecture independent paths
  21 layout_sysconfdir = "${sysconfdir}"
  22 layout_localstatedir = "${localstatedir}"
  23 layout_servicedir = "${servicedir}"
  24 layout_sharedstatedir = "${sharedstatedir}"
  25 layout_datadir = "${datadir}"
  26 layout_infodir = "${infodir}"
  27 layout_mandir = "${mandir}"
  28 layout_docdir = "${docdir}"
  29
  30 # Architecture dependent paths
  31 layout_bindir = "${bindir}"
  32 layout_sbindir = "${sbindir}"
  33 layout_libdir = "${libdir}"
  34 layout_includedir = "${includedir}"
  35 layout_libexecdir = "${libexecdir}"
  36
  37 ##################################################################
  38 # Standard target filesystem paths.
  39 ##################################################################
  40
  41 # Path prefixes
  42 export base_prefix = ""
  43 export prefix = "/usr"
  44 export exec_prefix = "/usr"
  45
  46 # Base paths
  47 export base_bindir = "${base_prefix}/bin"
  48 export base_sbindir = "${base_prefix}/sbin"
  49 export base_libdir = "${base_prefix}/lib"
  50
  51 # Architecture independent paths
  52 export datadir = "${prefix}/share"
  53 export sysconfdir = "${base_prefix}/etc"
  54 export servicedir = "${base_prefix}/srv"
  55 export sharedstatedir = "${base_prefix}/com"
  56 export localstatedir = "${base_prefix}/var"
  57 export infodir = "${datadir}/info"
  58 export mandir = "${datadir}/man"
  59 export docdir = "${datadir}/doc"
  60
  61 # Architecture dependent paths
  62 export bindir = "${exec_prefix}/bin"
  63 export sbindir = "${exec_prefix}/sbin"
  64 export libexecdir = "${exec_prefix}/libexec"
  65 export libdir = "${exec_prefix}/lib"
  66 export includedir = "${exec_prefix}/include"
  67 export oldincludedir = "${exec_prefix}/include"
  68
  69 #
  70 # These must match the various bbclass layout definitions
  71 #
  72 base_bindir_native = "/bin"
  73 base_sbindir_native = "/sbin"
  74 sysconfdir_native = "/etc"
  75 prefix_native = "/usr"
  76 bindir_native = "${prefix_native}/bin"
  77 sbindir_native = "${prefix_native}/sbin"
  78 includedir_native = "${prefix_native}/include"
  79 libdir_native = "${prefix_native}/lib"
  80 datadir_native = "${prefix_native}/share"
  81 bindir_cross = "/bin"
  82
  83 #
  84 # Cross recipes need to know about the target layout
  85 # := is used carefully here
  86 #
  87 target_datadir := "${datadir}"
  88
  89 ##################################################################
  90 # Architecture-dependent build variables.
  91 ##################################################################
  92
  93 BUILD_ARCH := "${@os.uname()[4]}"
  94 BUILD_OS := "${@os.uname()[0].lower()}"
  95 BUILD_VENDOR = ""
  96 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  97 BUILD_PREFIX = ""
  98 BUILD_CC_ARCH = ""
  99 BUILD_EXEEXT = ""
 100
 101 HOST_ARCH = "${TARGET_ARCH}"
 102 HOST_OS = "${TARGET_OS}"
 103 HOST_VENDOR = "${TARGET_VENDOR}"
 104 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
 105 HOST_PREFIX = "${TARGET_PREFIX}"
 106 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
 107 HOST_EXEEXT = ""
 108
 109 TARGET_ARCH ?= "INVALID"
 110 TARGET_OS = "INVALID"
 111 TARGET_VENDOR = "${BUILD_VENDOR}"
 112 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
 113 TARGET_PREFIX = "${TARGET_SYS}-"
 114 TARGET_CC_ARCH = ""
 115 TARGET_EXEEXT = ""
 116
 117 SDK_ARCH ?= "${BUILD_ARCH}"
 118 SDK_OS ?= "${BUILD_OS}"
 119 SDK_VENDOR ?= "${BUILD_VENDOR}"
 120 SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + bb.data.getVar('SDK_OS', d, 1), ''][bb.data.getVar('SDK_OS', d, 1) == ('' or 'custom')]}"
 121 SDK_PREFIX = "${SDK_SYS}-"
 122 SDK_CC_ARCH ?= "${BUILD_CC_ARCH}"
 123 SDK_EXEEXT = ""
 124
 125 # A shortcut for the commonly used value
 126 EXEEXT = "${HOST_EXEEXT}"
 127
 128 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
 129 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
 130 PACKAGE_EXTRA_ARCHS ?= ""
 131 MACHINE_ARCH = "${@oe.utils.ifelse(bool(d.getVar('MACHINE', True)), '${MACHINE}', \
 132                                    'BASE_PACKAGE_ARCH')}"
 133 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
 134
 135 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
 136 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 137 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
 138 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
 139 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 140
 141 # select proper CPU to get binary locales generated
 142 QEMU_OPTIONS = ""
 143 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 144 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 145 QEMU_OPTIONS_armv6-novfp = "-cpu arm1136"
 146 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 147
 148 ##################################################################
 149 # Date/time variables.
 150 ##################################################################
 151
 152 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 153 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 154 DATETIME = "${DATE}${TIME}"
 155
 156 ##################################################################
 157 # Openembedded Software Prerequisites.
 158 ##################################################################
 159
 160 # python-native should be here but python relies on building
 161 # its own in staging
 162 ASSUME_PROVIDED = "\
 163     bc-native \
 164     bzip2-native \
 165     cvs-native \
 166     diffstat-native \
 167     patch-native \
 168     perl-native-runtime \
 169     python-native-runtime \
 170     svn-native \
 171     texinfo-native \
 172     util-linux-native \
 173     "
 174
 175 ##################################################################
 176 # Package default variables.
 177 ##################################################################
 178 PN = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[0] or 'defaultpkgname'}"
 179 PV = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[1] or '1.0'}"
 180 PR = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[2] or 'r0'}"
 181 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 182 PE ?= "0"
 183 EXTENDPE = "${@int('${PE}') and '${PE}_' or ''}"
 184 EXTENDPEVER = "${@int('${PE}') and '${PE}:' or ''}"
 185 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 186 P = "${PN}-${PV}"
 187
 188 # Define a PR for kernels that machines can override so things like
 189 # modules get rebuilt
 190 MACHINE_KERNEL_PR = ""
 191
 192 # Base package name
 193 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 194 # otherwise it is the same as PN and P
 195 SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -nativesdk -crosssdk -cross-canadian -sdk"
 196 BPN = "${@base_prune_suffix('${PN}', '${SPECIAL_PKGSUFFIX}'.split(), d)}"
 197 BP = "${BPN}-${PV}"
 198
 199 # Package info.
 200
 201 SECTION = "base"
 202 PRIORITY = "optional"
 203 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 204 LICENSE = "unknown"
 205 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 206 HOMEPAGE = "unknown"
 207
 208 # Package dependencies and provides.
 209
 210 # Ensure that -dev packages recommend the corresponding -dev packages of their
 211 # deps, and the same for -dbg.
 212 DEPCHAIN_PRE  = ""
 213 DEPCHAIN_POST = "-dev -dbg"
 214
 215 DEPENDS = ""
 216 RDEPENDS = ""
 217 PROVIDES = ""
 218 PROVIDES_prepend = "${P} ${PF} ${PN} "
 219 RPROVIDES = ""
 220
 221 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 222
 223 SOLIBS = ".so.*"
 224 SOLIBS_darwin = ".*.dylib"
 225 SOLIBS_darwin8 = ".*.dylib"
 226 SOLIBS_darwin9 = ".*.dylib"
 227
 228 SOLIBSDEV = ".so"
 229 SOLIBSDEV_darwin = ".dylib"
 230 SOLIBSDEV_darwin8 = ".dylib"
 231 SOLIBSDEV_darwin9 = ".dylib"
 232
 233 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-static ${PN}-locale"
 234 #enable this when bitbake is upgraded to cope with ++ values in the field
 235 PACKAGES_DYNAMIC = "${PN}-locale-*"
 236 FILES = ""
 237
 238 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
 239             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 240             ${base_bindir}/* ${base_sbindir}/* \
 241             ${base_libdir}/*${SOLIBS} \
 242             ${datadir}/${PN} ${libdir}/${PN}/* \
 243             ${datadir}/pixmaps ${datadir}/applications \
 244             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 245             ${libdir}/bonobo/servers"
 246
 247 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 248             ${datadir}/gnome/help"
 249 SECTION_${PN}-doc = "doc"
 250
 251 FILES_${PN}-static = "${libdir}/*.a ${base_libdir}/*.a"
 252
 253 FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
 254                 ${libdir}/*.o ${libdir}/pkgconfig \
 255                 ${base_libdir}/*.o ${datadir}/aclocal ${datadir}/pkgconfig"
 256 SECTION_${PN}-dev = "devel"
 257 ALLOW_EMPTY_${PN}-dev = "1"
 258 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 259
 260 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 261             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 262             ${libdir}/matchbox-panel/.debug ${datadir}/gdb/autoload"
 263 SECTION_${PN}-dbg = "devel"
 264 ALLOW_EMPTY_${PN}-dbg = "1"
 265 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 266
 267 FILES_${PN}-locale = "${datadir}/locale"
 268
 269 # file:// search paths
 270 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 271 FILESPATHBASE = "${FILE_DIRNAME}"
 272 FILESPATHPKG = "${PF}:${P}:${PN}:${BP}:${BPN}:files:."
 273 FILESPATH = "${@':'.join([os.path.normpath(os.path.join(fp, p, o)) for fp in d.getVar('FILESPATHBASE', 1).split(':') for p in d.getVar('FILESPATHPKG', 1).split(':') for o in (d.getVar('OVERRIDES', 1) + ':').split(':')])}"
 274 FILESDIR = "${@bb.which(d.getVar('FILESPATH', 1), '.')}"
 275
 276 ##################################################################
 277 # General work and output directories for the build system.
 278 ##################################################################
 279
 280 TMPDIR = "${TOPDIR}/tmp"
 281 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 282 CO_DIR = "${DL_DIR}"
 283 CVSDIR = "${CO_DIR}/cvs"
 284 SVNDIR = "${CO_DIR}/svn"
 285 GITDIR = "${CO_DIR}/git"
 286 BZRDIR = "${CO_DIR}/bzr"
 287 HGDIR = "${CO_DIR}/hg"
 288
 289 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 290 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 291 T = "${WORKDIR}/temp"
 292 D = "${WORKDIR}/image"
 293 S = "${WORKDIR}/${BP}"
 294 B = "${S}"
 295
 296 STAGING_DIR = "${TMPDIR}/sysroots"
 297
 298 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 299 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
 300 STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
 301 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH}${base_bindir_native}"
 302 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
 303 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
 304 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
 305 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
 306
 307 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 308 # specific packages - hack around it for now.
 309 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 310 STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
 311 STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
 312 STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
 313 STAGING_ETCDIR = "${STAGING_DIR_HOST}${sysconfdir}"
 314 STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
 315 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
 316 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 317 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 318 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 319
 320 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 321 # specific packages - hack around it for now.
 322 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 323 STAGING_DIR_JAVA = "${STAGING_DATADIR}/java"
 324
 325 STAGING_DIR_SDK = "${STAGING_DIR}/${SDK_SYS}"
 326
 327 # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
 328 # packaged staging and/or multimachine.
 329 DEPLOY_DIR ?= "${TMPDIR}/deploy"
 330 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 331 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 332 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 333 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 334 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 335 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 336
 337 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 338
 339 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 340 SDK_PATH = "/usr/local/${SDK_NAME}"
 341 SDKPATH = "${SDK_PATH}"
 342
 343 ##################################################################
 344 # Kernel info.
 345 ##################################################################
 346
 347 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 348
 349 ##################################################################
 350 # Specific image creation and rootfs population info.
 351 ##################################################################
 352
 353 IMAGE_ROOTFS = "${TMPDIR}/rootfs/${PN}"
 354 IMAGE_BASENAME = "${PN}"
 355 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 356 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 357 IMAGE_EXTRA_SPACE = 10240
 358
 359 UBI_VOLNAME ?= "${MACHINE}-rootfs"
 360
 361 IMAGE_CMD = ""
 362 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 363 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 364 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 365 IMAGE_CMD_ext2 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 366 IMAGE_CMD_ext2.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz"
 367 IMAGE_CMD_ext2.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.bz2"
 368 IMAGE_CMD_ext3 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 369 IMAGE_CMD_ext3.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz"
 370 IMAGE_CMD_ext3.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.bz2"
 371 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 372 IMAGE_CMD_squashfs-lzma = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend -comp lzma"
 373 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 374 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 375 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 376 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio) ${EXTRA_IMAGECMD}"
 377 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}"
 378 IMAGE_CMD_cpio.gz.u-boot = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}; mkimage -A ${UBOOT_ARCH} -O linux -T ramdisk -C gzip -n ${IMAGE_NAME} -d ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz.u-boot"
 379 IMAGE_CMD_cpio.lzma = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | lzma -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.lzma) ${EXTRA_IMAGECMD}"
 380 IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
 381 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 382
 383 EXTRA_IMAGECMD = ""
 384 EXTRA_IMAGECMD_jffs2 = ""
 385 EXTRA_IMAGECMD_yaffs2 = "1"
 386 EXTRA_IMAGECMD_squashfs = ""
 387 EXTRA_IMAGECMD_squashfs-lzma = ""
 388 EXTRA_IMAGECMD_cpio = ""
 389 EXTRA_IMAGECMD_cpio.gz = ""
 390 EXTRA_IMAGECMD_cpio.lzma = ""
 391 EXTRA_IMAGECMD_ubi = ""
 392 EXTRA_IMAGECMD_ubifs = ""
 393
 394 IMAGE_DEPENDS = ""
 395 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 396 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 397 IMAGE_DEPENDS_cramfs = "cramfs-native"
 398 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 399 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 400 IMAGE_DEPENDS_ext2.bz2 = "genext2fs-native"
 401 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 402 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 403 IMAGE_DEPENDS_ext3.bz2 = "genext2fs-native e2fsprogs-native"
 404 IMAGE_DEPENDS_cpio.gz.u-boot = "u-boot-mkimage-native"
 405 IMAGE_DEPENDS_cpio.lzma = "lzma-native"
 406 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 407 IMAGE_DEPENDS_squashfs-lzma = "squashfs-tools-native"
 408 IMAGE_DEPENDS_ubi = "mtd-utils-native"
 409 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 410
 411 EXTRA_IMAGEDEPENDS = ""
 412
 413 ##################################################################
 414 # Toolchain info.
 415 ##################################################################
 416 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}/${base_bindir_native}:"
 417 export PATH
 418
 419 ##################################################################
 420 # Build utility info.
 421 ##################################################################
 422
 423 CCACHE ?= ""
 424 TOOLCHAIN_OPTIONS = ""
 425 TOOLCHAIN_PATH ?= "${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH}"
 426 TOOLCHAIN_SYSPATH ?= "${TOOLCHAIN_PATH}/${TARGET_SYS}"
 427
 428 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 429 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 430 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 431 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 432 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 433 export CCLD = "${CC}"
 434 export AR = "${HOST_PREFIX}ar"
 435 export AS = "${HOST_PREFIX}as"
 436 export RANLIB = "${HOST_PREFIX}ranlib"
 437 export STRIP = "${HOST_PREFIX}strip"
 438 export OBJCOPY = "${HOST_PREFIX}objcopy"
 439 export OBJDUMP = "${HOST_PREFIX}objdump"
 440 export NM = "${HOST_PREFIX}nm"
 441 PYTHON = "${@sys.executable}"
 442
 443 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 444 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 445 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 446 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 447 export BUILD_LD = "${BUILD_PREFIX}ld"
 448 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 449 export BUILD_AR = "${BUILD_PREFIX}ar"
 450 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 451 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 452
 453 export MAKE = "make"
 454 EXTRA_OEMAKE = "-e MAKEFLAGS="
 455
 456 ##################################################################
 457 # Patch handling.
 458 ##################################################################
 459 PATCHTOOL = 'quilt'
 460 PATCHRESOLVE = 'noop'
 461
 462 ##################################################################
 463 # Build flags and options.
 464 ##################################################################
 465
 466 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 467 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 468 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${includedir}"
 469 export SDK_CPPFLAGS = "-isystem${STAGING_DIR_SDK}${includedir} -isystem${STAGING_DIR_HOST}${includedir}"
 470
 471 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 472 export CFLAGS = "${TARGET_CFLAGS}"
 473 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 474 export SDK_CFLAGS = "${SDK_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 475
 476 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 477 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 478 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 479 export SDK_CXXFLAGS = "${SDK_CFLAGS} -fpermissive"
 480
 481 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 482                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 483                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 484
 485 export LDFLAGS = "${TARGET_LDFLAGS}"
 486 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${libdir} \
 487                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${libdir} \
 488                          -Wl,-O1 \
 489                          ${TARGET_LINK_HASH_STYLE}"
 490 export SDK_LDFLAGS = "-L${STAGING_DIR_SDK}${libdir} \
 491                          -Wl,-rpath-link,${STAGING_DIR_SDK}${libdir} \
 492                          -Wl,-O1"
 493
 494 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 495 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 496
 497 # Pass parallel make options to the compile task only
 498 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 499 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 500
 501 ##################################################################
 502 # Optimization flags.
 503 ##################################################################
 504
 505 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 506 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 507 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 508 BUILD_OPTIMIZATION = "-O2 -g"
 509
 510 ##################################################################
 511 # Bootstrap stuff.
 512 ##################################################################
 513
 514 BOOTSTRAP_EXTRA_RDEPENDS = ""
 515 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 516
 517 ##################################################################
 518 # Palmtop stuff.
 519 ##################################################################
 520
 521 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 522 export QPEDIR = "${STAGING_DIR_HOST}"
 523 export OPIEDIR = "${STAGING_DIR_HOST}"
 524 export palmtopdir = "${libdir}/opie"
 525 export palmqtdir = "${palmtopdir}"
 526
 527 ##################################################################
 528 # Download locations and utilities.
 529 ##################################################################
 530
 531 OE_STRICT_CHECKSUMS ?= "1"
 532
 533 ADOBE_MIRROR = "http://fpdownload.macromedia.com/get/flashplayer/current/"
 534 APACHE_MIRROR = "http://archive.apache.org/dist"
 535 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 536 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 537 E_URI = "http://enlightenment.freedesktop.org/files"
 538 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 539 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 540 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 541 GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
 542 GNOME_GIT = "git://git.gnome.org"
 543 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 544 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 545 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 546 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 547 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 548 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 549 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 550 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 551 KERNELORG_MIRROR = "http://kernel.org"
 552 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 553 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 554 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 555
 556 # You can use the mirror of your country to get faster downloads by putting
 557 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 558 #     into your local.conf
 559
 560 FETCHCMD_svn = "/usr/bin/env svn --non-interactive"
 561 FETCHCMD_cvs = "/usr/bin/env cvs"
 562 FETCHCMD_wget = "/usr/bin/env wget -t 5 --no-check-certificate"
 563 FETCHCMD_bzr = "/usr/bin/env bzr"
 564 FETCHCMD_hg = "/usr/bin/env hg"
 565
 566 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 567 FETCHCOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 568 FETCHCOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 569 FETCHCOMMAND_svn = "/usr/bin/env svn co --non-interactive ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 570 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 571 RESUMECOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -c -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 572 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 573 UPDATECOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 574 UPDATECOMMAND_svn = "/usr/bin/env svn update --non-interactive --force --accept theirs-full ${SVNCOOPTS}"
 575 SRCDATE = "${DATE}"
 576 SRCREV = "1"
 577 SRCPV = "${@bb.fetch.get_srcrev(d)}"
 578 AUTOREV = "${SRCPV}"
 579
 580 # For now disable autoincrement of revision counter in SRCPV, whoever wants it, should enable it in local.conf or distro config
 581 # Revision counter is incremented only locally (bad for multiple builders filling shared feeds), LOCALCOUNT can be used to maintain
 582 # counter globally in OE metadata (LOCALCOUNT value set in recipe).
 583 # Make sure you disable it, if you want always upgradable paths for git recipes without bumping LOCALCOUNT with every SRCREV change
 584 # or if you're using AUTOREV feature.
 585 BB_LOCALCOUNT_OVERRIDE = "1"
 586
 587 # Value for revision counter in GIT recipes (NNNN in PV="1.0+gitrNNNN+a7401084a72285c8d3485bacf4eed593f303b1b7-r4.4")
 588 LOCALCOUNT = "0"
 589
 590 SRC_URI = "file://${FILE}"
 591
 592 ##################################################################
 593 # UI/Interaction Configuration
 594 ##################################################################
 595
 596 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 597 export SHELLCMDS = "${SHELLRCCMD}"
 598 # Some common terminal programs to choose from
 599 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 600 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 601 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 602 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 603 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 604 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 605 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 606 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 607
 608 # Set a default
 609 TERMCMD ?= "${GNOME_TERMCMD}"
 610 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 611
 612 ##################################################################
 613 # Miscellaneous utilities.
 614 ##################################################################
 615
 616 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 617 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 618
 619 # GNU patch tries to be intellgent about checking out read-only files from
 620 # a RCS, which freaks out those special folks with active Perforce clients
 621 # the following makes patch ignore RCS:
 622
 623 export PATCH_GET="0"
 624
 625 # Program to be used to build ipkg packages
 626
 627 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 628
 629 ##################################################################
 630 # Not sure about the rest of this yet.
 631 ##################################################################
 632
 633 # slot - currently unused by OE. portage remnants
 634 SLOT = "0"
 635
 636 # Other
 637
 638 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${libdir}/pkgconfig"
 639 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 640 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 641 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 642
 643 export XDG_DATA_DIRS = "${STAGING_DATADIR}"
 644
 645 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 646 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 647 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 648
 649 # library package naming
 650 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 651
 652 # Globally toggle certain dependencies
 653 ENTERPRISE_DISTRO ?= "0"
 654
 655 # Pre-build configuration output
 656
 657 BUILDCFG_HEADER = "Build Configuration:"
 658 BUILDCFG_VARS ?= "BB_VERSION METADATA_BRANCH METADATA_REVISION TARGET_ARCH TARGET_OS MACHINE DISTRO DISTRO_VERSION"
 659 BUILDCFG_VARS_append_arm = " TARGET_FPU"
 660 BUILDCFG_VARS_append_armeb = " TARGET_FPU"
 661 BUILDCFG_NEEDEDVARS ?= "TARGET_ARCH TARGET_OS"
 662
 663 ###
 664 ### Config file processing
 665 ###
 666
 667 # Overrides are processed left to right, so the ones that are named later take precedence.
 668 # You generally want them to go from least to most specific.
 669 #
 670 # This means that an envionment variable named '<foo>_arm' overrides an
 671 # environment variable '<foo>' (when ${TARGET_ARCH} is arm).
 672 # an environment variable '<foo>_ramses' overrides '<foo>' but doesn't override
 673 # '<foo>_arm' when ${MACHINE} is 'ramses'.
 674 # If you use combination ie '<foo>_arm_ramses', then '<foo>_arm_ramses' will override
 675 # '<foo>_arm' and then '<foo>' will be overriden with that value from '<foo>_arm'.
 676 # And finally '<foo>_local' overrides anything, but with lowest priority.
 677 #
 678 # This works for  functions as well, they are really just environment variables.
 679 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 680 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 681 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 682 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 683
 684 ##################################################################
 685 # Include the rest of the config files.
 686 ##################################################################
 687
 688 include conf/site.conf
 689 include conf/auto.conf
 690 include conf/local.conf
 691 # USERDISTRO should always contain original DISTRO value as set by user
 692 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 693 # overrides like it wants), USERDISTRO must be reassigned with := first
 694 USERDISTRO = "${DISTRO}"
 695 include conf/build/${BUILD_SYS}.conf
 696 include conf/target/${TARGET_SYS}.conf
 697 include conf/machine/${MACHINE}.conf
 698 include conf/distro/${DISTRO}.conf
 699 include conf/documentation.conf
 700 require conf/sanity.conf
 701 require conf/abi_version.conf
 702 require conf/enterprise.conf
 703 require conf/compatibility-providers.conf
 704
 705 ##################################################################
 706 # Weak variables (usually to retain backwards compatibility)
 707 ##################################################################
 708
 709 DL_DIR ?= "${TMPDIR}/downloads"
 710 PSTAGE_DIR ?= "${TMPDIR}/pstage"
 711 IMAGE_FSTYPES ?= "tar.gz"
 712 PCMCIA_MANAGER ?= "pcmcia-cs"
 713 DEFAULT_TASK_PROVIDER ?= "task-base"
 714 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 715 IMAGE_ROOTFS_SIZE ?= "65536"
 716 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 717 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 718 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 719 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 720 DISTRO_PR ?= ""
 721
 722 # Forcefully set CACHE now so future changes to things like
 723 # MACHINE don't change the path to the cache
 724 CACHE := "${CACHE}"
 725
 726 # Default to disabling packaged staging code
 727 export PSTAGING_ACTIVE = "0"
 728
 729 ##################################################################
 730 # Magic Cookie for SANITY CHECK
 731 ##################################################################
 732 OES_BITBAKE_CONF = "1"
 733
 734 ##################################################################
 735 # Machine properties and task-base stuff
 736 ##################################################################
 737
 738 MACHINE_FEATURES ?= "kernel26"
 739 DISTRO_FEATURES ?= ""
 740 # Add thumb-interwork to feature list if selected machine supports it.
 741 DISTRO_FEATURES += ' ${@["", "thumb-interwork"][bb.data.getVar('THUMB_INTERWORK', d, 1) == "yes"]}'
 742
 743 # This is used to limit what packages goes into images built, so set big by default
 744 ROOT_FLASH_SIZE ?= "256"
 745
 746 MACHINE_GUI_CLASS ?= "smallscreen"
 747 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 748 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 749 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 750 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 751 MACHINE_DISPLAY_ORIENTATION ?= "0"
 752 MACHINE_DISPLAY_BPP ?= "16"
 753
 754 DISTRO_EXTRA_RDEPENDS ?= ""
 755 DISTRO_EXTRA_RRECOMMENDS ?= ""
 756 MACHINE_EXTRA_RDEPENDS ?= ""
 757 MACHINE_EXTRA_RRECOMMENDS ?= ""
 758 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 759 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 760
 761 COMBINED_FEATURES = "\
 762     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 763     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 764     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 765     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 766     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 767     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 768     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 769     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 770     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 771     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 772
 773 # We want madwifi if all of the following are true:
 774 # - distro has pci, wifi, and madwifi in its features
 775 # - machine has pci in its features
 776 COMBINED_FEATURES += "${@base_ifelse( \
 777     base_contains('DISTRO_FEATURES', ('pci', 'wifi', 'madwifi'), True, False, d) and \
 778     base_contains('MACHINE_FEATURES', 'pci', True, False, d), \
 779     'madwifi', '')}"
 780
 781 # We want hostap if all of the following are true:
 782 # - 'wifi' and 'hostap' are in distro features
 783 # - either 'pci' or 'pcmcia' are in both distro and machine features
 784 COMBINED_FEATURES += "${@base_ifelse( \
 785     base_contains('DISTRO_FEATURES', ('wifi', 'hostap'), True, False, d) and \
 786     ((base_contains('MACHINE_FEATURES', 'pci', True, False, d) and \
 787       base_contains('DISTRO_FEATURES', 'pci', True, False, d)) or \
 788      (base_contains('MACHINE_FEATURES', 'pcmcia', True, False, d) and \
 789       base_contains('DISTRO_FEATURES', 'pcmcia', True, False, d))), \
 790     'hostap', '')}"
 791
 792 # Make sure MACHINE isn't exported
 793 # (breaks binutils at least)
 794 MACHINE[unexport] = "1"
 795
 796 # Make sure TARGET_ARCH isn't exported
 797 # (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
 798 # in them, undocumented)
 799 TARGET_ARCH[unexport] = "1"
 800
 801 # Make sure DISTRO isn't exported
 802 # (breaks sysvinit at least)
 803 DISTRO[unexport] = "1"
 804
 805 # Make sure that LIBC isn't exported
 806 # (breaks perl at least)
 807 LIBC[unexport] = "1"