CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSOFT_CPUEXT_SSE  "Check for SSE/SSE2 support" ON)
  29 OPTION(ALSOFT_CPUEXT_NEON "Check for ARM Neon support" ON)
  30
  31 OPTION(ALSOFT_REQUIRE_SSE  "Require SSE/SSE2 support" OFF)
  32 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
  33
  34 IF(WIN32)
  35     # This option is mainly for static linking OpenAL Soft into another project
  36     # that already defines the IDs. It is up to that project to ensure all
  37     # required IDs are defined.
  38     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  39 ENDIF()
  40
  41
  42 OPTION(ALSOFT_BACKEND_ALSA    "Check for ALSA backend"                ON)
  43 OPTION(ALSOFT_BACKEND_OSS     "Check for OSS backend"                 ON)
  44 OPTION(ALSOFT_BACKEND_SOLARIS "Check for Solaris backend"             ON)
  45 OPTION(ALSOFT_BACKEND_SNDIO   "Check for SndIO backend"               ON)
  46 OPTION(ALSOFT_BACKEND_QSA     "Check for QSA backend"                 ON)
  47 OPTION(ALSOFT_BACKEND_MMDEVAPI "Check for MMDevApi backend"           ON)
  48 OPTION(ALSOFT_BACKEND_DSOUND   "Check for DirectSound backend"        ON)
  49 OPTION(ALSOFT_BACKEND_WINMM    "Check for Windows Multimedia backend" ON)
  50 OPTION(ALSOFT_BACKEND_PORTAUDIO  "Check for PortAudio backend"        ON)
  51 OPTION(ALSOFT_BACKEND_PULSEAUDIO "Check for PulseAudio backend"       ON)
  52 OPTION(ALSOFT_BACKEND_COREAUDIO  "Check for CoreAudio backend"        ON)
  53 OPTION(ALSOFT_BACKEND_OPENSL     "Check for OpenSL backend"           ON)
  54 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend"               ON)
  55
  56 OPTION(ALSOFT_MIDI_FLUIDSYNTH "Check for FluidSynth MIDI"             ON)
  57
  58 OPTION(ALSOFT_REQUIRE_ALSA       "Require ALSA backend"               OFF)
  59 OPTION(ALSOFT_REQUIRE_OSS        "Require OSS backend"                OFF)
  60 OPTION(ALSOFT_REQUIRE_SOLARIS    "Require Solaris backend"            OFF)
  61 OPTION(ALSOFT_REQUIRE_SNDIO      "Require SndIO backend"              OFF)
  62 OPTION(ALSOFT_REQUIRE_QSA        "Require QSA backend"                OFF)
  63 OPTION(ALSOFT_REQUIRE_MMDEVAPI   "Require MMDevApi"                   OFF)
  64 OPTION(ALSOFT_REQUIRE_DSOUND     "Require DirectSound backend"        OFF)
  65 OPTION(ALSOFT_REQUIRE_WINMM      "Require Windows Multimedia backend" OFF)
  66 OPTION(ALSOFT_REQUIRE_PORTAUDIO  "Require PortAudio backend"          OFF)
  67 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend"         OFF)
  68 OPTION(ALSOFT_REQUIRE_COREAUDIO  "Require CoreAudio backend"          OFF)
  69 OPTION(ALSOFT_REQUIRE_OPENSL     "Require OpenSL backend"             OFF)
  70
  71 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI"            OFF)
  72
  73 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  74
  75 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  76
  77 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  78 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  79
  80 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  81
  82 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  83
  84
  85 IF(WIN32)
  86     SET(LIBNAME OpenAL32)
  87     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0501")
  88 ELSE()
  89     SET(LIBNAME openal)
  90 ENDIF()
  91
  92 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  93 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  94     ADD_DEFINITIONS("-I/usr/include")
  95     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  96 ENDIF()
  97
  98 IF(NOT LIBTYPE)
  99     SET(LIBTYPE SHARED)
 100 ENDIF()
 101
 102 SET(LIB_MAJOR_VERSION "1")
 103 SET(LIB_MINOR_VERSION "15")
 104 SET(LIB_REVISION "1")
 105 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 106
 107 SET(EXPORT_DECL "")
 108 SET(ALIGN_DECL "")
 109
 110
 111 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 112 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 113
 114
 115 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 116 IF(HAVE_STD_C99)
 117     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 118 ENDIF()
 119
 120 # MSVC may need workarounds for C99 restrict and inline
 121 IF(MSVC)
 122     # TODO: Once we truly require C99, these restrict and inline checks should go
 123     # away.
 124     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 125                              int main() {return 0;}" HAVE_RESTRICT)
 126     IF(NOT HAVE_RESTRICT)
 127         # Slightly convoluted way to do this, because MSVC may barf if restrict is
 128         # defined to __restrict.
 129         CHECK_C_SOURCE_COMPILES("#define restrict __restrict
 130                                  #include <stdlib.h>
 131                                  int *restrict foo;
 132                                  int main() {return 0;}" HAVE___RESTRICT)
 133         IF(HAVE___RESTRICT)
 134             ADD_DEFINITIONS(-Drestrict=__restrict)
 135             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=__restrict")
 136         ELSE()
 137             ADD_DEFINITIONS("-Drestrict=")
 138             SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 139         ENDIF()
 140     ENDIF()
 141
 142     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 143                              int main() {return 0;}" HAVE_INLINE)
 144     IF(NOT HAVE_INLINE)
 145         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 146                                  int main() {return 0;}" HAVE___INLINE)
 147         IF(NOT HAVE___INLINE)
 148             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 149         ENDIF()
 150
 151         ADD_DEFINITIONS(-Dinline=__inline)
 152         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 153     ENDIF()
 154 ENDIF()
 155
 156 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 157 IF(CMAKE_COMPILER_IS_GNUCC)
 158     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 159     # Force no inlining for the next test.
 160     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 161
 162     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 163                              int main() {return foo();}" INLINE_IS_C99)
 164     IF(NOT INLINE_IS_C99)
 165         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 166                              Please update your compiler for better C99 compliance.")
 167     ENDIF()
 168
 169     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 170 ENDIF()
 171
 172 # Add definitions, compiler switches, etc.
 173 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 174 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 175     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 176     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 177         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 178     ENDIF()
 179 ENDIF()
 180
 181 IF(NOT CMAKE_BUILD_TYPE)
 182     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 183         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 184         FORCE)
 185 ENDIF()
 186 IF(NOT CMAKE_DEBUG_POSTFIX)
 187     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 188         "Library postfix for debug builds. Normally left blank."
 189         FORCE)
 190 ENDIF()
 191
 192 IF(MSVC)
 193     # ???
 194     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 195     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 196     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 197     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 198     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 199     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 200     ADD_DEFINITIONS("/wd4098")
 201
 202     IF(NOT DXSDK_DIR)
 203         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 204     ELSE()
 205         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 206     ENDIF()
 207     IF(DXSDK_DIR)
 208         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 209         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 210         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 211         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 212     ENDIF()
 213
 214     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 215     IF(FORCE_STATIC_VCRT)
 216         FOREACH(flag_var
 217                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 218                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 219             IF(${flag_var} MATCHES "/MD")
 220                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 221             ENDIF()
 222         ENDFOREACH(flag_var)
 223     ENDIF()
 224 ELSE()
 225     ADD_DEFINITIONS(-Winline -Wall)
 226     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 227     IF(HAVE_W_EXTRA)
 228         ADD_DEFINITIONS(-Wextra)
 229     ENDIF()
 230
 231     IF(ALSOFT_WERROR)
 232         ADD_DEFINITIONS(-Werror)
 233     ENDIF()
 234
 235     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 236         "Flags used by the compiler during Release with Debug Info builds."
 237         FORCE)
 238     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 239         "Flags used by the compiler during release minsize builds."
 240         FORCE)
 241     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 242         "Flags used by the compiler during release builds"
 243         FORCE)
 244     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 245         "Flags used by the compiler during debug builds."
 246         FORCE)
 247
 248     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 249                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 250 ENDIF()
 251
 252 # Set visibility/export options if available
 253 IF(WIN32)
 254     SET(EXPORT_DECL "__declspec(dllexport)")
 255     IF(NOT MINGW)
 256         SET(ALIGN_DECL "__declspec(align(x))")
 257     ELSE()
 258         SET(ALIGN_DECL "__declspec(aligned(x))")
 259     ENDIF()
 260 ELSE()
 261     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 262     # Yes GCC, really don't accept visibility modes you don't support
 263     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 264
 265     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 266                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 267     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 268         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 269     ELSE()
 270         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 271                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 272         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 273             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 274         ENDIF()
 275     ENDIF()
 276
 277     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 278         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 279         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 280             ADD_DEFINITIONS(-fvisibility=internal)
 281         ELSE()
 282             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 283             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 284                 ADD_DEFINITIONS(-fvisibility=hidden)
 285             ENDIF()
 286         ENDIF()
 287     ENDIF()
 288
 289     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 290                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 291     IF(HAVE_ATTRIBUTE_ALIGNED)
 292         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 293     ENDIF()
 294
 295     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 296 ENDIF()
 297
 298 SET(SSE_SWITCH "")
 299 IF(MSVC)
 300     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 301     IF(HAVE_ARCHSSE_SWITCH)
 302         SET(SSE_SWITCH "/arch:SSE")
 303     ENDIF()
 304 ENDIF()
 305 IF(NOT SSE_SWITCH)
 306     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 307     IF(HAVE_MSSE_SWITCH)
 308         SET(SSE_SWITCH "-msse")
 309     ENDIF()
 310 ENDIF()
 311
 312 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 313                          int main() {return 0;}" HAVE_GCC_FORMAT)
 314
 315 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 316 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 317 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 318 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 319 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 320 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 321 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 322 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 323 IF(NOT HAVE_GUIDDEF_H)
 324     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 325 ENDIF()
 326
 327 # Some systems need libm for some of the following math functions to work
 328 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 329 IF(HAVE_LIBM)
 330     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 331     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 332 ENDIF()
 333
 334
 335 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 336 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 337 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 338 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 339
 340 IF(HAVE_FLOAT_H)
 341     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 342     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 343 ENDIF()
 344
 345 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 346 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 347 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 348 IF(NOT HAVE_STRCASECMP)
 349     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 350     IF(NOT HAVE__STRICMP)
 351         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 352     ENDIF()
 353
 354     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 355 ENDIF()
 356
 357 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 358 IF(NOT HAVE_STRNCASECMP)
 359     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 360     IF(NOT HAVE__STRNICMP)
 361         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 362     ENDIF()
 363
 364     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 365 ENDIF()
 366
 367 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 368 IF(NOT HAVE_SNPRINTF)
 369     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 370     IF(NOT HAVE__SNPRINTF)
 371         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 372     ENDIF()
 373
 374     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 375 ENDIF()
 376
 377 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 378 IF(NOT HAVE_ISFINITE)
 379     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 380     IF(NOT HAVE_FINITE)
 381         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 382         IF(NOT HAVE__FINITE)
 383             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 384         ENDIF()
 385         ADD_DEFINITIONS(-Disfinite=_finite)
 386     ELSE()
 387         ADD_DEFINITIONS(-Disfinite=finite)
 388     ENDIF()
 389 ENDIF()
 390
 391 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 392 IF(NOT HAVE_ISNAN)
 393     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 394     IF(NOT HAVE__ISNAN)
 395         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 396     ENDIF()
 397
 398     ADD_DEFINITIONS(-Disnan=_isnan)
 399 ENDIF()
 400
 401
 402 # Check for the dlopen API (for dynamicly loading backend libs)
 403 IF(ALSOFT_DLOPEN)
 404     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 405     IF(HAVE_DLFCN_H)
 406         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 407         IF(HAVE_LIBDL)
 408             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 409         ENDIF()
 410     ENDIF()
 411 ENDIF()
 412
 413 # Check if we have Windows headers
 414 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0501)
 415 IF(NOT HAVE_WINDOWS_H)
 416     # These are needed on some systems for extra features
 417     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
 418     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
 419
 420     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 421     IF(NOT HAVE_GETTIMEOFDAY)
 422         MESSAGE(FATAL_ERROR "No timing function found!")
 423     ENDIF()
 424
 425     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 426     IF(NOT HAVE_NANOSLEEP)
 427         MESSAGE(FATAL_ERROR "No sleep function found!")
 428     ENDIF()
 429
 430     # We need pthreads outside of Windows
 431     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 432     IF(NOT HAVE_PTHREAD_H)
 433         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 434     ENDIF()
 435     # Some systems need pthread_np.h to get recursive mutexes
 436     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 437
 438     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 439     IF(HAVE_PTHREAD)
 440         ADD_DEFINITIONS(-pthread)
 441         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 442         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 443     ENDIF()
 444
 445     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 446     IF(HAVE_LIBPTHREAD)
 447         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 448     ENDIF()
 449
 450     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 451
 452     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 453     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 454         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 455     ENDIF()
 456
 457     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 458     IF(HAVE_LIBRT)
 459         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 460     ENDIF()
 461 ENDIF()
 462
 463 # Check for a 64-bit type
 464 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 465 IF(NOT HAVE_STDINT_H)
 466     IF(HAVE_WINDOWS_H)
 467         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0501
 468                                  #include <windows.h>
 469                                  __int64 foo;
 470                                  int main() {return 0;}" HAVE___INT64)
 471     ENDIF()
 472     IF(NOT HAVE___INT64)
 473         IF(NOT SIZEOF_LONG MATCHES "8")
 474             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 475                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 476             ENDIF()
 477         ENDIF()
 478     ENDIF()
 479 ENDIF()
 480
 481 # Windows needs winmm for timeGetTime, even if the backend is disabled
 482 CHECK_SHARED_FUNCTION_EXISTS(timeGetTime "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 483 IF(HAVE_LIBWINMM)
 484     SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 485     SET(PKG_CONFIG_LIBS ${PKG_CONFIG_LIBS} -lwinmm)
 486 ENDIF()
 487
 488
 489 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 490                  OpenAL32/alBuffer.c
 491                  OpenAL32/alEffect.c
 492                  OpenAL32/alError.c
 493                  OpenAL32/alExtension.c
 494                  OpenAL32/alFilter.c
 495                  OpenAL32/alFontsound.c
 496                  OpenAL32/alListener.c
 497                  OpenAL32/alMidi.c
 498                  OpenAL32/alPreset.c
 499                  OpenAL32/alSoundfont.c
 500                  OpenAL32/alSource.c
 501                  OpenAL32/alState.c
 502                  OpenAL32/alThunk.c
 503 )
 504 SET(ALC_OBJS  Alc/ALc.c
 505               Alc/ALu.c
 506               Alc/alcConfig.c
 507               Alc/alcRing.c
 508               Alc/bs2b.c
 509               Alc/effects/autowah.c
 510               Alc/effects/chorus.c
 511               Alc/effects/compressor.c
 512               Alc/effects/dedicated.c
 513               Alc/effects/distortion.c
 514               Alc/effects/echo.c
 515               Alc/effects/equalizer.c
 516               Alc/effects/flanger.c
 517               Alc/effects/modulator.c
 518               Alc/effects/null.c
 519               Alc/effects/reverb.c
 520               Alc/helpers.c
 521               Alc/hrtf.c
 522               Alc/panning.c
 523               Alc/threads.c
 524               Alc/mixer.c
 525               Alc/mixer_c.c
 526 )
 527
 528
 529 SET(CPU_EXTS "Default")
 530 SET(HAVE_SSE  0)
 531 SET(HAVE_NEON 0)
 532
 533 # Check for SSE support
 534 IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 535     CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 536     IF(HAVE_XMMINTRIN_H)
 537         SET(HAVE_SSE 1)
 538         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 539         IF(SSE_SWITCH)
 540             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 541                                         COMPILE_FLAGS "${SSE_SWITCH}")
 542         ENDIF()
 543         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 544     ENDIF()
 545 ENDIF()
 546 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 547     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 548 ENDIF()
 549
 550 # Check for ARM Neon support
 551 IF(ALSOFT_CPUEXT_NEON)
 552     CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 553     IF(HAVE_ARM_NEON_H)
 554         SET(HAVE_NEON 1)
 555         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 556         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 557     ENDIF()
 558 ENDIF()
 559 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 560     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 561 ENDIF()
 562
 563
 564 SET(ALC_OBJS  ${ALC_OBJS}
 565               Alc/midi/base.c
 566               Alc/midi/sf2load.c
 567               Alc/midi/dummy.c
 568               Alc/midi/fluidsynth.c
 569 )
 570
 571 SET(HAVE_FLUIDSYNTH  0)
 572
 573 # Check for FluidSynth support
 574 IF(ALSOFT_MIDI_FLUIDSYNTH)
 575     FIND_PACKAGE(FluidSynth)
 576     IF(FLUIDSYNTH_FOUND)
 577         SET(HAVE_FLUIDSYNTH 1)
 578         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 579             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 580         ENDIF()
 581         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 582     ENDIF()
 583 ENDIF()
 584 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 585     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 586 ENDIF()
 587
 588
 589 SET(ALC_OBJS  ${ALC_OBJS}
 590               Alc/backends/base.c
 591               # Default backends, always available
 592               Alc/backends/loopback.c
 593               Alc/backends/null.c
 594 )
 595
 596 SET(BACKENDS "")
 597 SET(HAVE_ALSA       0)
 598 SET(HAVE_OSS        0)
 599 SET(HAVE_SOLARIS    0)
 600 SET(HAVE_SNDIO      0)
 601 SET(HAVE_QSA        0)
 602 SET(HAVE_DSOUND     0)
 603 SET(HAVE_MMDEVAPI   0)
 604 SET(HAVE_WINMM      0)
 605 SET(HAVE_PORTAUDIO  0)
 606 SET(HAVE_PULSEAUDIO 0)
 607 SET(HAVE_COREAUDIO  0)
 608 SET(HAVE_OPENSL     0)
 609 SET(HAVE_WAVE       0)
 610
 611 # Check ALSA backend
 612 IF(ALSOFT_BACKEND_ALSA)
 613     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 614     IF(HAVE_ALSA_ASOUNDLIB_H)
 615         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "alsa/asoundlib.h" asound "" HAVE_LIBASOUND)
 616         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 617             SET(HAVE_ALSA 1)
 618             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 619             IF(HAVE_DLFCN_H OR WIN32)
 620                 SET(BACKENDS  "${BACKENDS} ALSA,")
 621             ELSE()
 622                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 623                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 624             ENDIF()
 625         ENDIF()
 626     ENDIF()
 627 ENDIF()
 628 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 629     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 630 ENDIF()
 631
 632 # Check OSS backend
 633 IF(ALSOFT_BACKEND_OSS)
 634     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 635     IF(HAVE_SYS_SOUNDCARD_H)
 636         SET(HAVE_OSS 1)
 637         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 638         SET(BACKENDS  "${BACKENDS} OSS,")
 639     ENDIF()
 640 ENDIF()
 641 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 642     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 643 ENDIF()
 644
 645 # Check Solaris backend
 646 IF(ALSOFT_BACKEND_SOLARIS)
 647     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 648     IF(HAVE_SYS_AUDIOIO_H)
 649         SET(HAVE_SOLARIS 1)
 650         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 651         SET(BACKENDS  "${BACKENDS} Solaris,")
 652     ENDIF()
 653 ENDIF()
 654 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 655     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 656 ENDIF()
 657
 658 # Check SndIO backend
 659 IF(ALSOFT_BACKEND_SNDIO)
 660     CHECK_INCLUDE_FILE(sndio.h HAVE_SNDIO_H)
 661     IF(HAVE_SNDIO_H)
 662         CHECK_SHARED_FUNCTION_EXISTS(sio_open "sndio.h" sndio "" HAVE_LIBSNDIO)
 663         IF(HAVE_LIBSNDIO)
 664             SET(HAVE_SNDIO 1)
 665             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 666             SET(BACKENDS  "${BACKENDS} SndIO \(linked\),")
 667             SET(EXTRA_LIBS sndio ${EXTRA_LIBS})
 668         ENDIF()
 669     ENDIF()
 670 ENDIF()
 671 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 672     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 673 ENDIF()
 674
 675 # Check QSA backend
 676 IF (ALSOFT_BACKEND_QSA AND "${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 677     CHECK_INCLUDE_FILE(sys/asoundlib.h HAVE_SYS_ASOUNDLIB_H)
 678     IF(HAVE_SYS_ASOUNDLIB_H)
 679         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "sys/asoundlib.h" asound "" HAVE_LIBASOUND)
 680         IF(HAVE_LIBASOUND)
 681             SET(HAVE_QSA 1)
 682             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 683             SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 684             SET(BACKENDS  "${BACKENDS} QSA \(linked\),")
 685         ENDIF()
 686     ENDIF()
 687 ENDIF()
 688 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 689     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 690 ENDIF()
 691
 692 # Check for MMDevApi backend
 693 IF(HAVE_WINDOWS_H)
 694     IF(ALSOFT_BACKEND_MMDEVAPI)
 695         CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 696         IF(HAVE_MMDEVICEAPI_H)
 697             SET(HAVE_MMDEVAPI 1)
 698             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 699
 700             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 701         ENDIF()
 702     ENDIF()
 703 ENDIF()
 704 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 705     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 706 ENDIF()
 707
 708 # Check DSound/MMSystem backend
 709 IF(ALSOFT_BACKEND_DSOUND)
 710     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 711     IF(HAVE_DSOUND_H)
 712         CHECK_SHARED_FUNCTION_EXISTS(DirectSoundCreate "dsound.h" dsound "" HAVE_LIBDSOUND)
 713         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 714             SET(HAVE_DSOUND 1)
 715             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 716
 717             IF(HAVE_DLFCN_H OR WIN32)
 718                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 719             ELSE()
 720                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 721                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 722             ENDIF()
 723         ENDIF()
 724     ENDIF()
 725 ENDIF()
 726 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 727     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 728 ENDIF()
 729
 730 IF(HAVE_WINDOWS_H)
 731     IF(ALSOFT_BACKEND_WINMM)
 732         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0501)
 733         IF(HAVE_MMSYSTEM_H AND HAVE_LIBWINMM)
 734             SET(HAVE_WINMM 1)
 735             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 736             SET(BACKENDS  "${BACKENDS} WinMM,")
 737         ENDIF()
 738     ENDIF()
 739 ENDIF()
 740 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 741     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 742 ENDIF()
 743
 744 # Check PortAudio backend
 745 IF(ALSOFT_BACKEND_PORTAUDIO)
 746     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 747     IF(HAVE_PORTAUDIO_H)
 748         CHECK_SHARED_FUNCTION_EXISTS(Pa_Initialize "portaudio.h" portaudio "" HAVE_LIBPORTAUDIO)
 749         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 750             SET(HAVE_PORTAUDIO 1)
 751             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 752             IF(HAVE_DLFCN_H OR WIN32)
 753                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 754             ELSE()
 755                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 756                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 757             ENDIF()
 758         ENDIF()
 759     ENDIF()
 760 ENDIF()
 761 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 762     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 763 ENDIF()
 764
 765 # Check PulseAudio backend
 766 IF(ALSOFT_BACKEND_PULSEAUDIO)
 767     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 768     IF(HAVE_PULSE_PULSEAUDIO_H)
 769         CHECK_SHARED_FUNCTION_EXISTS(pa_context_new "pulse/pulseaudio.h" pulse "" HAVE_LIBPULSE)
 770         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 771             SET(HAVE_PULSEAUDIO 1)
 772             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 773             IF(HAVE_DLFCN_H OR WIN32)
 774                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 775             ELSE()
 776                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 777                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 778             ENDIF()
 779         ENDIF()
 780     ENDIF()
 781 ENDIF()
 782 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 783     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 784 ENDIF()
 785
 786 # Check CoreAudio backend
 787 IF(ALSOFT_BACKEND_COREAUDIO)
 788     CHECK_INCLUDE_FILE(/System/Library/Frameworks/CoreAudio.framework/Headers/CoreAudio.h HAVE_COREAUDIO_FRAMEWORK)
 789     IF(HAVE_COREAUDIO_FRAMEWORK)
 790         SET(HAVE_COREAUDIO 1)
 791         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 792         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 793         SET(EXTRA_LIBS /System/Library/Frameworks/CoreAudio.framework ${EXTRA_LIBS})
 794         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 795         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 796
 797         # Some versions of OSX may need the AudioToolbox framework. Add it if
 798         # it's found.
 799         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 800                      NAMES AudioToolbox
 801                      PATHS ~/Library/Frameworks
 802                            /Library/Frameworks
 803                            /System/Library/Frameworks
 804                     )
 805         IF(AUDIOTOOLBOX_LIBRARY)
 806             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 807         ENDIF()
 808     ENDIF()
 809 ENDIF()
 810 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 811     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 812 ENDIF()
 813
 814 # Check for OpenSL (Android) backend
 815 IF(ALSOFT_BACKEND_OPENSL)
 816     CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 817     IF(HAVE_SLES_OPENSLES_ANDROID_H)
 818         CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 819         IF(HAVE_LIBOPENSLES)
 820             SET(HAVE_OPENSL 1)
 821             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 822             SET(BACKENDS  "${BACKENDS} OpenSL,")
 823             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 824         ENDIF()
 825     ENDIF()
 826 ENDIF()
 827 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 828     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 829 ENDIF()
 830
 831 # Optionally enable the Wave Writer backend
 832 IF(ALSOFT_BACKEND_WAVE)
 833     SET(HAVE_WAVE 1)
 834     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 835     SET(BACKENDS  "${BACKENDS} WaveFile,")
 836 ENDIF()
 837
 838 # This is always available
 839 SET(BACKENDS  "${BACKENDS} Null")
 840
 841 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 842     add_subdirectory(utils/alsoft-config)
 843 ENDIF()
 844 IF(ALSOFT_EXAMPLES)
 845     FIND_PACKAGE(SDL)
 846     IF(SDL_FOUND)
 847         FIND_PACKAGE(SDL_sound)
 848         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 849             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 850         ENDIF()
 851     ENDIF()
 852 ENDIF()
 853
 854 IF(LIBTYPE STREQUAL "STATIC")
 855     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 856     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 857 ENDIF()
 858
 859 # Needed for openal.pc.in
 860 SET(prefix ${CMAKE_INSTALL_PREFIX})
 861 SET(exec_prefix "\${prefix}")
 862 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 863 SET(bindir "\${exec_prefix}/bin")
 864 SET(includedir "\${prefix}/include")
 865 SET(PACKAGE_VERSION "${LIB_VERSION}")
 866
 867 # End configuration
 868 CONFIGURE_FILE(
 869     "${OpenAL_SOURCE_DIR}/config.h.in"
 870     "${OpenAL_BINARY_DIR}/config.h")
 871 CONFIGURE_FILE(
 872     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 873     "${OpenAL_BINARY_DIR}/openal.pc"
 874     @ONLY)
 875
 876 # Build a library
 877 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 878 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 879 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 880     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 881 ENDIF()
 882 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 883 IF(FLUIDSYNTH_FOUND)
 884     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 885 ENDIF()
 886 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 887                                             SOVERSION ${LIB_MAJOR_VERSION})
 888 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 889     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 890 ENDIF()
 891
 892 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 893
 894 # Add an install target here
 895 INSTALL(TARGETS ${LIBNAME}
 896         RUNTIME DESTINATION bin
 897         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 898         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 899 )
 900 INSTALL(FILES include/AL/al.h
 901               include/AL/alc.h
 902               include/AL/alext.h
 903               include/AL/efx.h
 904               include/AL/efx-creative.h
 905               include/AL/efx-presets.h
 906         DESTINATION include/AL
 907 )
 908 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 909         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 910
 911
 912 MESSAGE(STATUS "")
 913 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 914 MESSAGE(STATUS "    ${BACKENDS}")
 915 MESSAGE(STATUS "")
 916 MESSAGE(STATUS "Building with support for CPU extensions:")
 917 MESSAGE(STATUS "    ${CPU_EXTS}")
 918 MESSAGE(STATUS "")
 919 IF(HAVE_FLUIDSYNTH)
 920     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
 921     MESSAGE(STATUS "")
 922 ENDIF()
 923
 924 IF(WIN32)
 925     IF(NOT HAVE_DSOUND)
 926         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 927         MESSAGE(STATUS "         This is probably NOT what you want!")
 928         MESSAGE(STATUS "")
 929     ENDIF()
 930 ENDIF()
 931
 932 # Install alsoft.conf configuration file
 933 IF(ALSOFT_CONFIG)
 934     INSTALL(FILES alsoftrc.sample
 935             DESTINATION share/openal
 936     )
 937     MESSAGE(STATUS "Installing sample configuration")
 938     MESSAGE(STATUS "")
 939 ENDIF()
 940
 941 IF(ALSOFT_UTILS)
 942     ADD_EXECUTABLE(openal-info utils/openal-info.c)
 943     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 944
 945     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
 946     IF(HAVE_LIBM)
 947         TARGET_LINK_LIBRARIES(makehrtf m)
 948     ENDIF()
 949
 950     INSTALL(TARGETS openal-info makehrtf
 951             RUNTIME DESTINATION bin
 952             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 953             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 954     )
 955
 956     MESSAGE(STATUS "Building utility programs")
 957     IF(TARGET alsoft-config)
 958         MESSAGE(STATUS "Building configuration program")
 959     ENDIF()
 960     MESSAGE(STATUS "")
 961 ENDIF()
 962
 963 IF(ALSOFT_EXAMPLES)
 964     IF(SDL_FOUND AND SDL_SOUND_FOUND)
 965         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
 966                                      examples/common/sdl_sound.c)
 967         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 968
 969         ADD_EXECUTABLE(alstream examples/alstream.c)
 970         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 971         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 972
 973         ADD_EXECUTABLE(alreverb examples/alreverb.c)
 974         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 975         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 976
 977         ADD_EXECUTABLE(allatency examples/allatency.c)
 978         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 979         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 980
 981         ADD_EXECUTABLE(alloopback examples/alloopback.c)
 982         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
 983         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
 984                                                                            ${SDL_SOUND_INCLUDE_DIR})
 985
 986         INSTALL(TARGETS alstream alreverb allatency alloopback
 987                 RUNTIME DESTINATION bin
 988                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 989                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 990         )
 991
 992         MESSAGE(STATUS "Building example programs")
 993         MESSAGE(STATUS "")
 994     ENDIF()
 995 ENDIF()