CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSOFT_CPUEXT_SSE  "Check for SSE/SSE2 support" ON)
  29 OPTION(ALSOFT_CPUEXT_NEON "Check for ARM Neon support" ON)
  30
  31 OPTION(ALSOFT_REQUIRE_SSE  "Require SSE/SSE2 support" OFF)
  32 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
  33
  34 IF(WIN32)
  35     # This option is mainly for static linking OpenAL Soft into another project
  36     # that already defines the IDs. It is up to that project to ensure all
  37     # required IDs are defined.
  38     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  39 ENDIF()
  40
  41
  42 OPTION(ALSOFT_BACKEND_ALSA    "Check for ALSA backend"                ON)
  43 OPTION(ALSOFT_BACKEND_OSS     "Check for OSS backend"                 ON)
  44 OPTION(ALSOFT_BACKEND_SOLARIS "Check for Solaris backend"             ON)
  45 OPTION(ALSOFT_BACKEND_SNDIO   "Check for SndIO backend"               ON)
  46 OPTION(ALSOFT_BACKEND_QSA     "Check for QSA backend"                 ON)
  47 OPTION(ALSOFT_BACKEND_MMDEVAPI "Check for MMDevApi backend"           ON)
  48 OPTION(ALSOFT_BACKEND_DSOUND   "Check for DirectSound backend"        ON)
  49 OPTION(ALSOFT_BACKEND_WINMM    "Check for Windows Multimedia backend" ON)
  50 OPTION(ALSOFT_BACKEND_PORTAUDIO  "Check for PortAudio backend"        ON)
  51 OPTION(ALSOFT_BACKEND_PULSEAUDIO "Check for PulseAudio backend"       ON)
  52 OPTION(ALSOFT_BACKEND_COREAUDIO  "Check for CoreAudio backend"        ON)
  53 OPTION(ALSOFT_BACKEND_OPENSL     "Check for OpenSL backend"           ON)
  54 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend"               ON)
  55
  56 OPTION(ALSOFT_MIDI_FLUIDSYNTH "Check for FluidSynth MIDI"             ON)
  57
  58 OPTION(ALSOFT_REQUIRE_ALSA       "Require ALSA backend"               OFF)
  59 OPTION(ALSOFT_REQUIRE_OSS        "Require OSS backend"                OFF)
  60 OPTION(ALSOFT_REQUIRE_SOLARIS    "Require Solaris backend"            OFF)
  61 OPTION(ALSOFT_REQUIRE_SNDIO      "Require SndIO backend"              OFF)
  62 OPTION(ALSOFT_REQUIRE_QSA        "Require QSA backend"                OFF)
  63 OPTION(ALSOFT_REQUIRE_MMDEVAPI   "Require MMDevApi"                   OFF)
  64 OPTION(ALSOFT_REQUIRE_DSOUND     "Require DirectSound backend"        OFF)
  65 OPTION(ALSOFT_REQUIRE_WINMM      "Require Windows Multimedia backend" OFF)
  66 OPTION(ALSOFT_REQUIRE_PORTAUDIO  "Require PortAudio backend"          OFF)
  67 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend"         OFF)
  68 OPTION(ALSOFT_REQUIRE_COREAUDIO  "Require CoreAudio backend"          OFF)
  69 OPTION(ALSOFT_REQUIRE_OPENSL     "Require OpenSL backend"             OFF)
  70
  71 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI"            OFF)
  72
  73 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  74
  75 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  76
  77 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  78 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  79
  80 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  81
  82 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  83 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  84
  85
  86 IF(WIN32)
  87     SET(LIBNAME OpenAL32)
  88     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0501")
  89 ELSE()
  90     SET(LIBNAME openal)
  91 ENDIF()
  92
  93 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  94 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  95     ADD_DEFINITIONS("-I/usr/include")
  96     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  97 ENDIF()
  98
  99 IF(NOT LIBTYPE)
 100     SET(LIBTYPE SHARED)
 101 ENDIF()
 102
 103 SET(LIB_MAJOR_VERSION "1")
 104 SET(LIB_MINOR_VERSION "15")
 105 SET(LIB_REVISION "1")
 106 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 107
 108 SET(EXPORT_DECL "")
 109 SET(ALIGN_DECL "")
 110
 111
 112 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 113 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 114
 115
 116 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 117 IF(HAVE_STD_C99)
 118     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 119 ENDIF()
 120
 121 # MSVC may need workarounds for C99 restrict and inline
 122 IF(MSVC)
 123     # TODO: Once we truly require C99, these restrict and inline checks should go
 124     # away.
 125     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 126                              int main() {return 0;}" HAVE_RESTRICT)
 127     IF(NOT HAVE_RESTRICT)
 128         ADD_DEFINITIONS("-Drestrict=")
 129         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 130     ENDIF()
 131
 132     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 133                              int main() {return 0;}" HAVE_INLINE)
 134     IF(NOT HAVE_INLINE)
 135         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 136                                  int main() {return 0;}" HAVE___INLINE)
 137         IF(NOT HAVE___INLINE)
 138             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 139         ENDIF()
 140
 141         ADD_DEFINITIONS(-Dinline=__inline)
 142         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 143     ENDIF()
 144 ENDIF()
 145
 146 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 147 IF(CMAKE_COMPILER_IS_GNUCC)
 148     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 149     # Force no inlining for the next test.
 150     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 151
 152     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 153                              int main() {return foo();}" INLINE_IS_C99)
 154     IF(NOT INLINE_IS_C99)
 155         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 156                              Please update your compiler for better C99 compliance.")
 157     ENDIF()
 158
 159     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 160 ENDIF()
 161
 162 # Add definitions, compiler switches, etc.
 163 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 164 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 165     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 166     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 167         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 168     ENDIF()
 169 ENDIF()
 170
 171 IF(NOT CMAKE_BUILD_TYPE)
 172     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 173         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 174         FORCE)
 175 ENDIF()
 176 IF(NOT CMAKE_DEBUG_POSTFIX)
 177     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 178         "Library postfix for debug builds. Normally left blank."
 179         FORCE)
 180 ENDIF()
 181
 182 IF(MSVC)
 183     # ???
 184     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 185     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 186     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 187     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 188     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 189     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 190     ADD_DEFINITIONS("/wd4098")
 191
 192     IF(NOT DXSDK_DIR)
 193         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 194     ELSE()
 195         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 196     ENDIF()
 197     IF(DXSDK_DIR)
 198         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 199         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 200         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 201         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 202     ENDIF()
 203
 204     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 205     IF(FORCE_STATIC_VCRT)
 206         FOREACH(flag_var
 207                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 208                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 209             IF(${flag_var} MATCHES "/MD")
 210                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 211             ENDIF()
 212         ENDFOREACH(flag_var)
 213     ENDIF()
 214 ELSE()
 215     ADD_DEFINITIONS(-Winline -Wall)
 216     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 217     IF(HAVE_W_EXTRA)
 218         ADD_DEFINITIONS(-Wextra)
 219     ENDIF()
 220
 221     IF(ALSOFT_WERROR)
 222         ADD_DEFINITIONS(-Werror)
 223     ENDIF()
 224
 225     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 226         "Flags used by the compiler during Release with Debug Info builds."
 227         FORCE)
 228     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 229         "Flags used by the compiler during release minsize builds."
 230         FORCE)
 231     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 232         "Flags used by the compiler during release builds"
 233         FORCE)
 234     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 235         "Flags used by the compiler during debug builds."
 236         FORCE)
 237
 238     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 239                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 240 ENDIF()
 241
 242 # Set visibility/export options if available
 243 IF(WIN32)
 244     SET(EXPORT_DECL "__declspec(dllexport)")
 245     IF(NOT MINGW)
 246         SET(ALIGN_DECL "__declspec(align(x))")
 247     ELSE()
 248         SET(ALIGN_DECL "__declspec(aligned(x))")
 249     ENDIF()
 250 ELSE()
 251     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 252     # Yes GCC, really don't accept visibility modes you don't support
 253     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 254
 255     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 256                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 257     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 258         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 259     ELSE()
 260         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 261                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 262         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 263             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 264         ENDIF()
 265     ENDIF()
 266
 267     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 268         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 269         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 270             ADD_DEFINITIONS(-fvisibility=internal)
 271         ELSE()
 272             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 273             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 274                 ADD_DEFINITIONS(-fvisibility=hidden)
 275             ENDIF()
 276         ENDIF()
 277     ENDIF()
 278
 279     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 280                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 281     IF(HAVE_ATTRIBUTE_ALIGNED)
 282         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 283     ENDIF()
 284
 285     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 286 ENDIF()
 287
 288 SET(SSE_SWITCH "")
 289 IF(MSVC)
 290     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 291     IF(HAVE_ARCHSSE_SWITCH)
 292         SET(SSE_SWITCH "/arch:SSE")
 293     ENDIF()
 294 ENDIF()
 295 IF(NOT SSE_SWITCH)
 296     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 297     IF(HAVE_MSSE_SWITCH)
 298         SET(SSE_SWITCH "-msse")
 299     ENDIF()
 300 ENDIF()
 301
 302 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 303                          int main() {return 0;}" HAVE_GCC_FORMAT)
 304
 305 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 306 CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 307 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 308 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 309 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 310 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 311 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 312 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 313 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 314 IF(NOT HAVE_GUIDDEF_H)
 315     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 316 ENDIF()
 317
 318 # Some systems need libm for some of the following math functions to work
 319 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 320 IF(HAVE_LIBM)
 321     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 322     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 323 ENDIF()
 324
 325
 326 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 327 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 328 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 329 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 330 IF(HAVE_ALLOCA_H)
 331     CHECK_SYMBOL_EXISTS(alloca alloca.h HAVE_ALLOCA)
 332 ELSEIF(HAVE_MALLOC_H)
 333     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 334 ENDIF()
 335 IF(NOT HAVE_ALLOCA)
 336     CHECK_SYMBOL_EXISTS(_alloca malloc.h HAVE__ALLOCA)
 337     IF(NOT HAVE__ALLOCA)
 338         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 339     ENDIF()
 340
 341     ADD_DEFINITIONS(-Dalloca=_alloca)
 342 ENDIF()
 343
 344 IF(HAVE_FLOAT_H)
 345     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 346     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 347 ENDIF()
 348
 349 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 350 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 351 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 352 IF(NOT HAVE_STRCASECMP)
 353     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 354     IF(NOT HAVE__STRICMP)
 355         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 356     ENDIF()
 357
 358     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 359 ENDIF()
 360
 361 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 362 IF(NOT HAVE_STRNCASECMP)
 363     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 364     IF(NOT HAVE__STRNICMP)
 365         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 366     ENDIF()
 367
 368     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 369 ENDIF()
 370
 371 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 372 IF(NOT HAVE_SNPRINTF)
 373     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 374     IF(NOT HAVE__SNPRINTF)
 375         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 376     ENDIF()
 377
 378     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 379 ENDIF()
 380
 381 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 382 IF(NOT HAVE_ISFINITE)
 383     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 384     IF(NOT HAVE_FINITE)
 385         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 386         IF(NOT HAVE__FINITE)
 387             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 388         ENDIF()
 389         ADD_DEFINITIONS(-Disfinite=_finite)
 390     ELSE()
 391         ADD_DEFINITIONS(-Disfinite=finite)
 392     ENDIF()
 393 ENDIF()
 394
 395 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 396 IF(NOT HAVE_ISNAN)
 397     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 398     IF(NOT HAVE__ISNAN)
 399         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 400     ENDIF()
 401
 402     ADD_DEFINITIONS(-Disnan=_isnan)
 403 ENDIF()
 404
 405
 406 # Check for the dlopen API (for dynamicly loading backend libs)
 407 IF(ALSOFT_DLOPEN)
 408     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 409     IF(HAVE_DLFCN_H)
 410         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 411         IF(HAVE_LIBDL)
 412             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 413         ENDIF()
 414     ENDIF()
 415 ENDIF()
 416
 417 # Check if we have Windows headers
 418 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0501)
 419 IF(NOT HAVE_WINDOWS_H)
 420     # These are needed on some systems for extra features
 421     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
 422     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
 423
 424     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 425     IF(NOT HAVE_GETTIMEOFDAY)
 426         MESSAGE(FATAL_ERROR "No timing function found!")
 427     ENDIF()
 428
 429     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 430     IF(NOT HAVE_NANOSLEEP)
 431         MESSAGE(FATAL_ERROR "No sleep function found!")
 432     ENDIF()
 433
 434     # We need pthreads outside of Windows
 435     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 436     IF(NOT HAVE_PTHREAD_H)
 437         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 438     ENDIF()
 439     # Some systems need pthread_np.h to get recursive mutexes
 440     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 441
 442     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 443     IF(HAVE_PTHREAD)
 444         ADD_DEFINITIONS(-pthread)
 445         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 446         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 447     ENDIF()
 448
 449     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 450     IF(HAVE_LIBPTHREAD)
 451         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 452     ENDIF()
 453
 454     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 455
 456     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 457     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 458         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 459     ENDIF()
 460
 461     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 462     IF(HAVE_LIBRT)
 463         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 464     ENDIF()
 465 ENDIF()
 466
 467 # Check for a 64-bit type
 468 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 469 IF(NOT HAVE_STDINT_H)
 470     IF(HAVE_WINDOWS_H)
 471         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0501
 472                                  #include <windows.h>
 473                                  __int64 foo;
 474                                  int main() {return 0;}" HAVE___INT64)
 475     ENDIF()
 476     IF(NOT HAVE___INT64)
 477         IF(NOT SIZEOF_LONG MATCHES "8")
 478             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 479                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 480             ENDIF()
 481         ENDIF()
 482     ENDIF()
 483 ENDIF()
 484
 485 # Windows needs winmm for timeGetTime, even if the backend is disabled
 486 CHECK_SHARED_FUNCTION_EXISTS(timeGetTime "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 487 IF(HAVE_LIBWINMM)
 488     SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 489     SET(PKG_CONFIG_LIBS ${PKG_CONFIG_LIBS} -lwinmm)
 490 ENDIF()
 491
 492
 493 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 494                  OpenAL32/alBuffer.c
 495                  OpenAL32/alEffect.c
 496                  OpenAL32/alError.c
 497                  OpenAL32/alExtension.c
 498                  OpenAL32/alFilter.c
 499                  OpenAL32/alFontsound.c
 500                  OpenAL32/alListener.c
 501                  OpenAL32/alMidi.c
 502                  OpenAL32/alPreset.c
 503                  OpenAL32/alSoundfont.c
 504                  OpenAL32/alSource.c
 505                  OpenAL32/alState.c
 506                  OpenAL32/alThunk.c
 507                  OpenAL32/sample_cvt.c
 508 )
 509 SET(ALC_OBJS  Alc/ALc.c
 510               Alc/ALu.c
 511               Alc/alcConfig.c
 512               Alc/alcRing.c
 513               Alc/bs2b.c
 514               Alc/effects/autowah.c
 515               Alc/effects/chorus.c
 516               Alc/effects/compressor.c
 517               Alc/effects/dedicated.c
 518               Alc/effects/distortion.c
 519               Alc/effects/echo.c
 520               Alc/effects/equalizer.c
 521               Alc/effects/flanger.c
 522               Alc/effects/modulator.c
 523               Alc/effects/null.c
 524               Alc/effects/reverb.c
 525               Alc/helpers.c
 526               Alc/hrtf.c
 527               Alc/panning.c
 528               Alc/threads.c
 529               Alc/mixer.c
 530               Alc/mixer_c.c
 531 )
 532
 533
 534 SET(CPU_EXTS "Default")
 535 SET(HAVE_SSE  0)
 536 SET(HAVE_NEON 0)
 537
 538 # Check for SSE support
 539 IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 540     CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 541     IF(HAVE_XMMINTRIN_H)
 542         SET(HAVE_SSE 1)
 543         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 544         IF(SSE_SWITCH)
 545             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 546                                         COMPILE_FLAGS "${SSE_SWITCH}")
 547         ENDIF()
 548         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 549     ENDIF()
 550 ENDIF()
 551 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 552     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 553 ENDIF()
 554
 555 # Check for ARM Neon support
 556 IF(ALSOFT_CPUEXT_NEON)
 557     CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 558     IF(HAVE_ARM_NEON_H)
 559         SET(HAVE_NEON 1)
 560         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 561         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 562     ENDIF()
 563 ENDIF()
 564 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 565     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 566 ENDIF()
 567
 568
 569 SET(ALC_OBJS  ${ALC_OBJS}
 570               Alc/midi/base.c
 571               Alc/midi/sf2load.c
 572               Alc/midi/dummy.c
 573               Alc/midi/fluidsynth.c
 574               Alc/midi/soft.c
 575 )
 576
 577 SET(HAVE_FLUIDSYNTH  0)
 578
 579 # Check for FluidSynth support
 580 IF(ALSOFT_MIDI_FLUIDSYNTH)
 581     FIND_PACKAGE(FluidSynth)
 582     IF(FLUIDSYNTH_FOUND)
 583         SET(HAVE_FLUIDSYNTH 1)
 584         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 585             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 586         ENDIF()
 587         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 588     ENDIF()
 589 ENDIF()
 590 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 591     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 592 ENDIF()
 593
 594
 595 SET(ALC_OBJS  ${ALC_OBJS}
 596               Alc/backends/base.c
 597               # Default backends, always available
 598               Alc/backends/loopback.c
 599               Alc/backends/null.c
 600 )
 601
 602 SET(BACKENDS "")
 603 SET(HAVE_ALSA       0)
 604 SET(HAVE_OSS        0)
 605 SET(HAVE_SOLARIS    0)
 606 SET(HAVE_SNDIO      0)
 607 SET(HAVE_QSA        0)
 608 SET(HAVE_DSOUND     0)
 609 SET(HAVE_MMDEVAPI   0)
 610 SET(HAVE_WINMM      0)
 611 SET(HAVE_PORTAUDIO  0)
 612 SET(HAVE_PULSEAUDIO 0)
 613 SET(HAVE_COREAUDIO  0)
 614 SET(HAVE_OPENSL     0)
 615 SET(HAVE_WAVE       0)
 616
 617 # Check ALSA backend
 618 IF(ALSOFT_BACKEND_ALSA)
 619     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 620     IF(HAVE_ALSA_ASOUNDLIB_H)
 621         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "alsa/asoundlib.h" asound "" HAVE_LIBASOUND)
 622         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 623             SET(HAVE_ALSA 1)
 624             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 625             IF(HAVE_DLFCN_H OR WIN32)
 626                 SET(BACKENDS  "${BACKENDS} ALSA,")
 627             ELSE()
 628                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 629                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 630             ENDIF()
 631         ENDIF()
 632     ENDIF()
 633 ENDIF()
 634 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 635     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 636 ENDIF()
 637
 638 # Check OSS backend
 639 IF(ALSOFT_BACKEND_OSS)
 640     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 641     IF(HAVE_SYS_SOUNDCARD_H)
 642         SET(HAVE_OSS 1)
 643         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 644         SET(BACKENDS  "${BACKENDS} OSS,")
 645     ENDIF()
 646 ENDIF()
 647 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 648     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 649 ENDIF()
 650
 651 # Check Solaris backend
 652 IF(ALSOFT_BACKEND_SOLARIS)
 653     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 654     IF(HAVE_SYS_AUDIOIO_H)
 655         SET(HAVE_SOLARIS 1)
 656         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 657         SET(BACKENDS  "${BACKENDS} Solaris,")
 658     ENDIF()
 659 ENDIF()
 660 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 661     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 662 ENDIF()
 663
 664 # Check SndIO backend
 665 IF(ALSOFT_BACKEND_SNDIO)
 666     CHECK_INCLUDE_FILE(sndio.h HAVE_SNDIO_H)
 667     IF(HAVE_SNDIO_H)
 668         CHECK_SHARED_FUNCTION_EXISTS(sio_open "sndio.h" sndio "" HAVE_LIBSNDIO)
 669         IF(HAVE_LIBSNDIO)
 670             SET(HAVE_SNDIO 1)
 671             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 672             SET(BACKENDS  "${BACKENDS} SndIO \(linked\),")
 673             SET(EXTRA_LIBS sndio ${EXTRA_LIBS})
 674         ENDIF()
 675     ENDIF()
 676 ENDIF()
 677 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 678     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 679 ENDIF()
 680
 681 # Check QSA backend
 682 IF (ALSOFT_BACKEND_QSA AND "${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 683     CHECK_INCLUDE_FILE(sys/asoundlib.h HAVE_SYS_ASOUNDLIB_H)
 684     IF(HAVE_SYS_ASOUNDLIB_H)
 685         CHECK_SHARED_FUNCTION_EXISTS(snd_pcm_open "sys/asoundlib.h" asound "" HAVE_LIBASOUND)
 686         IF(HAVE_LIBASOUND)
 687             SET(HAVE_QSA 1)
 688             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 689             SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 690             SET(BACKENDS  "${BACKENDS} QSA \(linked\),")
 691         ENDIF()
 692     ENDIF()
 693 ENDIF()
 694 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 695     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 696 ENDIF()
 697
 698 # Check for MMDevApi backend
 699 IF(HAVE_WINDOWS_H)
 700     IF(ALSOFT_BACKEND_MMDEVAPI)
 701         CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 702         IF(HAVE_MMDEVICEAPI_H)
 703             SET(HAVE_MMDEVAPI 1)
 704             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 705
 706             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 707         ENDIF()
 708     ENDIF()
 709 ENDIF()
 710 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 711     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 712 ENDIF()
 713
 714 # Check DSound/MMSystem backend
 715 IF(ALSOFT_BACKEND_DSOUND)
 716     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 717     IF(HAVE_DSOUND_H)
 718         CHECK_SHARED_FUNCTION_EXISTS(DirectSoundCreate "dsound.h" dsound "" HAVE_LIBDSOUND)
 719         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 720             SET(HAVE_DSOUND 1)
 721             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 722
 723             IF(HAVE_DLFCN_H OR WIN32)
 724                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 725             ELSE()
 726                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 727                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 728             ENDIF()
 729         ENDIF()
 730     ENDIF()
 731 ENDIF()
 732 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 733     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 734 ENDIF()
 735
 736 IF(HAVE_WINDOWS_H)
 737     IF(ALSOFT_BACKEND_WINMM)
 738         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0501)
 739         IF(HAVE_MMSYSTEM_H AND HAVE_LIBWINMM)
 740             SET(HAVE_WINMM 1)
 741             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 742             SET(BACKENDS  "${BACKENDS} WinMM,")
 743         ENDIF()
 744     ENDIF()
 745 ENDIF()
 746 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 747     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 748 ENDIF()
 749
 750 # Check PortAudio backend
 751 IF(ALSOFT_BACKEND_PORTAUDIO)
 752     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 753     IF(HAVE_PORTAUDIO_H)
 754         CHECK_SHARED_FUNCTION_EXISTS(Pa_Initialize "portaudio.h" portaudio "" HAVE_LIBPORTAUDIO)
 755         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 756             SET(HAVE_PORTAUDIO 1)
 757             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 758             IF(HAVE_DLFCN_H OR WIN32)
 759                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 760             ELSE()
 761                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 762                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 763             ENDIF()
 764         ENDIF()
 765     ENDIF()
 766 ENDIF()
 767 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 768     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 769 ENDIF()
 770
 771 # Check PulseAudio backend
 772 IF(ALSOFT_BACKEND_PULSEAUDIO)
 773     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 774     IF(HAVE_PULSE_PULSEAUDIO_H)
 775         CHECK_SHARED_FUNCTION_EXISTS(pa_context_new "pulse/pulseaudio.h" pulse "" HAVE_LIBPULSE)
 776         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 777             SET(HAVE_PULSEAUDIO 1)
 778             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 779             IF(HAVE_DLFCN_H OR WIN32)
 780                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 781             ELSE()
 782                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 783                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 784             ENDIF()
 785         ENDIF()
 786     ENDIF()
 787 ENDIF()
 788 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 789     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 790 ENDIF()
 791
 792 # Check CoreAudio backend
 793 IF(ALSOFT_BACKEND_COREAUDIO)
 794     CHECK_INCLUDE_FILE(/System/Library/Frameworks/CoreAudio.framework/Headers/CoreAudio.h HAVE_COREAUDIO_FRAMEWORK)
 795     IF(HAVE_COREAUDIO_FRAMEWORK)
 796         SET(HAVE_COREAUDIO 1)
 797         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 798         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 799         SET(EXTRA_LIBS /System/Library/Frameworks/CoreAudio.framework ${EXTRA_LIBS})
 800         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 801         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 802
 803         # Some versions of OSX may need the AudioToolbox framework. Add it if
 804         # it's found.
 805         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 806                      NAMES AudioToolbox
 807                      PATHS ~/Library/Frameworks
 808                            /Library/Frameworks
 809                            /System/Library/Frameworks
 810                     )
 811         IF(AUDIOTOOLBOX_LIBRARY)
 812             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 813         ENDIF()
 814     ENDIF()
 815 ENDIF()
 816 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 817     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 818 ENDIF()
 819
 820 # Check for OpenSL (Android) backend
 821 IF(ALSOFT_BACKEND_OPENSL)
 822     CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 823     IF(HAVE_SLES_OPENSLES_ANDROID_H)
 824         CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 825         IF(HAVE_LIBOPENSLES)
 826             SET(HAVE_OPENSL 1)
 827             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 828             SET(BACKENDS  "${BACKENDS} OpenSL,")
 829             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 830         ENDIF()
 831     ENDIF()
 832 ENDIF()
 833 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 834     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 835 ENDIF()
 836
 837 # Optionally enable the Wave Writer backend
 838 IF(ALSOFT_BACKEND_WAVE)
 839     SET(HAVE_WAVE 1)
 840     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 841     SET(BACKENDS  "${BACKENDS} WaveFile,")
 842 ENDIF()
 843
 844 # This is always available
 845 SET(BACKENDS  "${BACKENDS} Null")
 846
 847 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 848     add_subdirectory(utils/alsoft-config)
 849 ENDIF()
 850 IF(ALSOFT_EXAMPLES)
 851     FIND_PACKAGE(SDL)
 852     IF(SDL_FOUND)
 853         FIND_PACKAGE(SDL_sound)
 854         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 855             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 856         ENDIF()
 857     ENDIF()
 858 ENDIF()
 859
 860 IF(LIBTYPE STREQUAL "STATIC")
 861     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 862     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 863 ENDIF()
 864
 865 # Needed for openal.pc.in
 866 SET(prefix ${CMAKE_INSTALL_PREFIX})
 867 SET(exec_prefix "\${prefix}")
 868 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 869 SET(bindir "\${exec_prefix}/bin")
 870 SET(includedir "\${prefix}/include")
 871 SET(PACKAGE_VERSION "${LIB_VERSION}")
 872
 873 # End configuration
 874 CONFIGURE_FILE(
 875     "${OpenAL_SOURCE_DIR}/config.h.in"
 876     "${OpenAL_BINARY_DIR}/config.h")
 877 CONFIGURE_FILE(
 878     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 879     "${OpenAL_BINARY_DIR}/openal.pc"
 880     @ONLY)
 881
 882 # Build a library
 883 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 884 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 885 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 886     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 887 ENDIF()
 888 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 889 IF(FLUIDSYNTH_FOUND)
 890     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 891 ENDIF()
 892 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 893                                             SOVERSION ${LIB_MAJOR_VERSION})
 894 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 895     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 896 ENDIF()
 897
 898 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 899
 900 # Add an install target here
 901 INSTALL(TARGETS ${LIBNAME}
 902         RUNTIME DESTINATION bin
 903         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 904         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 905 )
 906 INSTALL(FILES include/AL/al.h
 907               include/AL/alc.h
 908               include/AL/alext.h
 909               include/AL/efx.h
 910               include/AL/efx-creative.h
 911               include/AL/efx-presets.h
 912         DESTINATION include/AL
 913 )
 914 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 915         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 916
 917
 918 MESSAGE(STATUS "")
 919 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 920 MESSAGE(STATUS "    ${BACKENDS}")
 921 MESSAGE(STATUS "")
 922 MESSAGE(STATUS "Building with support for CPU extensions:")
 923 MESSAGE(STATUS "    ${CPU_EXTS}")
 924 MESSAGE(STATUS "")
 925 IF(HAVE_FLUIDSYNTH)
 926     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
 927     MESSAGE(STATUS "")
 928 ENDIF()
 929
 930 IF(WIN32)
 931     IF(NOT HAVE_DSOUND)
 932         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 933         MESSAGE(STATUS "         This is probably NOT what you want!")
 934         MESSAGE(STATUS "")
 935     ENDIF()
 936 ENDIF()
 937
 938 # Install alsoft.conf configuration file
 939 IF(ALSOFT_CONFIG)
 940     INSTALL(FILES alsoftrc.sample
 941             DESTINATION share/openal
 942     )
 943     MESSAGE(STATUS "Installing sample configuration")
 944     MESSAGE(STATUS "")
 945 ENDIF()
 946
 947 # Install HRTF definitions
 948 IF(ALSOFT_HRTF_DEFS)
 949     INSTALL(FILES hrtf/default-44100.mhr
 950             DESTINATION share/openal/hrtf
 951     )
 952     MESSAGE(STATUS "Installing HRTF definitions")
 953     MESSAGE(STATUS "")
 954 ENDIF()
 955
 956 IF(ALSOFT_UTILS)
 957     ADD_EXECUTABLE(openal-info utils/openal-info.c)
 958     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 959
 960     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
 961     IF(HAVE_LIBM)
 962         TARGET_LINK_LIBRARIES(makehrtf m)
 963     ENDIF()
 964
 965     INSTALL(TARGETS openal-info makehrtf
 966             RUNTIME DESTINATION bin
 967             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 968             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 969     )
 970
 971     MESSAGE(STATUS "Building utility programs")
 972     IF(TARGET alsoft-config)
 973         MESSAGE(STATUS "Building configuration program")
 974     ENDIF()
 975     MESSAGE(STATUS "")
 976 ENDIF()
 977
 978 IF(ALSOFT_EXAMPLES)
 979     IF(SDL_FOUND AND SDL_SOUND_FOUND)
 980         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
 981                                      examples/common/sdl_sound.c)
 982         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 983
 984         ADD_EXECUTABLE(alstream examples/alstream.c)
 985         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 986         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 987
 988         ADD_EXECUTABLE(alreverb examples/alreverb.c)
 989         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 990         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 991
 992         ADD_EXECUTABLE(allatency examples/allatency.c)
 993         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
 994         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
 995
 996         ADD_EXECUTABLE(alloopback examples/alloopback.c)
 997         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
 998         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
 999                                                                            ${SDL_SOUND_INCLUDE_DIR})
1000
1001         INSTALL(TARGETS alstream alreverb allatency alloopback
1002                 RUNTIME DESTINATION bin
1003                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1004                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1005         )
1006
1007         MESSAGE(STATUS "Building example programs")
1008         MESSAGE(STATUS "")
1009     ENDIF()
1010 ENDIF()