CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.4)
   4
   5 IF(COMMAND CMAKE_POLICY)
   6   CMAKE_POLICY(SET CMP0003 NEW)
   7 ENDIF(COMMAND CMAKE_POLICY)
   8
   9 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")
  10
  11 INCLUDE(CheckFunctionExists)
  12 INCLUDE(CheckLibraryExists)
  13 INCLUDE(CheckSharedLibraryExists)
  14 INCLUDE(CheckIncludeFile)
  15 INCLUDE(CheckIncludeFiles)
  16 INCLUDE(CheckSymbolExists)
  17 INCLUDE(CheckCCompilerFlag)
  18 INCLUDE(CheckCSourceCompiles)
  19 INCLUDE(CheckTypeSize)
  20
  21
  22 PROJECT(OpenAL C)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSA    "Check for ALSA backend"                ON)
  29 OPTION(OSS     "Check for OSS backend"                 ON)
  30 OPTION(SOLARIS "Check for Solaris backend"             ON)
  31 OPTION(DSOUND  "Check for DirectSound backend"         ON)
  32 OPTION(WINMM   "Check for Windows Multimedia backend"  ON)
  33 OPTION(PORTAUDIO  "Check for PortAudio backend"        ON)
  34 OPTION(PULSEAUDIO "Check for PulseAudio backend"       ON)
  35
  36 OPTION(DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  37
  38 OPTION(WERROR  "Treat compile warnings as errors"      OFF)
  39
  40 OPTION(EXAMPLES  "Build example programs"              ON)
  41
  42 OPTION(ALSOFT_CONFIG "Install alsoft.conf configuration file" OFF)
  43
  44
  45 IF(WIN32)
  46     SET(LIBNAME OpenAL32)
  47     ADD_DEFINITIONS("-D_WIN32")
  48 ELSE()
  49     SET(LIBNAME openal)
  50 ENDIF()
  51
  52 SET(LIB_MAJOR_VERSION "1")
  53 SET(LIB_MINOR_VERSION "11")
  54 SET(LIB_BUILD_VERSION "753")
  55 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_BUILD_VERSION}")
  56 IF(NOT DEFINED LIB_INSTALL_DIR)
  57   SET(LIB_INSTALL_DIR "lib${LIB_SUFFIX}")
  58 ENDIF(NOT DEFINED LIB_INSTALL_DIR)
  59
  60
  61 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  62 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  63 CHECK_TYPE_SIZE("unsigned int" SIZEOF_UINT)
  64 CHECK_TYPE_SIZE("void*" SIZEOF_VOIDP)
  65
  66
  67 # Add definitions, compiler switches, etc.
  68 INCLUDE_DIRECTORIES(OpenAL32/Include include "${OpenAL_BINARY_DIR}")
  69
  70 IF(NOT CMAKE_BUILD_TYPE)
  71     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  72         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  73         FORCE)
  74 ENDIF()
  75 IF(NOT CMAKE_DEBUG_POSTFIX)
  76     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  77         "Library postfix for debug builds. Normally left blank."
  78         FORCE)
  79 ENDIF()
  80
  81 IF(MSVC)
  82     # ???
  83     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
  84     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
  85     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
  86     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
  87     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
  88     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  89
  90     IF(NOT DXSDK_DIR)
  91         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
  92     ELSE()
  93         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
  94     ENDIF()
  95     IF(DXSDK_DIR)
  96         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
  97         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
  98         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
  99         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 100     ENDIF()
 101
 102 ELSE()
 103     ADD_DEFINITIONS(-Wall)
 104     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 105     IF(HAVE_W_EXTRA)
 106         ADD_DEFINITIONS(-Wextra)
 107     ENDIF()
 108
 109     IF(WERROR)
 110         ADD_DEFINITIONS(-Werror)
 111     ENDIF()
 112
 113     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -funroll-loops -D_DEBUG" CACHE STRING
 114         "Flags used by the compiler during Release with Debug Info builds."
 115         FORCE)
 116     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 117         "Flags used by the compiler during release minsize builds."
 118         FORCE)
 119     SET(CMAKE_C_FLAGS_RELEASE "-O2 -funroll-loops -fomit-frame-pointer -DNDEBUG" CACHE STRING
 120         "Flags used by the compiler during release builds"
 121         FORCE)
 122     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 123         "Flags used by the compiler during debug builds."
 124         FORCE)
 125
 126     # Set visibility options if available
 127     IF(NOT WIN32)
 128         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 129                                  int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 130
 131         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_SWITCH)
 132         IF(HAVE_VISIBILITY_SWITCH)
 133             CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 134                                      int main() {return 0;}" HAVE_GCC_VISIBILITY)
 135             IF(HAVE_GCC_VISIBILITY)
 136                 ADD_DEFINITIONS(-fvisibility=hidden -DHAVE_GCC_VISIBILITY)
 137             ENDIF()
 138         ENDIF()
 139     ENDIF()
 140 ENDIF()
 141
 142 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 143                          int main() {return 0;}" HAVE_GCC_FORMAT)
 144
 145 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 146 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 147
 148 CHECK_LIBRARY_EXISTS(m  powf   "" HAVE_POWF)
 149 CHECK_LIBRARY_EXISTS(m  sqrtf  "" HAVE_SQRTF)
 150 CHECK_LIBRARY_EXISTS(m  acosf  "" HAVE_ACOSF)
 151 CHECK_LIBRARY_EXISTS(m  atanf  "" HAVE_ATANF)
 152 CHECK_LIBRARY_EXISTS(m  fabsf  "" HAVE_FABSF)
 153 IF(HAVE_FENV_H)
 154     CHECK_LIBRARY_EXISTS(m  fesetround  "" HAVE_FESETROUND)
 155 ENDIF()
 156 IF(HAVE_SQRTF OR HAVE_ACOSF OR HAVE_ATANF OR HAVE_FABSF OR HAVE_FESETROUND)
 157     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 158 ENDIF()
 159 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 160 CHECK_FUNCTION_EXISTS(_controlfp HAVE__CONTROLFP)
 161
 162 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 163 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 164 IF(NOT HAVE_STRCASECMP)
 165     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 166     IF(NOT HAVE__STRICMP)
 167         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 168     ENDIF()
 169
 170     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 171 ENDIF()
 172
 173 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 174 IF(NOT HAVE_STRNCASECMP)
 175     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 176     IF(NOT HAVE__STRNICMP)
 177         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 178     ENDIF()
 179
 180     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 181 ENDIF()
 182
 183 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 184 IF(NOT HAVE_SNPRINTF)
 185     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 186     IF(NOT HAVE__SNPRINTF)
 187         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 188     ENDIF()
 189
 190     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 191 ENDIF()
 192
 193 CHECK_FUNCTION_EXISTS(vsnprintf HAVE_VSNPRINTF)
 194 IF(NOT HAVE_VSNPRINTF)
 195     CHECK_FUNCTION_EXISTS(_vsnprintf HAVE__VSNPRINTF)
 196     IF(NOT HAVE__VSNPRINTF)
 197         MESSAGE(FATAL_ERROR "No vsnprintf function found, please report!")
 198     ENDIF()
 199
 200     ADD_DEFINITIONS(-Dvsnprintf=_vsnprintf)
 201 ENDIF()
 202
 203 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 204 IF(NOT HAVE_ISNAN)
 205     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 206     IF(NOT HAVE__ISNAN)
 207         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 208     ENDIF()
 209
 210     ADD_DEFINITIONS(-Disnan=_isnan)
 211 ENDIF()
 212
 213
 214 # Check for the dlopen API (for dynamicly loading backend libs)
 215 IF(DLOPEN)
 216     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 217     IF(HAVE_DLFCN_H)
 218         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 219         IF(HAVE_LIBDL)
 220             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 221         ENDIF()
 222     ENDIF()
 223 ENDIF()
 224
 225 # Check if we have Windows headers
 226 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0500)
 227 IF(NOT HAVE_WINDOWS_H)
 228     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 229     IF(NOT HAVE_GETTIMEOFDAY)
 230         MESSAGE(FATAL_ERROR "No timing function found!")
 231     ENDIF()
 232
 233     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 234     IF(NOT HAVE_NANOSLEEP)
 235         MESSAGE(FATAL_ERROR "No sleep function found!")
 236     ENDIF()
 237
 238     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 239     IF(HAVE_PTHREAD)
 240         ADD_DEFINITIONS(-pthread)
 241         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 242     ENDIF()
 243
 244     # We need pthreads outside of Windows
 245     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 246     IF(NOT HAVE_PTHREAD_H)
 247         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 248     ENDIF()
 249     # Some systems need pthread_np.h to get recursive mutexes
 250     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 251
 252     # _GNU_SOURCE is needed on some systems for extra attributes, and
 253     # _REENTRANT is needed for libc thread-safety
 254     ADD_DEFINITIONS(-D_GNU_SOURCE=1)
 255     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 256     IF(HAVE_LIBPTHREAD)
 257         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 258     ENDIF()
 259
 260     CHECK_LIBRARY_EXISTS(pthread pthread_setschedparam "" HAVE_PTHREAD_SETSCHEDPARAM)
 261
 262     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 263     IF(HAVE_LIBRT)
 264         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 265     ENDIF()
 266 ENDIF()
 267
 268 # Check for a 64-bit type
 269 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 270 IF(NOT HAVE_STDINT_H)
 271     IF(HAVE_WINDOWS_H)
 272         CHECK_C_SOURCE_COMPILES("\#define _WIN32_WINNT 0x0500
 273                                  \#include <windows.h>
 274                                  __int64 foo;
 275                                  int main() {return 0;}" HAVE___INT64)
 276     ENDIF()
 277     IF(NOT HAVE___INT64)
 278         IF(NOT SIZEOF_LONG MATCHES "8")
 279             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 280                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 281             ENDIF()
 282         ENDIF()
 283     ENDIF()
 284 ENDIF()
 285
 286
 287 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 288                  OpenAL32/alBuffer.c
 289                  OpenAL32/alDatabuffer.c
 290                  OpenAL32/alEffect.c
 291                  OpenAL32/alError.c
 292                  OpenAL32/alExtension.c
 293                  OpenAL32/alFilter.c
 294                  OpenAL32/alListener.c
 295                  OpenAL32/alSource.c
 296                  OpenAL32/alState.c
 297                  OpenAL32/alThunk.c
 298 )
 299 SET(ALC_OBJS  Alc/ALc.c
 300               Alc/ALu.c
 301               Alc/alcConfig.c
 302               Alc/alcEcho.c
 303               Alc/alcReverb.c
 304               Alc/alcRing.c
 305               Alc/alcThread.c
 306               Alc/bs2b.c
 307               Alc/wave.c
 308 )
 309
 310 SET(BACKENDS "")
 311
 312 # Check ALSA backend
 313 IF(ALSA)
 314     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 315     IF(HAVE_ALSA_ASOUNDLIB_H)
 316         CHECK_SHARED_LIBRARY_EXISTS(asound snd_pcm_open 4 "" HAVE_LIBASOUND)
 317         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 318             SET(HAVE_ALSA 1)
 319             SET(ALC_OBJS  ${ALC_OBJS} Alc/alsa.c)
 320             IF(HAVE_DLFCN_H OR WIN32)
 321                 SET(BACKENDS  "${BACKENDS} ALSA,")
 322             ELSE()
 323                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 324                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 325             ENDIF()
 326         ENDIF()
 327     ENDIF()
 328 ENDIF()
 329
 330 # Check OSS backend
 331 IF(OSS)
 332     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 333     IF(HAVE_SYS_SOUNDCARD_H)
 334         SET(HAVE_OSS 1)
 335         SET(ALC_OBJS  ${ALC_OBJS} Alc/oss.c)
 336         SET(BACKENDS  "${BACKENDS} OSS,")
 337     ENDIF()
 338 ENDIF()
 339
 340 # Check Solaris backend
 341 IF(SOLARIS)
 342     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 343     IF(HAVE_SYS_AUDIOIO_H)
 344         SET(HAVE_SOLARIS 1)
 345         SET(ALC_OBJS  ${ALC_OBJS} Alc/solaris.c)
 346         SET(BACKENDS  "${BACKENDS} Solaris,")
 347     ENDIF()
 348 ENDIF()
 349
 350 # Check DSound/MMSystem backend
 351 IF(DSOUND)
 352     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 353     IF(HAVE_DSOUND_H)
 354         CHECK_SHARED_LIBRARY_EXISTS(dsound DirectSoundCreate 3 "" HAVE_LIBDSOUND)
 355         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 356             SET(HAVE_DSOUND 1)
 357             SET(ALC_OBJS  ${ALC_OBJS} Alc/dsound.c)
 358
 359             IF(HAVE_DLFCN_H OR WIN32)
 360                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 361             ELSE()
 362                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 363                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 364             ENDIF()
 365         ENDIF()
 366     ENDIF()
 367 ENDIF()
 368 IF(HAVE_WINDOWS_H)
 369     IF(WINMM)
 370         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0500)
 371         IF(HAVE_MMSYSTEM_H)
 372             CHECK_SHARED_LIBRARY_EXISTS(winmm waveInOpen 6 "" HAVE_LIBWINMM)
 373             IF(HAVE_LIBWINMM)
 374                 SET(HAVE_WINMM 1)
 375                 SET(ALC_OBJS  ${ALC_OBJS} Alc/winmm.c)
 376                 SET(BACKENDS  "${BACKENDS} WinMM,")
 377
 378                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 379             ENDIF()
 380         ENDIF()
 381     ENDIF()
 382 ENDIF()
 383
 384 # Check PortAudio backend
 385 IF(PORTAUDIO)
 386     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 387     IF(HAVE_PORTAUDIO_H)
 388         CHECK_SHARED_LIBRARY_EXISTS(portaudio Pa_Initialize 0 "" HAVE_LIBPORTAUDIO)
 389         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 390             SET(HAVE_PORTAUDIO 1)
 391             SET(ALC_OBJS  ${ALC_OBJS} Alc/portaudio.c)
 392             IF(HAVE_DLFCN_H OR WIN32)
 393                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 394             ELSE()
 395                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 396                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 397             ENDIF()
 398         ENDIF()
 399     ENDIF()
 400 ENDIF()
 401
 402 # Check PortAudio backend
 403 IF(PULSEAUDIO)
 404     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 405     IF(HAVE_PULSE_PULSEAUDIO_H)
 406         CHECK_SHARED_LIBRARY_EXISTS(pulse pa_context_new 2 "" HAVE_LIBPULSE)
 407         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 408             SET(HAVE_PULSEAUDIO 1)
 409             SET(ALC_OBJS  ${ALC_OBJS} Alc/pulseaudio.c)
 410             IF(HAVE_DLFCN_H OR WIN32)
 411                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 412             ELSE()
 413                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 414                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 415             ENDIF()
 416         ENDIF()
 417     ENDIF()
 418 ENDIF()
 419
 420 # This is always available
 421 SET(BACKENDS  "${BACKENDS} WaveFile")
 422
 423 # Needed for openal.pc.in
 424 SET(prefix ${CMAKE_INSTALL_PREFIX})
 425 SET(exec_prefix "\${prefix}")
 426 SET(libdir "\${exec_prefix}/${LIB_INSTALL_DIR}")
 427 SET(bindir "\${exec_prefix}/bin")
 428 SET(includedir "\${prefix}/include")
 429 SET(PACKAGE_VERSION "${LIB_VERSION}")
 430
 431 # End configuration
 432 CONFIGURE_FILE(
 433     "${OpenAL_SOURCE_DIR}/config.h.in"
 434     "${OpenAL_BINARY_DIR}/config.h")
 435 CONFIGURE_FILE(
 436     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 437     "${OpenAL_BINARY_DIR}/openal.pc"
 438     @ONLY)
 439
 440 # Build a library
 441 IF(NOT LIBTYPE)
 442     SET(LIBTYPE SHARED)
 443 ENDIF()
 444 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 445 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES DEFINE_SYMBOL AL_BUILD_LIBRARY
 446                                             COMPILE_FLAGS -DAL_ALEXT_PROTOTYPES
 447                                             VERSION ${LIB_VERSION}
 448                                             SOVERSION ${LIB_MAJOR_VERSION})
 449 IF(WIN32)
 450     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 451 ENDIF()
 452
 453 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 454
 455 # Add an install target here
 456 INSTALL(TARGETS ${LIBNAME}
 457         RUNTIME DESTINATION bin
 458         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 459         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 460 )
 461 INSTALL(FILES include/AL/al.h
 462               include/AL/alc.h
 463               include/AL/alext.h
 464               include/AL/efx.h
 465         DESTINATION include/AL
 466 )
 467 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 468         DESTINATION "${LIB_INSTALL_DIR}/pkgconfig")
 469
 470 # Install alsoft.conf configuration file
 471 IF(ALSOFT_CONFIG)
 472     INSTALL(FILES alsoftrc.sample
 473             DESTINATION /etc/openal
 474             RENAME alsoft.conf
 475     )
 476 ENDIF()
 477
 478 IF(EXAMPLES)
 479     ADD_EXECUTABLE(openal-info examples/openal-info.c)
 480     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 481     INSTALL(TARGETS openal-info
 482             RUNTIME DESTINATION bin
 483             LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 484             ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 485     )
 486 ENDIF()
 487
 488 MESSAGE(STATUS "")
 489 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 490 MESSAGE(STATUS "    ${BACKENDS}")
 491 MESSAGE(STATUS "")
 492
 493 IF(WIN32)
 494     IF(NOT HAVE_DSOUND)
 495         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 496         MESSAGE(STATUS "         This is probably NOT what you want!")
 497         MESSAGE(STATUS "")
 498     ENDIF()
 499 ENDIF()