recipes/linux/linux.inc

   1 DESCRIPTION = "Linux Kernel"
   2 SECTION = "kernel"
   3 LICENSE = "GPLv2"
   4
   5 inherit kernel
   6
   7 RPSRC = "http://www.rpsys.net/openzaurus/patches/archive"
   8
   9 # Enable OABI compat for people stuck with obsolete userspace
  10 ARM_KEEP_OABI ?= "1"
  11
  12 # Quirk for udev greater or equal 141
  13 UDEV_GE_141 ?= "0"
  14
  15 # Specify the commandline for your device
  16
  17 # Boot from mmc
  18 CMDLINE_at91sam9263ek = "mem=64M console=ttyS0,115200 root=/dev/mmcblk0p1 rootfstype=ext2 rootdelay=5"
  19 # Boot from nfs
  20 #CMDLINE_at91sam9263ek = "mem=64M console=ttyS0,115200 root=301 root=/dev/nfs nfsroot=172.20.3.1:/data/at91 ip=172.20.0.5:::255.255.0.0"
  21
  22 # Set the verbosity of kernel messages during runtime
  23 # You can define CMDLINE_DEBUG in your local.conf or distro.conf to override this behaviour
  24 CMDLINE_DEBUG ?= '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug", d)}'
  25 CMDLINE_append = " ${CMDLINE_DEBUG} "
  26
  27 # Support for binary device tree generation
  28
  29 FILES_kernel-devicetree = "/boot/devicetree*"
  30
  31 KERNEL_DEVICETREE_boc01 = "${WORKDIR}/boc01.dts"
  32 KERNEL_DEVICETREE_calamari = "arch/${ARCH}/boot/dts/mpc8536ds.dts"
  33 KERNEL_DEVICETREE_canyonlands = "arch/${ARCH}/boot/dts/canyonlands.dts"
  34 KERNEL_DEVICETREE_kilauea = "arch/${ARCH}/boot/dts/kilauea.dts"
  35 KERNEL_DEVICETREE_lsppchd = "arch/${ARCH}/boot/dts/kuroboxHD.dts"
  36 KERNEL_DEVICETREE_lsppchg = "arch/${ARCH}/boot/dts/kuroboxHG.dts"
  37 KERNEL_DEVICETREE_mpc8313e-rdb = "arch/${ARCH}/boot/dts/mpc8313erdb.dts"
  38 KERNEL_DEVICETREE_mpc8315e-rdb = "arch/${ARCH}/boot/dts/mpc8315erdb.dts"
  39 KERNEL_DEVICETREE_mpc8323e-rdb = "arch/${ARCH}/boot/dts/mpc832x_rdb.dts"
  40 KERNEL_DEVICETREE_sequoia = "arch/${ARCH}/boot/dts/sequoia.dts"
  41 KERNEL_DEVICETREE_p2020ds = "arch/${ARCH}/boot/dts/p2020ds.dts"
  42
  43 KERNEL_DEVICETREE_FLAGS = "-R 8 -S 0x3000"
  44
  45 python __anonymous () {
  46
  47     import bb
  48
  49     devicetree = bb.data.getVar('KERNEL_DEVICETREE', d, 1) or ''
  50     if devicetree:
  51         depends = bb.data.getVar("DEPENDS", d, 1)
  52         bb.data.setVar("DEPENDS", "%s dtc-native" % depends, d)
  53         packages = bb.data.getVar("PACKAGES", d, 1)
  54         bb.data.setVar("PACKAGES", "%s kernel-devicetree" % packages, d)
  55 }
  56
  57 do_configure_prepend() {
  58         echo "" > ${S}/.config
  59
  60         #
  61         # logo support, if you supply logo_linux_clut224.ppm in SRC_URI, then it's going to be used
  62         #
  63         if [ -e ${WORKDIR}/logo_linux_clut224.ppm ]; then
  64                 install -m 0644 ${WORKDIR}/logo_linux_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm
  65                 echo "CONFIG_LOGO=y"                    >> ${S}/.config
  66                 echo "CONFIG_LOGO_LINUX_CLUT224=y"      >> ${S}/.config
  67         fi
  68
  69         #
  70         # oabi / eabi support
  71         #
  72         if [ "${TARGET_OS}" = "linux-gnueabi" -o  "${TARGET_OS}" = "linux-uclibceabi" ]; then
  73                 echo "CONFIG_AEABI=y"                   >> ${S}/.config
  74                 if [ "${ARM_KEEP_OABI}" = "1" ] ; then
  75                         echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
  76                 else
  77                         echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
  78                 fi
  79         else
  80                 echo "# CONFIG_AEABI is not set"        >> ${S}/.config
  81                 echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
  82         fi
  83
  84         # When enabling thumb for userspace we also need thumb support in the kernel
  85         if [ "${ARM_INSTRUCTION_SET}" = "thumb" ] ; then
  86             sed -i -e /CONFIG_ARM_THUMB/d ${WORKDIR}/defconfig
  87             echo "CONFIG_ARM_THUMB=y" >> ${S}/.config
  88         fi
  89
  90         #
  91         # endian support
  92         #
  93         if [ "${SITEINFO_ENDIANESS}" = "be" ]; then
  94                 echo "CONFIG_CPU_BIG_ENDIAN=y"          >> ${S}/.config
  95         fi
  96
  97         echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
  98
  99         sed -e '/CONFIG_AEABI/d' \
 100             -e '/CONFIG_OABI_COMPAT=/d' \
 101             -e '/CONFIG_CMDLINE=/d' \
 102             -e '/CONFIG_CPU_BIG_ENDIAN/d' \
 103             -e '/CONFIG_LOGO=/d' \
 104             -e '/CONFIG_LOGO_LINUX_CLUT224=/d' \
 105             -e '/CONFIG_LOCALVERSION/d' \
 106             -e '/CONFIG_LOCALVERSION_AUTO/d' \
 107             < '${WORKDIR}/defconfig' >>'${S}/.config'
 108
 109         echo 'CONFIG_LOCALVERSION=""' >>${S}/.config
 110         echo '# CONFIG_LOCALVERSION_AUTO is not set' >>${S}/.config
 111
 112         #
 113         # Udev quirks
 114         #
 115
 116         # Newer versions of udev mandate that sysfs doesn't have deprecated entries
 117         if [ "${UDEV_GE_141}" = "1" ] ; then
 118             sed -e /CONFIG_SYSFS_DEPRECATED/d \
 119                 -e /CONFIG_SYSFS_DEPRECATED_V2/d \
 120                 -e /CONFIG_HOTPLUG/d \
 121                 -e /CONFIG_UEVENT_HELPER_PATH/d \
 122                 -e /CONFIG_UNIX/d \
 123                 -e /CONFIG_SYSFS/d \
 124                 -e /CONFIG_PROC_FS/d \
 125                 -e /CONFIG_TMPFS/d \
 126                 -e /CONFIG_INOTIFY_USER/d \
 127                 -e /CONFIG_SIGNALFD/d \
 128                 -e /CONFIG_TMPFS_POSIX_ACL/d \
 129                 -e /CONFIG_BLK_DEV_BSG/d \
 130                 -i '${S}/.config'
 131
 132             echo '# CONFIG_SYSFS_DEPRECATED is not set' >> ${S}/.config
 133             echo '# CONFIG_SYSFS_DEPRECATED_V2 is not set' >> ${S}/.config
 134             echo 'CONFIG_HOTPLUG=y' >> ${S}/.config
 135             echo 'CONFIG_UEVENT_HELPER_PATH=""' >> ${S}/.config
 136             echo 'CONFIG_UNIX=y' >> ${S}/.config
 137             echo 'CONFIG_SYSFS=y' >> ${S}/.config
 138             echo 'CONFIG_PROC_FS=y' >> ${S}/.config
 139             echo 'CONFIG_TMPFS=y' >> ${S}/.config
 140             echo 'CONFIG_INOTIFY_USER=y' >> ${S}/.config
 141             echo 'CONFIG_SIGNALFD=y' >> ${S}/.config
 142             echo 'CONFIG_TMPFS_POSIX_ACL=y' >> ${S}/.config
 143             echo 'CONFIG_BLK_DEV_BSG=y' >> ${S}/.config
 144             echo 'CONFIG_DEVTMPFS=y' >> ${S}/.config
 145             echo 'CONFIG_DEVTMPFS_MOUNT=y' >> ${S}/.config
 146         fi
 147
 148         #
 149         # root-over-nfs-over-usb-eth support. Limited, but should cover some cases.
 150         # Enable this by setting a proper CMDLINE_NFSROOT_USB.
 151         #
 152         if [ ! -z "${CMDLINE_NFSROOT_USB}" ]; then
 153                 oenote "Configuring the kernel for root-over-nfs-over-usb-eth with CMDLINE ${CMDLINE_NFSROOT_USB}"
 154                 sed -e '/CONFIG_INET/d' \
 155                     -e '/CONFIG_IP_PNP=/d' \
 156                     -e '/CONFIG_USB_GADGET=/d' \
 157                     -e '/CONFIG_USB_GADGET_SELECTED=/d' \
 158                     -e '/CONFIG_USB_ETH=/d' \
 159                     -e '/CONFIG_NFS_FS=/d' \
 160                     -e '/CONFIG_ROOT_NFS=/d' \
 161                     -e '/CONFIG_CMDLINE=/d' \
 162                     -i ${S}/.config
 163                 echo "CONFIG_INET=y"                     >> ${S}/.config
 164                 echo "CONFIG_IP_PNP=y"                   >> ${S}/.config
 165                 echo "CONFIG_USB_GADGET=y"               >> ${S}/.config
 166                 echo "CONFIG_USB_GADGET_SELECTED=y"      >> ${S}/.config
 167                 echo "CONFIG_USB_ETH=y"                  >> ${S}/.config
 168                 echo "CONFIG_NFS_FS=y"                   >> ${S}/.config
 169                 echo "CONFIG_ROOT_NFS=y"                 >> ${S}/.config
 170                 echo "CONFIG_CMDLINE=\"${CMDLINE_NFSROOT_USB}\"" >> ${S}/.config
 171         fi
 172                 yes '' | oe_runmake oldconfig
 173 }
 174
 175 do_configure_append_avr32() {
 176         sed -i -e s:-mno-pic::g arch/avr32/Makefile
 177 }
 178
 179 do_configure_append() {
 180         if test -e scripts/Makefile.fwinst ; then
 181                 sed -i -e "s:-m0644:-m 0644:g" scripts/Makefile.fwinst
 182         fi
 183 }
 184
 185 do_devicetree_image() {
 186     if test -n "${KERNEL_DEVICETREE}" ; then
 187         dtc -I dts -O dtb ${KERNEL_DEVICETREE_FLAGS} -o devicetree ${KERNEL_DEVICETREE}
 188         install -m 0644 devicetree ${D}/boot/devicetree-${KERNEL_VERSION}
 189         install -d ${DEPLOY_DIR_IMAGE}
 190         install -m 0644 devicetree ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb
 191         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb
 192         cd ${DEPLOY_DIR_IMAGE}
 193         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 194         ln -sf ${KERNEL_IMAGE_BASE_NAME}.dtb ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 195         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 196     fi
 197 }
 198
 199 addtask devicetree_image after do_install before do_package do_deploy
 200
 201 pkg_postinst_kernel-devicetree () {
 202         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/devicetree devicetree devicetree-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 203 }
 204
 205 pkg_postrm_kernel-devicetree () {
 206         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove devicetree devicetree-${KERNEL_VERSION} || true
 207 }
 208