CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 IF(WIN32)
  66     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  67
  68     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  69
  70     # This option is mainly for static linking OpenAL Soft into another project
  71     # that already defines the IDs. It is up to that project to ensure all
  72     # required IDs are defined.
  73     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  74
  75     IF(MINGW)
  76         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  77         IF(NOT DLLTOOL)
  78             IF(HOST)
  79                 SET(DLLTOOL "${HOST}-dlltool")
  80             ELSE()
  81                 SET(DLLTOOL "dlltool")
  82             ENDIF()
  83         ENDIF()
  84     ENDIF()
  85 ENDIF()
  86
  87
  88 SET(EXTRA_LIBS "")
  89 SET(EXTRA_LDFLAGS "")
  90
  91 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  92 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  93     ADD_DEFINITIONS("-I/usr/include")
  94     SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -L/usr/lib")
  95 ENDIF()
  96
  97 IF(NOT LIBTYPE)
  98     SET(LIBTYPE SHARED)
  99 ENDIF()
 100
 101 SET(LIB_MAJOR_VERSION "1")
 102 SET(LIB_MINOR_VERSION "18")
 103 SET(LIB_REVISION "0")
 104 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 105
 106 SET(EXPORT_DECL "")
 107 SET(ALIGN_DECL "")
 108
 109
 110 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 111 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 112
 113
 114 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 115 IF(HAVE_STD_C11)
 116     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 117 ELSE()
 118     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 119     IF(HAVE_STD_C99)
 120         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 121     ENDIF()
 122 ENDIF()
 123
 124 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 125 IF(HAVE_STD_CXX11)
 126     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 127 ENDIF()
 128
 129 if(NOT WIN32)
 130     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 131     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 132     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 133         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 134         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 135         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 136         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 137             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 138         ELSE()
 139             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600)
 140         ENDIF()
 141     ENDIF()
 142     UNSET(OLD_REQUIRED_FLAGS)
 143 ENDIF()
 144
 145 # Set defines for large file support
 146 CHECK_FILE_OFFSET_BITS()
 147 IF(_FILE_OFFSET_BITS)
 148     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 149     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 150 ENDIF()
 151 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 152 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 153
 154 # MSVC may need workarounds for C99 restrict and inline
 155 IF(MSVC)
 156     # TODO: Once we truly require C99, these restrict and inline checks should go
 157     # away.
 158     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 159                              int main() {return 0;}" HAVE_RESTRICT)
 160     IF(NOT HAVE_RESTRICT)
 161         ADD_DEFINITIONS("-Drestrict=")
 162         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 163     ENDIF()
 164
 165     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 166                              int main() {return 0;}" HAVE_INLINE)
 167     IF(NOT HAVE_INLINE)
 168         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 169                                  int main() {return 0;}" HAVE___INLINE)
 170         IF(NOT HAVE___INLINE)
 171             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 172         ENDIF()
 173
 174         ADD_DEFINITIONS(-Dinline=__inline)
 175         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 176     ENDIF()
 177 ENDIF()
 178
 179 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 180 IF(CMAKE_COMPILER_IS_GNUCC)
 181     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 182
 183     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 184     # Force no inlining for the next test.
 185     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 186
 187     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 188                              int main() {return foo();}" INLINE_IS_C99)
 189     IF(NOT INLINE_IS_C99)
 190         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 191                              Please update your compiler for better C99 compliance.")
 192     ENDIF()
 193
 194     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 195 ENDIF()
 196
 197 # Check if we have a proper timespec declaration
 198 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 199 IF(HAVE_STRUCT_TIMESPEC)
 200     # Define it here so we don't have to include config.h for it
 201     ADD_DEFINITIONS("-DHAVE_STRUCT_TIMESPEC")
 202 ENDIF()
 203
 204 # Some systems may need libatomic for C11 atomic functions to work
 205 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 206 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 207 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 208 int _Atomic foo = ATOMIC_VAR_INIT(0);
 209 int main()
 210 {
 211     return atomic_fetch_add(&foo, 2);
 212 }"
 213 HAVE_LIBATOMIC)
 214 IF(NOT HAVE_LIBATOMIC)
 215     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 216 ELSE()
 217     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 218 ENDIF()
 219 UNSET(OLD_REQUIRED_LIBRARIES)
 220
 221 # Include liblog for Android logging
 222 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 223 IF(HAVE_LIBLOG)
 224     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 225     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 226 ENDIF()
 227
 228 # Check if we have C99 variable length arrays
 229 CHECK_C_SOURCE_COMPILES(
 230 "int main(int argc, char *argv[])
 231  {
 232      volatile int tmp[argc];
 233      tmp[0] = argv[0][0];
 234      return tmp[0];
 235  }"
 236 HAVE_C99_VLA)
 237
 238 # Check if we have C99 bool
 239 CHECK_C_SOURCE_COMPILES(
 240 "int main(int argc, char *argv[])
 241  {
 242      volatile _Bool ret;
 243      ret = (argc > 1) ? 1 : 0;
 244      return ret ? -1 : 0;
 245  }"
 246 HAVE_C99_BOOL)
 247
 248 # Check if we have C11 static_assert
 249 CHECK_C_SOURCE_COMPILES(
 250 "int main()
 251  {
 252      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 253      return 0;
 254  }"
 255 HAVE_C11_STATIC_ASSERT)
 256
 257 # Check if we have C11 alignas
 258 CHECK_C_SOURCE_COMPILES(
 259 "_Alignas(16) int foo;
 260  int main()
 261  {
 262      return 0;
 263  }"
 264 HAVE_C11_ALIGNAS)
 265
 266 # Check if we have C11 _Atomic
 267 CHECK_C_SOURCE_COMPILES(
 268 "#include <stdatomic.h>
 269  int _Atomic foo = ATOMIC_VAR_INIT(0);
 270  int main()
 271  {
 272      atomic_fetch_add(&foo, 2);
 273      return 0;
 274  }"
 275 HAVE_C11_ATOMIC)
 276
 277 # Add definitions, compiler switches, etc.
 278 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 279
 280 IF(NOT CMAKE_BUILD_TYPE)
 281     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 282         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 283         FORCE)
 284 ENDIF()
 285 IF(NOT CMAKE_DEBUG_POSTFIX)
 286     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 287         "Library postfix for debug builds. Normally left blank."
 288         FORCE)
 289 ENDIF()
 290
 291 SET(EXTRA_CFLAGS "")
 292 IF(MSVC)
 293     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 294     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 295     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} /wd4098")
 296
 297     IF(NOT DXSDK_DIR)
 298         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 299     ELSE()
 300         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 301     ENDIF()
 302     IF(DXSDK_DIR)
 303         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 304     ENDIF()
 305
 306     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 307     IF(FORCE_STATIC_VCRT)
 308         FOREACH(flag_var
 309                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 310                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 311             IF(${flag_var} MATCHES "/MD")
 312                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 313             ENDIF()
 314         ENDFOREACH(flag_var)
 315     ENDIF()
 316 ELSE()
 317     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Winline -Wall")
 318     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 319     IF(HAVE_W_EXTRA)
 320         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wextra")
 321     ENDIF()
 322
 323     IF(ALSOFT_WERROR)
 324         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
 325     ENDIF()
 326
 327     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 328     # instead of NDEBUG)
 329     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 330         IF(${flag_var} MATCHES "-DNDEBUG")
 331             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 332         ENDIF()
 333     ENDFOREACH()
 334
 335     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 336     IF(HAVE_FNO_MATH_ERRNO)
 337         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fno-math-errno")
 338     ENDIF()
 339
 340     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 341                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 342
 343     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 344     if(ALSOFT_STATIC_LIBGCC)
 345         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 346         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 347         check_c_source_compiles(
 348 "#include <stdlib.h>
 349 int main()
 350 {
 351     return 0;
 352 }"
 353             HAVE_STATIC_LIBGCC_SWITCH
 354         )
 355         if(HAVE_STATIC_LIBGCC_SWITCH)
 356             set(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -static-libgcc")
 357         endif()
 358         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 359         unset(OLD_REQUIRED_LIBRARIES)
 360     endif()
 361 ENDIF()
 362
 363 # Set visibility/export options if available
 364 IF(WIN32)
 365     SET(EXPORT_DECL "__declspec(dllexport)")
 366     IF(NOT MINGW)
 367         SET(ALIGN_DECL "__declspec(align(x))")
 368     ELSE()
 369         SET(ALIGN_DECL "__declspec(aligned(x))")
 370     ENDIF()
 371 ELSE()
 372     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 373     # Yes GCC, really don't accept visibility modes you don't support
 374     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 375
 376     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 377                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 378     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 379         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 380     ELSE()
 381         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 382                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 383         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 384             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 385         ENDIF()
 386     ENDIF()
 387
 388     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 389         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 390         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 391             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
 392         ENDIF()
 393     ENDIF()
 394
 395     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 396                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 397     IF(HAVE_ATTRIBUTE_ALIGNED)
 398         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 399     ENDIF()
 400
 401     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 402 ENDIF()
 403
 404 CHECK_C_SOURCE_COMPILES("
 405 int main()
 406 {
 407     float *ptr;
 408     ptr = __builtin_assume_aligned(ptr, 16);
 409     return 0;
 410 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 411 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 412     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 413 ELSE()
 414     SET(ASSUME_ALIGNED_DECL "x")
 415 ENDIF()
 416
 417 SET(SSE_SWITCH "")
 418 SET(SSE2_SWITCH "")
 419 SET(SSE3_SWITCH "")
 420 SET(SSE4_1_SWITCH "")
 421 SET(FPU_NEON_SWITCH "")
 422 IF(NOT MSVC)
 423     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 424     IF(HAVE_MSSE_SWITCH)
 425         SET(SSE_SWITCH "-msse")
 426     ENDIF()
 427     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 428     IF(HAVE_MSSE2_SWITCH)
 429         SET(SSE2_SWITCH "-msse2")
 430     ENDIF()
 431     CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 432     IF(HAVE_MSSE3_SWITCH)
 433         SET(SSE3_SWITCH "-msse3")
 434     ENDIF()
 435     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 436     IF(HAVE_MSSE4_1_SWITCH)
 437         SET(SSE4_1_SWITCH "-msse4.1")
 438     ENDIF()
 439     CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 440     IF(HAVE_MFPU_NEON_SWITCH)
 441         SET(FPU_NEON_SWITCH "-mfpu=neon")
 442     ENDIF()
 443 ENDIF()
 444
 445 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 446                          int main() {return 0;}" HAVE_GCC_FORMAT)
 447
 448 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 449 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 450 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 451 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 452 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 453 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 454 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 455 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 456 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 457 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 458 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 459 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 460 IF(NOT HAVE_GUIDDEF_H)
 461     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 462 ENDIF()
 463
 464 # Some systems need libm for some of the following math functions to work
 465 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 466 IF(HAVE_LIBM)
 467     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 468     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 469 ENDIF()
 470
 471 # Check for the dlopen API (for dynamicly loading backend libs)
 472 IF(ALSOFT_DLOPEN)
 473     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 474     IF(HAVE_LIBDL)
 475         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 476         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 477     ENDIF()
 478
 479     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 480 ENDIF()
 481
 482 # Check for a cpuid intrinsic
 483 IF(HAVE_CPUID_H)
 484     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 485         int main()
 486         {
 487             unsigned int eax, ebx, ecx, edx;
 488             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 489         }" HAVE_GCC_GET_CPUID)
 490 ENDIF()
 491 IF(HAVE_INTRIN_H)
 492     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 493         int main()
 494         {
 495             int regs[4];
 496             __cpuid(regs, 0);
 497             return regs[0];
 498         }" HAVE_CPUID_INTRINSIC)
 499 ENDIF()
 500
 501 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 502 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 503 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 504 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 505 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 506 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 507 IF(NOT HAVE_C99_VLA)
 508     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 509     IF(NOT HAVE_ALLOCA)
 510         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 511     ENDIF()
 512 ENDIF()
 513
 514 IF(HAVE_FLOAT_H)
 515     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 516     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 517 ENDIF()
 518
 519 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 520 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 521 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 522 IF(NOT HAVE_STRCASECMP)
 523     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 524     IF(NOT HAVE__STRICMP)
 525         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 526     ENDIF()
 527
 528     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 529 ENDIF()
 530
 531 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 532 IF(NOT HAVE_STRNCASECMP)
 533     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 534     IF(NOT HAVE__STRNICMP)
 535         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 536     ENDIF()
 537
 538     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 539 ENDIF()
 540
 541 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 542 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 543 IF(NOT HAVE_SNPRINTF)
 544     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 545     IF(NOT HAVE__SNPRINTF)
 546         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 547     ENDIF()
 548
 549     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 550 ENDIF()
 551
 552 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 553 IF(NOT HAVE_ISFINITE)
 554     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 555     IF(NOT HAVE_FINITE)
 556         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 557         IF(NOT HAVE__FINITE)
 558             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 559         ENDIF()
 560         ADD_DEFINITIONS(-Disfinite=_finite)
 561     ELSE()
 562         ADD_DEFINITIONS(-Disfinite=finite)
 563     ENDIF()
 564 ENDIF()
 565
 566 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 567 IF(NOT HAVE_ISNAN)
 568     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 569     IF(NOT HAVE__ISNAN)
 570         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 571     ENDIF()
 572
 573     ADD_DEFINITIONS(-Disnan=_isnan)
 574 ENDIF()
 575
 576
 577 # Check if we have Windows headers
 578 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 579 IF(NOT HAVE_WINDOWS_H)
 580     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 581     IF(NOT HAVE_GETTIMEOFDAY)
 582         MESSAGE(FATAL_ERROR "No timing function found!")
 583     ENDIF()
 584
 585     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 586     IF(NOT HAVE_NANOSLEEP)
 587         MESSAGE(FATAL_ERROR "No sleep function found!")
 588     ENDIF()
 589
 590     # We need pthreads outside of Windows
 591     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 592     IF(NOT HAVE_PTHREAD_H)
 593         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 594     ENDIF()
 595     # Some systems need pthread_np.h to get recursive mutexes
 596     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 597
 598     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 599     IF(HAVE_PTHREAD)
 600         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -pthread")
 601         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 602         SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -pthread")
 603     ENDIF()
 604
 605     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 606     IF(HAVE_LIBPTHREAD)
 607         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 608     ENDIF()
 609
 610     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 611
 612     IF(HAVE_PTHREAD_NP_H)
 613         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 614         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 615             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 616         ELSE()
 617             CHECK_C_SOURCE_COMPILES("
 618 #include <pthread.h>
 619 #include <pthread_np.h>
 620 int main()
 621 {
 622     pthread_setname_np(\"testname\");
 623     return 0;
 624 }"
 625                 PTHREAD_SETNAME_NP_ONE_PARAM
 626             )
 627         ENDIF()
 628         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 629     ELSE()
 630         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 631         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 632             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 633         ELSE()
 634             CHECK_C_SOURCE_COMPILES("
 635 #include <pthread.h>
 636 int main()
 637 {
 638     pthread_setname_np(\"testname\");
 639     return 0;
 640 }"
 641                 PTHREAD_SETNAME_NP_ONE_PARAM
 642             )
 643         ENDIF()
 644         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 645     ENDIF()
 646
 647     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 648
 649     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 650     IF(HAVE_LIBRT)
 651         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 652     ENDIF()
 653 ENDIF()
 654
 655 # Check for a 64-bit type
 656 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 657 IF(NOT HAVE_STDINT_H)
 658     IF(HAVE_WINDOWS_H)
 659         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 660                                  #include <windows.h>
 661                                  __int64 foo;
 662                                  int main() {return 0;}" HAVE___INT64)
 663     ENDIF()
 664     IF(NOT HAVE___INT64)
 665         IF(NOT SIZEOF_LONG MATCHES "8")
 666             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 667                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 668             ENDIF()
 669         ENDIF()
 670     ENDIF()
 671 ENDIF()
 672
 673
 674 SET(COMMON_OBJS  common/almalloc.c
 675                  common/atomic.c
 676                  common/rwlock.c
 677                  common/threads.c
 678                  common/uintmap.c
 679 )
 680 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 681                  OpenAL32/alBuffer.c
 682                  OpenAL32/alEffect.c
 683                  OpenAL32/alError.c
 684                  OpenAL32/alExtension.c
 685                  OpenAL32/alFilter.c
 686                  OpenAL32/alListener.c
 687                  OpenAL32/alSource.c
 688                  OpenAL32/alState.c
 689                  OpenAL32/alThunk.c
 690                  OpenAL32/sample_cvt.c
 691 )
 692 SET(ALC_OBJS  Alc/ALc.c
 693               Alc/ALu.c
 694               Alc/alcConfig.c
 695               Alc/alcRing.c
 696               Alc/bs2b.c
 697               Alc/converter.c
 698               Alc/mastering.c
 699               Alc/effects/chorus.c
 700               Alc/effects/compressor.c
 701               Alc/effects/dedicated.c
 702               Alc/effects/distortion.c
 703               Alc/effects/echo.c
 704               Alc/effects/equalizer.c
 705               Alc/effects/flanger.c
 706               Alc/effects/modulator.c
 707               Alc/effects/null.c
 708               Alc/effects/reverb.c
 709               Alc/helpers.c
 710               Alc/bsinc.c
 711               Alc/hrtf.c
 712               Alc/uhjfilter.c
 713               Alc/ambdec.c
 714               Alc/bformatdec.c
 715               Alc/nfcfilter.c
 716               Alc/panning.c
 717               Alc/mixer.c
 718               Alc/mixer_c.c
 719 )
 720
 721
 722 SET(CPU_EXTS "Default")
 723 SET(HAVE_SSE        0)
 724 SET(HAVE_SSE2       0)
 725 SET(HAVE_SSE3       0)
 726 SET(HAVE_SSE4_1     0)
 727 SET(HAVE_NEON       0)
 728
 729 SET(HAVE_ALSA       0)
 730 SET(HAVE_OSS        0)
 731 SET(HAVE_SOLARIS    0)
 732 SET(HAVE_SNDIO      0)
 733 SET(HAVE_QSA        0)
 734 SET(HAVE_DSOUND     0)
 735 SET(HAVE_MMDEVAPI   0)
 736 SET(HAVE_WINMM      0)
 737 SET(HAVE_PORTAUDIO  0)
 738 SET(HAVE_PULSEAUDIO 0)
 739 SET(HAVE_COREAUDIO  0)
 740 SET(HAVE_OPENSL     0)
 741 SET(HAVE_WAVE       0)
 742
 743 # Check for SSE support
 744 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 745 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 746 IF(HAVE_XMMINTRIN_H)
 747     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 748     IF(ALSOFT_CPUEXT_SSE)
 749         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 750             SET(HAVE_SSE 1)
 751             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 752             IF(SSE_SWITCH)
 753                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 754                                             COMPILE_FLAGS "${SSE_SWITCH}")
 755             ENDIF()
 756             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 757         ENDIF()
 758     ENDIF()
 759 ENDIF()
 760 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 761     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 762 ENDIF()
 763
 764 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 765 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 766 IF(HAVE_EMMINTRIN_H)
 767     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 768     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 769         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 770             SET(HAVE_SSE2 1)
 771             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 772             IF(SSE2_SWITCH)
 773                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 774                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 775             ENDIF()
 776             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 777         ENDIF()
 778     ENDIF()
 779 ENDIF()
 780 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 781     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 782 ENDIF()
 783
 784 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 785 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 786 IF(HAVE_EMMINTRIN_H)
 787     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 788     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 789         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 790             SET(HAVE_SSE3 1)
 791             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 792             IF(SSE2_SWITCH)
 793                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 794                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 795             ENDIF()
 796             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 797         ENDIF()
 798     ENDIF()
 799 ENDIF()
 800 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 801     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 802 ENDIF()
 803
 804 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 805 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 806 IF(HAVE_SMMINTRIN_H)
 807     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 808     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 809         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 810             SET(HAVE_SSE4_1 1)
 811             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 812             IF(SSE4_1_SWITCH)
 813                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 814                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 815             ENDIF()
 816             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 817         ENDIF()
 818     ENDIF()
 819 ENDIF()
 820 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 821     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 822 ENDIF()
 823
 824 # Check for ARM Neon support
 825 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 826 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 827 IF(HAVE_ARM_NEON_H)
 828     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 829     IF(ALSOFT_CPUEXT_NEON)
 830         SET(HAVE_NEON 1)
 831         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 832         IF(FPU_NEON_SWITCH)
 833             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 834                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 835         ENDIF()
 836         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 837     ENDIF()
 838 ENDIF()
 839 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 840     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 841 ENDIF()
 842
 843
 844 IF(WIN32 OR HAVE_DLFCN_H)
 845     SET(IS_LINKED "")
 846     MACRO(ADD_BACKEND_LIBS _LIBS)
 847     ENDMACRO()
 848 ELSE()
 849     SET(IS_LINKED " (linked)")
 850     MACRO(ADD_BACKEND_LIBS _LIBS)
 851         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 852     ENDMACRO()
 853 ENDIF()
 854
 855 SET(BACKENDS "")
 856 SET(ALC_OBJS  ${ALC_OBJS}
 857               Alc/backends/base.c
 858               # Default backends, always available
 859               Alc/backends/loopback.c
 860               Alc/backends/null.c
 861 )
 862
 863 # Check ALSA backend
 864 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 865 FIND_PACKAGE(ALSA)
 866 IF(ALSA_FOUND)
 867     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 868     IF(ALSOFT_BACKEND_ALSA)
 869         SET(HAVE_ALSA 1)
 870         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 871         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 872         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 873     ENDIF()
 874 ENDIF()
 875 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 876     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 877 ENDIF()
 878
 879 # Check OSS backend
 880 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 881 FIND_PACKAGE(OSS)
 882 IF(OSS_FOUND)
 883     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 884     IF(ALSOFT_BACKEND_OSS)
 885         SET(HAVE_OSS 1)
 886         SET(BACKENDS  "${BACKENDS} OSS,")
 887         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 888     ENDIF()
 889 ENDIF()
 890 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 891     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 892 ENDIF()
 893
 894 # Check Solaris backend
 895 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 896 FIND_PACKAGE(AudioIO)
 897 IF(AUDIOIO_FOUND)
 898     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 899     IF(ALSOFT_BACKEND_SOLARIS)
 900         SET(HAVE_SOLARIS 1)
 901         SET(BACKENDS  "${BACKENDS} Solaris,")
 902         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 903     ENDIF()
 904 ENDIF()
 905 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 906     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 907 ENDIF()
 908
 909 # Check SndIO backend
 910 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 911 FIND_PACKAGE(SoundIO)
 912 IF(SOUNDIO_FOUND)
 913     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 914     IF(ALSOFT_BACKEND_SNDIO)
 915         SET(HAVE_SNDIO 1)
 916         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 917         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 918         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 919     ENDIF()
 920 ENDIF()
 921 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 922     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 923 ENDIF()
 924
 925 # Check QSA backend
 926 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 927 FIND_PACKAGE(QSA)
 928 IF(QSA_FOUND)
 929     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 930     IF(ALSOFT_BACKEND_QSA)
 931         SET(HAVE_QSA 1)
 932         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 933         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 934         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 935     ENDIF()
 936 ENDIF()
 937 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 938     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 939 ENDIF()
 940
 941 # Check Windows-only backends
 942 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 943 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 944 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 945 IF(HAVE_WINDOWS_H)
 946     # Check MMSystem backend
 947     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 948     IF(HAVE_MMSYSTEM_H)
 949         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 950         IF(HAVE_LIBWINMM)
 951             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 952             IF(ALSOFT_BACKEND_WINMM)
 953                 SET(HAVE_WINMM 1)
 954                 SET(BACKENDS  "${BACKENDS} WinMM,")
 955                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 956                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 957             ENDIF()
 958         ENDIF()
 959     ENDIF()
 960
 961     # Check DSound backend
 962     FIND_PACKAGE(DSound)
 963     IF(DSOUND_FOUND)
 964         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 965         IF(ALSOFT_BACKEND_DSOUND)
 966             SET(HAVE_DSOUND 1)
 967             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 968             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 969             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 970         ENDIF()
 971     ENDIF()
 972
 973     # Check for MMDevApi backend
 974     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 975     IF(HAVE_MMDEVICEAPI_H)
 976         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 977         IF(ALSOFT_BACKEND_MMDEVAPI)
 978             SET(HAVE_MMDEVAPI 1)
 979             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 980             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 981         ENDIF()
 982     ENDIF()
 983 ENDIF()
 984 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 985     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 986 ENDIF()
 987 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 988     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 989 ENDIF()
 990 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 991     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 992 ENDIF()
 993
 994 # Check PortAudio backend
 995 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 996 FIND_PACKAGE(PortAudio)
 997 IF(PORTAUDIO_FOUND)
 998     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 999     IF(ALSOFT_BACKEND_PORTAUDIO)
1000         SET(HAVE_PORTAUDIO 1)
1001         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1002         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1003         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1004     ENDIF()
1005 ENDIF()
1006 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1007     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1008 ENDIF()
1009
1010 # Check PulseAudio backend
1011 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1012 FIND_PACKAGE(PulseAudio)
1013 IF(PULSEAUDIO_FOUND)
1014     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1015     IF(ALSOFT_BACKEND_PULSEAUDIO)
1016         SET(HAVE_PULSEAUDIO 1)
1017         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1018         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1019         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1020     ENDIF()
1021 ENDIF()
1022 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1023     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1024 ENDIF()
1025
1026 # Check JACK backend
1027 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1028 FIND_PACKAGE(JACK)
1029 IF(JACK_FOUND)
1030     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1031     IF(ALSOFT_BACKEND_JACK)
1032         SET(HAVE_JACK 1)
1033         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1034         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1035         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1036     ENDIF()
1037 ENDIF()
1038 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1039     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1040 ENDIF()
1041
1042 # Check CoreAudio backend
1043 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1044 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1045              NAMES CoreAudio
1046              PATHS /System/Library/Frameworks
1047 )
1048 IF(COREAUDIO_FRAMEWORK)
1049     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1050     IF(ALSOFT_BACKEND_COREAUDIO)
1051         SET(HAVE_COREAUDIO 1)
1052         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1053         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1054         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1055         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1056         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1057
1058         # Some versions of OSX may need the AudioToolbox framework. Add it if
1059         # it's found.
1060         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1061                      NAMES AudioToolbox
1062                      PATHS ~/Library/Frameworks
1063                            /Library/Frameworks
1064                            /System/Library/Frameworks
1065                     )
1066         IF(AUDIOTOOLBOX_LIBRARY)
1067             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1068         ENDIF()
1069     ENDIF()
1070 ENDIF()
1071 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1072     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1073 ENDIF()
1074
1075 # Check for OpenSL (Android) backend
1076 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1077 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1078 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1079     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1080     IF(HAVE_LIBOPENSLES)
1081         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1082         IF(ALSOFT_BACKEND_OPENSL)
1083             SET(HAVE_OPENSL 1)
1084             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1085             SET(BACKENDS  "${BACKENDS} OpenSL,")
1086             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1087         ENDIF()
1088     ENDIF()
1089 ENDIF()
1090 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1091     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1092 ENDIF()
1093
1094 # Optionally enable the Wave Writer backend
1095 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1096 IF(ALSOFT_BACKEND_WAVE)
1097     SET(HAVE_WAVE 1)
1098     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1099     SET(BACKENDS  "${BACKENDS} WaveFile,")
1100 ENDIF()
1101
1102 # This is always available
1103 SET(BACKENDS  "${BACKENDS} Null")
1104
1105 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1106 if(ALSOFT_EMBED_HRTF_DATA)
1107     SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1108     SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1109     FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1110
1111     SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1112     ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}"
1113         COMMAND ${CMAKE_COMMAND} "${NATIVE_SRC_DIR}"
1114         COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1115         WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1116         DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt" "${NATIVE_SRC_DIR}bin2h.c"
1117         VERBATIM
1118     )
1119
1120     MACRO(make_hrtf_header FILENAME VARNAME)
1121         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1122         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1123
1124         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1125             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1126             DEPENDS "${BIN2H_COMMAND}" "${infile}"
1127             COMMENT "Generating ${FILENAME}.h"
1128             VERBATIM
1129         )
1130
1131         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1132     ENDMACRO()
1133
1134     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1135     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1136 endif()
1137
1138
1139 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1140     add_subdirectory(utils/alsoft-config)
1141 ENDIF()
1142 IF(ALSOFT_EXAMPLES)
1143     FIND_PACKAGE(SDL2)
1144     IF(SDL2_FOUND)
1145         FIND_PACKAGE(SDL_sound)
1146         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1147     ENDIF()
1148 ENDIF()
1149
1150 IF(LIBTYPE STREQUAL "STATIC")
1151     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1152     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1153 ENDIF()
1154
1155 IF(NOT WIN32)
1156     SET(LIBNAME "openal")
1157 ELSE()
1158     SET(LIBNAME "OpenAL32")
1159 ENDIF()
1160
1161 FIND_PACKAGE(Git)
1162 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1163     # Get the current working branch and its latest abbreviated commit hash
1164     ADD_CUSTOM_TARGET(build_version
1165         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1166                          -D LIB_VERSION=${LIB_VERSION}
1167                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1168                          -D DST=${OpenAL_BINARY_DIR}/version.h
1169                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1170         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1171         VERBATIM
1172     )
1173 ELSE()
1174     SET(GIT_BRANCH "UNKNOWN")
1175     SET(GIT_COMMIT_HASH "unknown")
1176     CONFIGURE_FILE(
1177         "${OpenAL_SOURCE_DIR}/version.h.in"
1178         "${OpenAL_BINARY_DIR}/version.h")
1179 ENDIF()
1180
1181 # Needed for openal.pc.in
1182 SET(prefix ${CMAKE_INSTALL_PREFIX})
1183 SET(exec_prefix "\${prefix}")
1184 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1185 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1186 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1187 SET(PACKAGE_VERSION "${LIB_VERSION}")
1188
1189 # End configuration
1190 CONFIGURE_FILE(
1191     "${OpenAL_SOURCE_DIR}/config.h.in"
1192     "${OpenAL_BINARY_DIR}/config.h")
1193 CONFIGURE_FILE(
1194     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1195     "${OpenAL_BINARY_DIR}/openal.pc"
1196     @ONLY)
1197
1198 MACRO(ADD_INCLUDE_DIRS TRGT TESTVAR INCVAR)
1199     IF(${TESTVAR})
1200         SET_PROPERTY(TARGET ${TRGT} APPEND PROPERTY INCLUDE_DIRECTORIES ${${INCVAR}})
1201     ENDIF()
1202 ENDMACRO()
1203
1204 UNSET(HAS_ROUTER)
1205 SET(IMPL_TARGET OpenAL)
1206
1207 # Build main library
1208 IF(LIBTYPE STREQUAL "STATIC")
1209     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1210 ELSE()
1211     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1212         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c ${COMMON_OBJS})
1213         SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1214         SET_PROPERTY(TARGET OpenAL APPEND PROPERTY
1215             COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES
1216         )
1217         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1218         IF(MSVC)
1219             SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1220         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1221             SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1222         ENDIF()
1223         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1224         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1225         IF(TARGET build_version)
1226             ADD_DEPENDENCIES(OpenAL build_version)
1227         ENDIF()
1228         SET(HAS_ROUTER 1)
1229
1230         SET(LIBNAME "soft_oal")
1231         SET(IMPL_TARGET soft_oal)
1232     ENDIF()
1233
1234     ADD_LIBRARY(${IMPL_TARGET} SHARED ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1235     IF(WIN32)
1236         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1237     ENDIF()
1238 ENDIF()
1239 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1240     VERSION ${LIB_VERSION}
1241     SOVERSION ${LIB_MAJOR_VERSION}
1242 )
1243 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY INCLUDE_DIRECTORIES
1244     "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc"
1245 )
1246 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_ALSA       ALSA_INCLUDE_DIRS)
1247 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_OSS        OSS_INCLUDE_DIRS)
1248 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_SOLARIS    AUDIOIO_INCLUDE_DIRS)
1249 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_SNDIO      SOUNDIO_INCLUDE_DIRS)
1250 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_QSA        QSA_INCLUDE_DIRS)
1251 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_DSOUND     DSOUND_INCLUDE_DIRS)
1252 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_PORTAUDIO  PORTAUDIO_INCLUDE_DIRS)
1253 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_PULSEAUDIO PULSEAUDIO_INCLUDE_DIRS)
1254 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_JACK       JACK_INCLUDE_DIRS)
1255 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY
1256     COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES
1257 )
1258 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1259     SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1260 ENDIF()
1261 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1262 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1263
1264 TARGET_LINK_LIBRARIES(${IMPL_TARGET} ${EXTRA_LIBS})
1265 IF(TARGET build_version)
1266     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1267 ENDIF()
1268
1269 IF(WIN32)
1270     IF(MSVC)
1271         SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1272     ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1273         SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1274     ENDIF()
1275
1276     if(NOT LIBTYPE STREQUAL "STATIC")
1277         IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1278             FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1279             FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1280             IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1281                 MESSAGE(STATUS "")
1282                 IF(NOT SED_EXECUTABLE)
1283                     MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1284                 ENDIF()
1285                 IF(NOT DLLTOOL_EXECUTABLE)
1286                     MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1287                 ENDIF()
1288             ELSE()
1289                 SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1290                              " -Wl,--output-def,OpenAL32.def")
1291                 ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1292                     COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1293                     COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1294                     COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1295                     VERBATIM
1296                 )
1297             ENDIF()
1298         ENDIF()
1299     ENDIF()
1300 ENDIF()
1301
1302 IF(ALSOFT_INSTALL)
1303     INSTALL(TARGETS OpenAL EXPORT OpenAL
1304             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1305             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1306             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1307             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1308     )
1309     EXPORT(TARGETS OpenAL
1310            NAMESPACE OpenAL::
1311            FILE OpenALConfig.cmake)
1312     INSTALL(EXPORT OpenAL
1313             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1314             NAMESPACE OpenAL::
1315             FILE OpenALConfig.cmake)
1316     INSTALL(FILES include/AL/al.h
1317                   include/AL/alc.h
1318                   include/AL/alext.h
1319                   include/AL/efx.h
1320                   include/AL/efx-creative.h
1321                   include/AL/efx-presets.h
1322             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1323     )
1324     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1325             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1326     IF(TARGET soft_oal)
1327         INSTALL(TARGETS soft_oal
1328                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1329         )
1330     ENDIF()
1331 ENDIF()
1332
1333
1334 if(HAS_ROUTER)
1335     message(STATUS "")
1336     message(STATUS "Building DLL router")
1337 endif()
1338
1339 MESSAGE(STATUS "")
1340 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1341 MESSAGE(STATUS "    ${BACKENDS}")
1342 MESSAGE(STATUS "")
1343 MESSAGE(STATUS "Building with support for CPU extensions:")
1344 MESSAGE(STATUS "    ${CPU_EXTS}")
1345 MESSAGE(STATUS "")
1346
1347 IF(WIN32)
1348     IF(NOT HAVE_DSOUND)
1349         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1350         MESSAGE(STATUS "         This is probably NOT what you want!")
1351         MESSAGE(STATUS "")
1352     ENDIF()
1353 ENDIF()
1354
1355 if(ALSOFT_EMBED_HRTF_DATA)
1356     message(STATUS "Embedding HRTF datasets")
1357     message(STATUS "")
1358 endif()
1359
1360 # Install alsoft.conf configuration file
1361 IF(ALSOFT_CONFIG)
1362     INSTALL(FILES alsoftrc.sample
1363             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1364     )
1365     MESSAGE(STATUS "Installing sample configuration")
1366     MESSAGE(STATUS "")
1367 ENDIF()
1368
1369 # Install HRTF definitions
1370 IF(ALSOFT_HRTF_DEFS)
1371     INSTALL(FILES hrtf/default-44100.mhr
1372                   hrtf/default-48000.mhr
1373             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1374     )
1375     MESSAGE(STATUS "Installing HRTF definitions")
1376     MESSAGE(STATUS "")
1377 ENDIF()
1378
1379 # Install AmbDec presets
1380 IF(ALSOFT_AMBDEC_PRESETS)
1381     INSTALL(FILES presets/3D7.1.ambdec
1382                   presets/hexagon.ambdec
1383                   presets/itu5.1.ambdec
1384                   presets/rectangle.ambdec
1385                   presets/square.ambdec
1386                   presets/presets.txt
1387             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1388     )
1389     MESSAGE(STATUS "Installing AmbDec presets")
1390     MESSAGE(STATUS "")
1391 ENDIF()
1392
1393 IF(ALSOFT_UTILS)
1394     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1395     SET_PROPERTY(TARGET openal-info APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1396     TARGET_LINK_LIBRARIES(openal-info OpenAL)
1397
1398     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1399     SET_PROPERTY(TARGET makehrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1400     IF(HAVE_LIBM)
1401         TARGET_LINK_LIBRARIES(makehrtf m)
1402     ENDIF()
1403
1404     ADD_EXECUTABLE(bsincgen utils/bsincgen.c)
1405     SET_PROPERTY(TARGET bsincgen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1406     IF(HAVE_LIBM)
1407         TARGET_LINK_LIBRARIES(bsincgen m)
1408     ENDIF()
1409
1410     IF(ALSOFT_INSTALL)
1411         INSTALL(TARGETS openal-info makehrtf bsincgen
1412                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1413                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1414                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1415         )
1416     ENDIF()
1417
1418     MESSAGE(STATUS "Building utility programs")
1419     IF(TARGET alsoft-config)
1420         MESSAGE(STATUS "Building configuration program")
1421     ENDIF()
1422     MESSAGE(STATUS "")
1423 ENDIF()
1424
1425 IF(ALSOFT_TESTS)
1426     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1427
1428     ADD_EXECUTABLE(altonegen examples/altonegen.c ${COMMON_OBJS} ${TEST_COMMON_OBJS})
1429     TARGET_LINK_LIBRARIES(altonegen OpenAL)
1430     SET_PROPERTY(TARGET altonegen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1431
1432     IF(ALSOFT_INSTALL)
1433         INSTALL(TARGETS altonegen
1434                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1435                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1436                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1437         )
1438     ENDIF()
1439
1440     MESSAGE(STATUS "Building test programs")
1441     MESSAGE(STATUS "")
1442 ENDIF()
1443
1444 IF(ALSOFT_EXAMPLES)
1445     ADD_EXECUTABLE(alrecord examples/alrecord.c ${COMMON_OBJS})
1446     TARGET_LINK_LIBRARIES(alrecord OpenAL)
1447     SET_PROPERTY(TARGET alrecord APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1448
1449     IF(ALSOFT_INSTALL)
1450         INSTALL(TARGETS alrecord
1451                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1452                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1453                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1454         )
1455     ENDIF()
1456
1457     MESSAGE(STATUS "Building example programs")
1458
1459     IF(SDL2_FOUND)
1460         IF(SDL_SOUND_FOUND)
1461             SET(EX_COMMON_OBJS  examples/common/alhelpers.c)
1462
1463             ADD_EXECUTABLE(alstream examples/alstream.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1464             TARGET_LINK_LIBRARIES(alstream ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1465             SET_PROPERTY(TARGET alstream APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1466             SET_PROPERTY(TARGET alstream APPEND PROPERTY
1467                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1468             )
1469
1470             ADD_EXECUTABLE(alreverb examples/alreverb.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1471             TARGET_LINK_LIBRARIES(alreverb ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1472             SET_PROPERTY(TARGET alreverb APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1473             SET_PROPERTY(TARGET alreverb APPEND PROPERTY
1474                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1475             )
1476
1477             ADD_EXECUTABLE(allatency examples/allatency.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1478             TARGET_LINK_LIBRARIES(allatency ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1479             SET_PROPERTY(TARGET allatency APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1480             SET_PROPERTY(TARGET allatency APPEND PROPERTY
1481                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1482             )
1483
1484             ADD_EXECUTABLE(alloopback examples/alloopback.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1485             TARGET_LINK_LIBRARIES(alloopback ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1486             SET_PROPERTY(TARGET alloopback APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1487             SET_PROPERTY(TARGET alloopback APPEND PROPERTY
1488                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1489             )
1490
1491             ADD_EXECUTABLE(alhrtf examples/alhrtf.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1492             TARGET_LINK_LIBRARIES(alhrtf ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1493             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1494             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY
1495                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1496             )
1497
1498             IF(ALSOFT_INSTALL)
1499                 INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1500                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1501                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1502                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1503                 )
1504             ENDIF()
1505
1506             MESSAGE(STATUS "Building SDL_sound example programs")
1507         ENDIF()
1508
1509         SET(FFVER_OK FALSE)
1510         IF(FFMPEG_FOUND)
1511             SET(FFVER_OK TRUE)
1512             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1513                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1514                 SET(FFVER_OK FALSE)
1515             ENDIF()
1516             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1517                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1518                 SET(FFVER_OK FALSE)
1519             ENDIF()
1520             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1521                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1522                 SET(FFVER_OK FALSE)
1523             ENDIF()
1524             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1525                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1526                 SET(FFVER_OK FALSE)
1527             ENDIF()
1528             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1529                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1530                 SET(FFVER_OK FALSE)
1531             ENDIF()
1532         ENDIF()
1533         IF(FFVER_OK)
1534             ADD_EXECUTABLE(alffplay examples/alffplay.cpp ${COMMON_OBJS})
1535             TARGET_LINK_LIBRARIES(alffplay ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} OpenAL)
1536             SET_PROPERTY(TARGET alffplay APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1537             SET_PROPERTY(TARGET alffplay APPEND PROPERTY
1538                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS}
1539             )
1540
1541             IF(ALSOFT_INSTALL)
1542                 INSTALL(TARGETS alffplay
1543                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1544                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1545                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1546                 )
1547             ENDIF()
1548             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1549         ENDIF()
1550         MESSAGE(STATUS "")
1551     ENDIF()
1552 ENDIF()